Linha Microsiga Protheus - Inglês

Páginas filhas
  • EP CT192POS

01. GENERAL DATA

Product

TOTVS Backoffice

Product Line

Protheus Line

Segment

Services

Module

TOTVS Backoffice (Protheus Line) - Managerial Accounting (SIGACTB)

Function

CTBA192

Country

Brazil

Ticket

Internal

Requisite/Story/Issue

DSERCTR1-46829

02. DESCRIPTION

The Entry Point CT192POS enables the execution of additional processing after the conclusion of the standard operations of the CTBA192 routine. This point is used to include complementary procedures or specific customizations that must be executed only after the closure of the main processing, providing greater flexibility and control over the finalization of the routine's activities.

03. FURTHER INFORMATION


Entry Point (EP) manipulation in the system
ExecBlock("CT192POS",.F.,.F.,{cFilDe,cFilAte,dDataIni,dDataFim,lMoedaEsp,cMoeda,cTpSald})
EP Example
#Include 'Protheus.ch'

User Function CT192POS()

	Local aArea     := GetArea()
	Local aCtbMoeda := {}
	Local cFilDe    := PARAMIXB[1]
	Local cFilAte   := PARAMIXB[2]
	Local dDataIni  := PARAMIXB[3]
	Local dDataFim  := PARAMIXB[4]
	Local lMoedaEsp := PARAMIXB[5]
	Local cMoeda    := PARAMIXB[6]
	Local cTpSald   := PARAMIXB[7]
	SAVEINTER()

	// Specific currency handling

	If lMoedaEsp                    

		aCtbMoeda := CtbMoeda( cMoeda )

		If Empty( aCtbMoeda[1] )

			Help(" ",1,"NOMOEDA")

			Return Nil

		EndIf

		nMoedaIni := Val( cMoeda )

		nMoedaFim := Val( cMoeda )

	Else

		nMoedaIni    := 1

		nMoedaFim    := __nQuantas

	EndIf

	Conout( "CT192POS: Starting the BATCH update process")

	//Reprocesses totals by batch => updates CT6

	Ctb190Lote(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

	Conout( "CT192POS: Starting the DOCUMENT update process")

	//Reprocesses totals by document => updates CTC

	Ctb190Doc(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

	Conout( "CT192POS: Starting the BRIDGE ACCOUNT FLAG update process")

	//Updates the bridge account flags.

	CtbFlgPon(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

	Conout( "CT192POS: PROCESS CONCLUDED!" )

	RESTINTER()

	RestArea( aArea )

Return Nil


Important!

  • It is noteworthy that the customer is responsible for EP utilization and its impacts on the system.
  • The examples used in this documentation are for demonstration purposes only; each customer must determine the behavior they wish to implement according to the scope of the entry point.

04. RELATED SUBJECTS

  • N/A