Aviso
Classe deverá ser utilizada com a linguagem TL++

Índice

maxLevel	1
exclude	Índice

Objetivo

Classe disponibilizada para a construção do Objeto de Negócio para integração com o TReports, sendo possível utilizá-la como um facilitador para geração de relatórios.

Utilização da classe IntegratedProvider

A nova classe criada em TL++ possui Namespace que deverá ser herdado no novo fonte.

...

Bloco de código

#include "msobject.ch"
// Referência o .th da classe
#include "totvs.framework.treports.integratedprovider.th"

// Cria um novo namespace para sua classe
namespace custom.financeiro.naturezas.integratedprovider

// Caso queira desativar a utilização da classe mudar para active=.F.
@totvsFrameworkTReportsIntegratedProvider(active=.T.)

// Cria uma nova classe e herda a classe principal (IntegratedProvider) com o namespace
class SEDTReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider 
	public method new() as object
endclass

Métodos

New()

Método de instância da classe.

...

Informações

Objeto oSchema

Serão feitos tratamentos internos neste objeto.

Ele possui apenas dois métodos para uso externo, usados em conjunto com os métodos da nova classe, sendo eles:

Método AliasToSchema() - Método do objeto oSchema que transforma o alias em um schema, todos os campos serão enviados.

Método AddProperty() - Método do objeto oSchema que adiciona uma propriedade ao schema.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cName	Caracter	X		Nome da propriedade
cDescription	Caracter	X		Descrição da propriedade
cType	Caracter	X		Tipo da propriedade
cDisplayName	Caracter	X		Nome de exibição da propriedade
cRealName	Caracter			Nome da propriedade no Protheus (Nome real do campo da tabela)
cComboValues (Disponível a partir da LIB Label 20220321)	Caracter		Ao ser utilizado o método self:setIsCBoxLookup() documentado abaixo, com o segundo parâmetro igual a .T., o cComboValues receberá o valor do combobox do campo a partir da SX3	Valores do key-label (Formato igual ao combobox da SX3, ex.: "D MG 01=Filial BH" separado por ; caso tenha mais de uma opção)
lIsRequired (Disponível a partir da LIB Label 20220321)	Lógico		.F.	Indica que será obrigatório informar um valor para o campo

Exemplos de uso estarão abaixo nos métodos criados para a classe IntegratedProvider.

Obs: O nome real é necessário para que o filtro seja feito com base no nome real do campo, caso contrário, o mesmo levará em consideração a propriedade name.

GetSchema()

Retorna a Estrutura de dados.

Exemplos de uso:

Bloco de código
method getSchema() as object class SEDTReportsBusinessObject self:oSchema:aliasToSchema("SED") //Alias utilizado para retorno dos dados return self:oSchema

...

Sintaxe: GetSchema() → objeto self:oSchema

GetData()

Retorna o Objeto de dados.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
nPage	Numérico		Página atual	Número da página atual
oFilter	Objeto			Objeto do Filtro

Exemplos de uso:

Bloco de código

method getData(nPage as numeric, oFilter as object) as object class SEDTReportsBusinessObject
	// Objeto de filtro nulo pois o recurso não se encontra ativo
	self:oData:aliasToData("SED", oFilter)
return self:oData

...

Sintaxe: GetData() → objeto self:oData

SetDisplayName()

Define o nome do relatório.

Exemplo de uso:

Bloco de código
SetDisplayName("Naturezas")

Sintaxe: SetDisplayName(<cTexto>) → nil

GetDisplayName()

Retorna o nome do relatório.

Sintaxe: GetDisplayName() → self:cTexto

AppendArea()

Adiciona uma área a qual o relatório pertence.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cArea	Caracter	X		Nome da área do relatório

Exemplo de uso:

Bloco de código
AppendArea("Financeiro")

Sintaxe: AppendArea(<cArea>) → nil

GetAreas()

Retorna a área que os relatórios pertencem.

Sintaxe: GetAreas() → self:aArray

SetDescription()

Define a descrição do relatório.

Sintaxe: SetDescription(<cTexto>) → nil

GetDescription()

Retorna a descrição do relatório.

...

Bloco de código

title	Exemplo 3
collapse	true

#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"

namespace custom.materiais.produtos.integratedprovider

@totvsFrameworkTReportsIntegratedProvider(active=.T.)
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass

