Linha Microsiga Protheus

Árvore de páginas

01. DADOS GERAIS

Produto:

TOTVS Backoffice

Linha de Produto:

Linha Protheus

Segmento:

Serviços

Módulo:

TOTVS Backoffice (Linha Protheus) - Contabilidade Gerencial (SIGACTB)

Função:CTBA192
País:Brasil
Ticket:Interno
Requisito/Story/IssueDSERCTR1-46829

02. DESCRIÇÃO

O ponto de entrada CT192POS possibilita a execução de processamentos adicionais após o término das operações padrão da rotina CTBA192. Esse ponto é utilizado para incluir procedimentos complementares ou customizações específicas que devem ser executadas somente após o fechamento dos processamentos principais, proporcionando maior flexibilidade e controle sobre a finalização das atividades da rotina.

03. DEMAIS INFORMAÇÕES


Manipulação de PE no sistema
ExecBlock("CT192POS",.F.,.F.,{cFilDe,cFilAte,dDataIni,dDataFim,lMoedaEsp,cMoeda,cTpSald})
Exemplo de PE
#Include 'Protheus.ch'

User Function CT192POS()

	Local aArea     := GetArea()
	Local aCtbMoeda := {}
	Local cFilDe    := PARAMIXB[1]
	Local cFilAte   := PARAMIXB[2]
	Local dDataIni  := PARAMIXB[3]
	Local dDataFim  := PARAMIXB[4]
	Local lMoedaEsp := PARAMIXB[5]
	Local cMoeda    := PARAMIXB[6]
	Local cTpSald   := PARAMIXB[7]
	SAVEINTER()

	// Tratamento da moeda especifica

	If lMoedaEsp                    

		aCtbMoeda := CtbMoeda( cMoeda )

		If Empty( aCtbMoeda[1] )

			Help(" ",1,"NOMOEDA")

			Return Nil

		EndIf

		nMoedaIni := Val( cMoeda )

		nMoedaFim := Val( cMoeda )

	Else

		nMoedaIni    := 1

		nMoedaFim    := __nQuantas

	EndIf

	Conout( "CT192POS: Iniciando processo de atualização do LOTE" )

	//Reprocessa totais por lote  => atualiza CT6

	Ctb190Lote(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

	Conout( "CT192POS: Iniciando processo de atualização do DOCUMENTO" )

	//Reprocessa totais por documento => atualiza CTC

	Ctb190Doc(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

	Conout( "CT192POS: Iniciando processo de atualização do FLAG DE CONTA PONTE" )

	//Atualiza os flags de conta ponte.

	CtbFlgPon(nMoedaIni,nMoedaFim,cFilDe,cFilAte,cTpSald,dDataIni,dDataFim)

	Conout( "CT192POS: PROCESSO CONCLUIDO!" )

	RESTINTER()

	RestArea( aArea )

Return Nil


Importante !!

  • Observa-se que a utilização do PE e os impactos dele no sistema são de responsabilidade do cliente.
  • Os exemplos utilizados nessa documentação são apenas para fins de demonstração, cada cliente deve verificar qual comportamento deseja realizar de acordo com o escopo do ponto de entrada.

04. ASSUNTOS RELACIONADOS

  • Não se aplica.