Histórico da Página
| Informações | ||
|---|---|---|
| ||
Novos métodos para objeto de negócio localizado disponíveis a partir da LIB Label 20230626 |
Índice
| Índice | ||||
|---|---|---|---|---|
|
Pré-requisitos
Nesta documentação teremos os novos métodos implementados, para que sejam utilizados nos objetos de negócio que serão personalizados por localização.
...
- Já ter feito a integração com o TReportsSmart View, mais informações: TReports Smart View - Protheus como Fonte de Dados Nativa
- Ler a documentação da classe utilizada: TReports Smart View - Classe IntegratedProvider - Criação de Objetos de Negócios
- Entender os annotations dos objetos de negócio: TReports Smart View - Annotation no objeto de negócio
Novos métodos
preSchema()
Método que será chamado antes do getSchema(), aqui poderão ser adicionados novos campos para o schema, que não estão no schema principal e que poderão ser campos novos, campos totalizadores, campos que só existem em um país específico etc.
preData()
Método que será chamado antes do getData(), esse método pode ser utilizado para fazer a query atualizada com os campos que poderão ser adicionados no objeto de negócio localizado ou para adicionar o where que deverá ser localizado.
processData()
Este método deverá ser chamado antes do envio dos dados no getData() para que sejam adicionados os dados dos campos que estarão no objeto de negócio localizado.
Como ira funcionar
1º cenário:
Os objetos com o annotation country=ALL irá ser exibido para todos os países e todas as informações desse objeto serão herdadas para o objeto de negócio localizado.
...
Caso o objeto seja exclusivo de um país, por exemplo, um relatório de impostos apenas para o Brasil, o annotation country deverá ser igual a BRA e o active deverá vir como .T.
Como ficarão os Annotations e heranças dos Objetos de Negócio
1º Cenário:
Se eu tenho a classe MATR190TReportsBusinessObject como objeto de negócio padrão, assim ficará o annotation e herança da classe:
...
Obs.: Neste caso o active é igual a .T. pois é um objeto exclusivo apenas para o Brasil
Exemplo completo
Objeto padrão:
| Bloco de código | ||||
|---|---|---|---|---|
| ||||
#include "msobject.ch"
#include "protheus.ch"
#include "apcfg021.ch"
#include "totvs.framework.treports.integratedprovider.th"
namespace custom.materiais
//-------------------------------------------------------------------
/*{Protheus.doc} MATR190TReportsBusinessObject
Classe para criação do Objeto de Negócio de Prod x Forn para o TReports
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SA5", name="Produto X Fornecedor", country="ALL", initialRelease="12.1.2210")
class MATR190TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
public method new() as object
public method getDisplayName() as character
public method getDescription() as character
public method getData() as object
public method getSchema() as object
protected data aFields as array
protected data aStruct as array
protected data cQuery as character
protected data cWhere as character
protected data jItems as json
endclass
//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe
@return object: self
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method new() class MATR190TReportsBusinessObject
_Super:new()
self:appendArea("Compras")
self:aFields := {"A5_LOJA", "A5_NOMEFOR", "A5_PRODUTO"}
return self
//-------------------------------------------------------------------
/*{Protheus.doc} getDisplayName
Retorna o nome de exibição do objeto de negócio
@return string
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getDisplayName() as character class MATR190TReportsBusinessObject
return "Produtos x Fornecedores - Localizado"
//-------------------------------------------------------------------
/*{Protheus.doc} getDescription
Retorna a descrição do objeto de negócio
@return string
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getDescription() as character class MATR190TReportsBusinessObject
return "Produtos x Fornecedores"
//-------------------------------------------------------------------
/*{Protheus.doc} getData
Retorna os dados do objeto de negócio
@param nPage, numérico, indica a página atual do relatório
@param oFilter, objeto, contém o filtro do TReports
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getData(nPage as numeric, oFilter as object) as object class MATR190TReportsBusinessObject
local cAlias as character
local nSkip as numeric
local nCount as numeric
local nX as numeric
local aPDFields as array
local cFieldsQry as character
nCount := 0
cFieldsQry := ArrTokStr(self:aFields, ",")
self:cQuery := "SELECT "
self:cQuery += cFieldsQry
self:cQuery += " FROM " + RetSQLName("SA5")
if !empty(self:cWhere)
self:cQuery += self:cWhere //Where que foi populado no objeto localizado
endif
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
self:cQuery += " AND " + oFilter:getSQLExpression()
endif
cAlias := MPSysOpenQuery(self:cQuery)
if nPage == 1
(cAlias)->(dbGoTop())
else
//Encontra a quantidade de itens que irá pular de acordo com a página atual
nSkip := ((nPage - 1) * self:getPageSize())
(cAlias)->(dbSkip(nSkip))
endif
//Verifica se precisa fazer o tratamento para LGPD
aPDFields := FwProtectedDataUtil():UsrAccessPDField(__cUserID, self:aFields)
lObfuscated := len( aPDFields ) != Len(self:aFields)
while !(cAlias)->(Eof())
self:jItems := JsonObject():new()
for nX := 1 To Len(self:aStruct)
if lObfuscated .and. aScan(aPDFields, self:aStruct[nX][5]) == 0
self:jItems[self:aStruct[nX][1]] := FwProtectedDataUtil():ValueAsteriskToAnonymize((cAlias)->&(self:aStruct[nX][5]))
else
self:jItems[self:aStruct[nX][1]] := (cAlias)->&(self:aStruct[nX][5])
endif
next nX
self:processData()
self:oData:appendData(self:jItems)
(cAlias)->(DBSkip())
nCount++
//Sai do loop quando chegar no tamanho de itens da página
if nCount == self:getPageSize()
exit
endif
enddo
//Se não for o último registro indica que terá próxima página
self:setHasNext(!(cAlias)->(Eof()))
(cAlias)->(DBCloseArea())
return self:oData
//-------------------------------------------------------------------
/*{Protheus.doc} getSchema
Retorna a estrutura dos campos
@return object: self:oSchema
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getSchema() as object class MATR190TReportsBusinessObject
Local nX as numeric
self:aStruct := getStruct(self:aFields)
for nX := 1 To Len(self:aStruct)
self:addProperty(self:aStruct[nX][1], self:aStruct[nX][2], self:aStruct[nX][3], self:aStruct[nX][4], self:aStruct[nX][5])
Next nX
return self:oSchema
//-------------------------------------------------------------------
/*{Protheus.doc} getStruct
Prepara a estrutura dos campos
@param aCpos array: Array com os campos do relatório
@return array: Array com a estrutura dos campos
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
function getStruct(aCpos)
Local aDeParaCpo as array
Local aCpoTmp as array
Local cCampo as character
Local cCpoQry as character
Local cTipR as character
Local nPos as numeric
Local nC as numeric
aDeParaCpo := {{"C", "string"}, {"D", "date"}, {"N", "number"}, {"L", "boolean"}}
aCpoTmp := {}
for nC := 1 to Len(aCpos)
cCpoQry := aCpos[nC]
nPos := AT(".", aCpos[nC]) + 1
if nPos > 0
cCampo := Substr(cCpoQry, nPos)
else
cCampo := cCpoQry
endif
cTipo := GetSx3Cache(cCampo, "X3_TIPO")
if (nPos := aScan(aDeParaCpo, {|c| c[01] = cTipo})) > 0
cTipR := aDeParaCpo[nPos, 02]
else
cTipR := "string"
endif
AAdd(aCpoTmp, {strTran(cCampo, "_", ""), FWSX3Util():GetDescription(cCampo), cTipR, FWSX3Util():GetDescription(cCampo), cCampo})
next nC
return (aCpoTmp) |
...
| Bloco de código | ||||
|---|---|---|---|---|
| ||||
#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
namespace custom.materiais
//-------------------------------------------------------------------
/*{Protheus.doc} MATR190TReportsBusinessObjectARG
Classe para criação do Objeto de Negócio de Prod x Forn para o TReports
Localizado para a Argentina
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
@totvsFrameworkTReportsIntegratedProvider(active=.F., tables="SA5", team="SIGACOM", name="Produto X Fornecedor", country="ARG", initialRelease="12.1.2210") //O active deverá vir como .F. para que o objeto não fique duplicado
/*Aqui será herdada a classe padrão criada anteriormente, o nome da classe localizada deverá ser a padrão + sigla do país (cPaisLoc)*/
class MATR190TReportsBusinessObjectARG from custom.materiais.MATR190TReportsBusinessObject
public method new() as object
public method preData() as object
public method processData() as object
public method preSchema() as object
protected data aFields as array
protected data aStruct as array
endclass
//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe que herdará a principal
@return object: self
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method new() class MATR190TReportsBusinessObjectARG
_Super:new()
aAdd(self:aFields, "A5_FORNECE") //Adicionando um novo campo para o objeto localizado
return self
//-------------------------------------------------------------------
/*{Protheus.doc} preData
Método chamado antes do getData do objeto principal
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method preData() as object class MATR190TReportsBusinessObjectARG
//Aqui é adicionada uma condição no where que será utilizado na query do objeto padrão
self:cWhere := " WHERE D_E_L_E_T_ = ' '"
return self:oData
//-------------------------------------------------------------------
/*{Protheus.doc} processData
Deverá ser chamado no momento do processamento da query
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method processData() as object class MATR190TReportsBusinessObjectARG
//Adição dos dados dos campos personalizados que só existem no objeto localizado (não existem na tabela)
self:jItems["Comentarios"] := "Teste Localizado"
self:jItems["Totalizador"] := "1220"
return
//-------------------------------------------------------------------
/*{Protheus.doc} preSchema
Método chamada antes do getSchema do objeto principal
@return object: self:oSchema
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method preSchema() as object class MATR190TReportsBusinessObjectARG
//Adição de novos campos personalizados (não existem na tabela)
self:addProperty("Comentarios", "Comentarios", "string", "Comentarios", "Comentarios")
self:addProperty("Totalizador", "Totalizador", "string", "Totalizador", "Totalizador")
return self:oSchema |
Resultados no TReports
Objeto padrão:
Objeto localizado ARG:
...
| Bloco de código | ||||
|---|---|---|---|---|
| ||||
#include "protheus.ch"
#include "msobject.ch"
#include "totvs.framework.treports.integratedprovider.th"
namespace custom.produtos.fornecedores
//active virá como .T. pois esse objeto é exclusivo para o Brasil
@totvsFrameworkTReportsIntegratedProvider(active=.T., team="SIGACOM", tables="SA5", name="Produto X Fornecedor", country="BRA", initialRelease="12.1.2210")
//-------------------------------------------------------------------
/*{Protheus.doc} ProdFornTReportsBusinessObjectBRA
Classe para criação do Objeto de Negócio de Prod x Forn para o TReports
Localizado BRA
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
class ProdFornTReportsBusinessObjectBRA from totvs.framework.treports.integratedprovider.IntegratedProvider
public method new() as object
public method getData() as object
public method getSchema() as object
protected data aFields as array
protected data aStruct as array
endclass
//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe
@return object: self
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method new() class ProdFornTReportsBusinessObjectBRA
_Super:new()
self:appendArea("Compras")
self:setDisplayName("Fornecedores x Produtos")
self:setDescription("Relatório Fornecedores x Produtos com tratamento LGPD")
self:aFields := {"A5_FILIAL", "A5_FORNECE", "A5_LOJA", "A5_NOMEFOR", "A5_PRODUTO", "A5_NOMPROD", "A5_CODPRF"}
self:aStruct := getStruct(self:aFields)
return self
//-------------------------------------------------------------------
/*{Protheus.doc} getData
Retorna os dados do objeto de negócio
@param nPage, numérico, indica a página atual do relatório
@param oFilter, objeto, contém o filtro do TReports
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getData(nPage as numeric, oFilter as object) as object class ProdFornTReportsBusinessObjectBRA
local cQuery as character
local cAlias as character
local nSkip as numeric
local nCount as numeric
local nX as numeric
local jItems as json
local aPDFields as array
nCount := 0
cQuery := "SELECT A5_FILIAL,A5_PRODUTO,A5_NOMPROD,A5_FORNECE,A5_NOMEFOR,A5_LOJA,A5_CODPRF FROM " + RetSQLName("SA5") + " WHERE D_E_L_E_T_ = ' '"
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
cQuery += " AND " + oFilter:getSQLExpression()
endif
cAlias := MPSysOpenQuery(cQuery)
if nPage == 1
(cAlias)->(dbGoTop())
else
//Encontra a quantidade de itens que irá pular de acordo com a página atual
nSkip := ((nPage - 1) * self:getPageSize())
(cAlias)->(dbSkip(nSkip))
endif
//Verifica se precisa fazer o tratamento para LGPD
aPDFields := FwProtectedDataUtil():UsrAccessPDField(__cUserID, self:aFields)
lObfuscated := len( aPDFields ) != Len(self:aFields)
while !(cAlias)->(Eof())
jItems := JsonObject():new()
for nX := 1 To Len(self:aStruct)
if lObfuscated .and. aScan(aPDFields, self:aStruct[nX][5]) == 0
jItems[self:aStruct[nX][1]] := FwProtectedDataUtil():ValueAsteriskToAnonymize((cAlias)->&(self:aStruct[nX][5]))
else
jItems[self:aStruct[nX][1]] := (cAlias)->&(self:aStruct[nX][5])
endif
next nX
self:oData:appendData(jItems)
(cAlias)->(DBSkip())
nCount++
//Sai do loop quando chegar no tamanho de itens da página
if nCount == self:getPageSize()
exit
endif
enddo
//Se não for o último registro indica que terá próxima página
self:setHasNext(!(cAlias)->(Eof()))
(cAlias)->(DBCloseArea())
return self:oData
//-------------------------------------------------------------------
/*{Protheus.doc} getSchema
Retorna a estrutura dos campos
@return object: self:oSchema
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getSchema() as object class ProdFornTReportsBusinessObjectBRA
Local nX as numeric
for nX := 1 To Len(self:aStruct)
self:addProperty(self:aStruct[nX][1], self:aStruct[nX][2], self:aStruct[nX][3], self:aStruct[nX][4], self:aStruct[nX][5])
Next nX
return self:oSchema
//-------------------------------------------------------------------
/*{Protheus.doc} getStruct
Prepara a estrutura dos campos
@param aFlds array: Array com os campos do relatório
@return array: Array com a estrutura dos campos
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
function getStruct(aFlds)
Local aConvFld as array
Local aFldTmp as array
Local cCampo as character
Local cFldQry as character
Local cTipR as character
Local nPos as numeric
Local nC as numeric
aConvFld := {{"C", "string"}, {"D", "date"}, {"N", "number"}, {"L", "boolean"}, {"M", "memo"}}
aFldTmp := {}
for nC := 1 to Len(aFlds)
cFldQry := aFlds[nC]
nPos := AT(".", aFlds[nC]) + 1
if nPos > 0
cCampo := Substr(cFldQry, nPos)
else
cCampo := cFldQry
endif
cTipo := GetSx3Cache(cCampo, "X3_TIPO")
if (nPos := aScan(aConvFld, {|c| c[01] = cTipo})) > 0
cTipR := aConvFld[nPos, 02]
else
cTipR := "string"
endif
AAdd(aFldTmp, {cCampo, FWSX3Util():GetDescription(cCampo), cTipR, FWSX3Util():GetDescription(cCampo), cCampo})
next nC
return (aFldTmp) |
Resultados no
...
Smart View
Ambiente BRA:
Ambiente ARG:
Observações
- Na visão de dados e tabela dinâmica deverá se atentar aos filtros, se ele for feito para um campo do objeto localizado, deverá ser separado do padrão.
- Os layouts dos relatórios deverão ser criados separadamente por país, pois se houver personalização, podem ter campos que não existem em outros países.
...
Visão Geral
Import HTML Content
Conteúdo das Ferramentas
Tarefas