method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Materiais")
return self

method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"

method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"

method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character

cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"

//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif

cAlias := MPSysOpenQuery(cQuery)

while !(cAlias)->(Eof())
    self:oData:appendData({"Filial": (cAlias)->B1_FILIAL,; 
            "Codigo": (cAlias)->B1_COD,; 
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": FwTimeStamp(6, StoD((cAlias)->B1_UREV)) }) //O campo data deverá ser enviado no formato correto
    (cAlias)->(DBSkip())
enddo

(cAlias)->(DBCloseArea())

return self:oData

method getSchema() as object class SB1TReportsBusinessObject
self:oSchema:addProperty("Codigo", "Codigo", "string", "Código", "B1_COD")
self:oSchema:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:oSchema:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:oSchema:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM")
self:oSchema:addProperty("Revisao", "Revisao", "date", "Revisao","B1_UREV") 
return self:oSchema

Implementação do LookUp dos campos

Informações
Disponível a partir da LIB Label 20220321

Com os métodos documentados a seguir será possível adicionar o LookUp dos campos na interface do TReports, seu uso é opcional.

Padrão Key-Label

Key - Chave do LookUp (Valor que será procurado na tabela do schema)

Label - Label de exibição do Lookup. (Nome amigável que será apresentado na interface do TReports)

Método self:setIsCBoxLookup()

Indica no objeto Schema que o LookUp será do tipo Key-Value (combobox).

Informações
Método deverá ser utilizado no new() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
lKeyLabel	Lógico	X	.F.	Indica que o filtro lookup será do tipo key-label
lX3	Lógico		.F.	Indica que utilizará o SX3 para recuperar os valores do key-label dos campos

Exemplo de uso:

Bloco de código
self:setIsCBoxLookup(.T., .T.)

...

Aviso

title	Atenção

Ao utilizar o parâmetro lX3 como .T. todos os campos da classe passará pela aplicação do lookup de acordo com a SX3, caso o número de campos seja grande a performance poderá ser afetada.

Método self:oSchema:setComboValues()

Indica os valores dos combos dos schemas da nova classe.

Informações
Método deverá ser utilizado no getSchema() após a criação dos campos da nova classe, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cField	Caracter	X		Campo que receberá o LookUp Key-Label
cComboValues	Caracter	X		Valores do key-label (Formato igual ao combobox da SX3, ex.: "D MG 01=Filial BH" separado por ; caso tenha mais de uma opção)
lIsRequired	Lógico		.F.	Indica que é obrigatório o preenchimento do campo.

Utilização com o método addProperty() documentado acima

Exemplo de uso:

Bloco de código
self:oSchema:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL", "D MG 01=Filial BH; D MG 02=Filial Uberaba", .F.)

Exemplos completos com LookUp Key-Label:

Bloco de código

title	Exemplo 1 - LookUp Key-Label
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
 
namespace custom.materiais
 
@totvsFrameworkTReportsIntegratedProvider(active=.T.)
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
endclass
 
method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Materiais")
self:setIsCBoxLookup(.T., .T.)
return self
 
method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"
 
method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"
 
method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character
 
cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV, B1_FILIAL, B1_PRV1 FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"
 
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif
 
cAlias := MPSysOpenQuery(cQuery)
 
while !(cAlias)->(Eof())
    cDate := FwTimeStamp(6, StoD((cAlias)->B1_UREV))
    self:oData:appendData({"Filial": (cAlias)->B1_FILIAL,; 
            "Codigo": (cAlias)->B1_COD,; 
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": cDate ,;
            "Preco": (cAlias)->B1_PRV1})
    (cAlias)->(DBSkip())
enddo
 
(cAlias)->(DBCloseArea()) 
 
return self:oData
 
method getSchema() as object class SB1TReportsBusinessObject
local cComboFil as character

cComboFil := "D MG 01=Filial BH; D MG 02=Filial Uberaba"

self:oSchema:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL", cComboFil,.F.)
self:oSchema:addProperty("Codigo", "Codigo", "string", "Codigo", "B1_COD")
self:oSchema:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:oSchema:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:oSchema:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM") 
self:oSchema:addProperty("Revisao", "Revisao", "date", "revisao","B1_UREV") 
self:oSchema:addProperty("Data", "Data", "date", "Data","B1_UREV")
self:oSchema:addProperty("Preco", "Preço", "number", "Preço","B1_PRV1")
return self:oSchema

...

Exemplo do Key-Label na interface:

Padrão LookUp

ID - Chave do LookUp (Valor que será procurado na tabela do schema)

...

Desc - Descrição do LookUp (Nome amigável que será apresentado na interface do TReports)

Método self:setIsLookup()

Indica no objeto Schema que o LookUp será do tipo padrão LookUp.

Informações
Método deverá ser utilizado no new() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
lIsLookUp	Lógico	X	.F.	Indica que o filtro será do tipo padrão lookup
lIsX5LookUp	Lógico		.F.	Seta que o filtro será do tipo padrão lookup a partir da SX5

Exemplo de uso:

Bloco de código
self:setIsLookup(.T., .T.)

Sintaxe: self:SetIsLookUp(<lIsLookUp>, <lIsX5LookUp>) → nil

Método self:oSchema:setDescriptor()

Indica a descrição para o LookUp (padrão lookup).

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Default	Descrição
cId	Caracter	ID	Indica o cabeçalho de exibição da chave do lookup
cProd	Caracter	Código	Indica o cabeçalho de exibição do código do lookup (Mesmo conteúdo do ID)
cDesc	Caracter	Descrição	Indica o cabeçalho de exibição da descrição do lookup

Exemplo de uso:

Bloco de código
self:oSchema:setDescriptor("Código","Código do Produto", "Descrição do Produto")

Sintaxe: self:oSchema:setDescriptor(<cId>, <cProd>, <cDesc>) → nil

Método self:oSchema:setLookUpVal()

Indica os valores para o LookUp (padrão lookup)

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome

Tipo

Obrigatório

Default

Descrição

cField

Caracter

X

Indica o campo que será setado a consulta

aStruct

Array

X

Indica a estrutura que será utilizada no Lookup

Exemplo da estrutura:

aStruct[1][1]:"ATF0510001"
aStruct[1][2]:"ATFA036 EMISSAO DE NOTA EM LOT"

aStruct[2][1]:"0003"
aStruct[2][2]:"PRODUTO PADRAO"

lIsRequired

Lógico

.F.

Indica que é obrigatório o preenchimento do campo

Exemplo de uso:

Bloco de código
self:oSchema:setLookUpVal(cField, aStruct, lIsRequired)

Sintaxe: self:oSchema:setLookUpVal(<cField>, <aStruct>, <lIsRequired>) → nil

Método self:oSchema:setX5Struct()

Indica os valores para o LookUp (padrão lookup) a partir da SX5.

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome	Tipo	Obrigatório	Default	Descrição
cField	Caracter	X		Indica o campo que será setado a consulta
cTable	Caracter	X		Indica a tabela da SX5 que será utilizada para buscar a estrutura do lookup
lIsRequired	Lógico		.F.	Indica que é obrigatório o preenchimento do campo

Exemplo de uso:

Bloco de código
self:oSchema:setLookUpVal(cField, cTable, lIsRequired)

Sintaxe: self:oSchema:setLookUpVal(<cField>, <cTable>, <lIsRequired>) → nil

Método self:oSchema:setLookUpQuery()

Indica os valores para o LookUp (padrão lookup) a partir de uma query.

Informações
Método deverá ser utilizado no getSchema() da nova classe criada, exemplo completo estará no final da documentação.

Parâmetros:

Nome

Tipo

Obrigatório

Default

Descrição

aFields

Array

X

Indica os campos da estrutura da consulta (chave-descrição).

Exemplo:

aFields[1]:"ED_CODIGO"

aFields[2]:"ED_DESCRIC"

cQuery

Caracter

X

Indica a tabela da SX5 que será utilizada para buscar a estrutura do lookup

lIsRequired

Lógico

.F.

Indica que é obrigatório o preenchimento do campo

Exemplo de uso:

Bloco de código
self:oSchema:setLookUpQuery(aFields, cQuery, lIsRequired)

Sintaxe: self:oSchema:setLookUpQuery(<aFields>, <cQuery>, <lIsRequired>) → nil

Exemplos completos com padrão LookUp:

Bloco de código

title	Exemplo 1 - padrão LookUp - Valores setados manualmente
collapse	true

#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
 
namespace custom.materiais.produtos.integratedprovider.lookup
 
@totvsFrameworkTReportsIntegratedProvider(active=.T.)
class SB1TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
    public method new() as object
    public method getDisplayName() as character
    public method getDescription() as character
    public method getData() as object
    public method getSchema() as object
    public method getLookUp() as object
endclass
 
method new() class SB1TReportsBusinessObject
_Super:new()
self:appendArea("Materiais")
self:setIsLookUp(.T.)
return self
 
method getDisplayName() as character class SB1TReportsBusinessObject
return "Produtos"
 
method getDescription() as character class SB1TReportsBusinessObject
return "Produtos do Protheus"
 
method getData(nPage as numeric, oFilter as object) as object class SB1TReportsBusinessObject
local cQuery as character
local cAlias as character
 
cQuery := "SELECT B1_FILIAL, B1_COD, B1_DESC, B1_TIPO, B1_UM, B1_UREV FROM " + RetSQLName("SB1") + " WHERE D_E_L_E_T_ = ' '"
 
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
    cQuery += " AND " + oFilter:getSQLExpression()
endif
 
cAlias := MPSysOpenQuery(cQuery)

while !(cAlias)->(Eof())
    cDate := FwTimeStamp(6, StoD((cAlias)->B1_UREV))
    self:oData:appendData({"Filial": (cAlias)->B1_FILIAL,; 
            "Codigo": (cAlias)->B1_COD,; 
            "Descricao": (cAlias)->B1_DESC,;
            "Tipo": (cAlias)->B1_TIPO, ;
            "Unidade": (cAlias)->B1_UM, ;
            "Revisao": cDate})
    (cAlias)->(DBSkip())
enddo
 
(cAlias)->(DBCloseArea()) 
 
return self:oData
 
method getSchema() as object class SB1TReportsBusinessObject
local cField as character
local aStruct as array
local lIsRequired as logical

//Seta a descrição da consulta
self:oSchema:setDescriptor("Código","Código do Produto", "Descrição")

self:oSchema:addProperty("Filial", "Filial", "string", "Filial", "B1_FILIAL", cComboFil,.F.)
self:oSchema:addProperty("Codigo", "Codigo", "string", "Codigo", "B1_COD")
self:oSchema:addProperty("Descricao", "Descricao", "string", "Descricao","B1_DESC")
self:oSchema:addProperty("Tipo", "Tipo", "string", "Tipo","B1_TIPO")
self:oSchema:addProperty("Unidade", "Unidade de medida", "string", "Unidade","B1_UM") 
self:oSchema:addProperty("Revisao", "Revisao", "date", "revisao","B1_UREV") 
self:oSchema:addProperty("Camp Log", "Camp Log", "boolean", "Camp Lógico","B1_LOGI")

cField := "B1_COD"
aStruct := {}
aAdd(aStruct, {"ATF0510001", "ATFA036 EMISSAO DE NOTA EM LOT"})
aAdd(aStruct, {"0003","PRODUTO PADRAO"})
aAdd(aStruct, {"EST00000000000000000000001GGGR","'PRODTO ESTOQUE GRADE EAI INTE"})
lIsRequired := .F.

//Seta os valores para o Lookup
self:oSchema:setLookUpVal(cField, aStruct, lIsRequired)

return self:oSchema

...

Páginas filhas

Histórico da Página

Versões comparadas

Versão antiga 42

Nova versão 43

Chave

Índice

Objetivo

Utilização da classe IntegratedProvider

Métodos

New()

GetSchema()

Exemplos de uso:

GetData()

Parâmetros:

Exemplos de uso:

SetDisplayName()

Exemplo de uso:

GetDisplayName()

AppendArea()

Parâmetros:

Exemplo de uso:

GetAreas()

SetDescription()

GetDescription()

Implementação do LookUp dos campos

Padrão Key-Label

Método self:setIsCBoxLookup()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setComboValues()

Parâmetros:

Utilização com o método addProperty() documentado acima

Exemplo de uso:

Exemplos completos com LookUp Key-Label:

Padrão LookUp

Método self:setIsLookup()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setDescriptor()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setLookUpVal()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setX5Struct()

Parâmetros:

Exemplo de uso:

Método self:oSchema:setLookUpQuery()

Parâmetros:

Exemplo de uso:

Exemplos completos com padrão LookUp: