Histórico da Página

#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWMVCDEF.CH"
/*
    @description Exemplo de função para recuperação do valor de hora extra
    cadastrado na tabela TFU, de um determinado orçamento de serviço.
    @param cCodTfj, string, código do orçamento de serviço
    @param cQtdHrs, string, quantidade de horas no formato string 'HH:MM'
    @param cCodAbn, string, código do motivo de manutenção, cadastrada na tabela TFU, campo TFU_CODABN
*/
USER FUNCTION GTETFU(cCodTfj,cQtdHrs,cCodAbn)

Local nRet      := 0
Local cQry      := ''
Local cTmpAlias := 'TFUTMP'
// Conversão do formato HH:MM para formato decimal
Local nQtdhrs   := VAL(substr(cQtdHrs,1,2)) + val(substr(cQtdHrs,4,2))/60

cQry += "SELECT DISTINCT TFU_CODIGO, TFU_CODTFF, TFU_CODABN, TFU_VALOR "
cQry += "FROM "+retSqlName("TFJ")+" " 
cQry += "INNER JOIN "+retSqlName("TFL")+" ON TFL_CODPAI = TFJ_CODIGO "
cQry += "AND TFJ_FILIAL = '"+xFilial('TFJ')+"' " 
cQry += "AND TFL_FILIAL = '"+xFilial('TFL')+"' " 
cQry += "INNER JOIN "+retSqlName("TFF")+"   ON TFF_CODPAI = TFL_CODIGO "
cQry += "INNER JOIN "+retSqlName("TFU")+" ON TFU_CODTFF = TFF_COD "
cQry += "WHERE TFJ_CODIGO = '"+cCodTfj+"' AND TFU_CODABN = '"+cCodAbn+"' "

cQry := ChangeQuery(cQry)

dbUseArea(.T.,"TOPCONN",TcGenQry(,,cQry),cTmpAlias,.T.,.T.)

// Recuperando um único valor, relacionado com o motivo de manutenção (cCodAbn)
If (cTmpAlias)->(!EOF())
    nRet := (cTmpAlias)->TFU_VALOR * nQtdhrs
EndIf

(cTmpAlias)->(DBCLOSEAREA())

return nRet