Histórico da Página

#INCLUDE "TOTVS.CH"

/*/{Protheus.doc} User Function FI020CABEC

    (Ponto de Entrada para cliente alterar informacoes antes do ExecAuto
	ou Adicionar campos de usuario.)
    
    @type  Function
    @author Cassio S Dias
    @since 01/12/2023
    @version 12.1.2310
    @param param_name, param_type, param_descr
    @return aCab, array
    @see (https://tdn.totvs.com/x/gUQ6M)
    /*/
User Function FI020CABEC(aCabec) as array

	Local aCab     as array
	Local aStruSF2 as array
    Local cCond    as character
    Local j        as numeric

	aCab     := {}
    aStruSF2 := SF2->(dbStruct())
    cCond    := PARAMIXB

	//Monta o cabecalho da NF
	For j := 1 to len(aStruSF2)

		Do Case
		Case ALLTRIM(aStruSF2[j][1]) == 'F2_FILIAL'
			Aadd( aCab, xFilial("SF2") )			// Filial

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_CLIENTE'
			Aadd( aCab, SA1->A1_COD    )			// Cliente

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_LOJA'
			Aadd( aCab, SA1->A1_LOJA   )			// Loja

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_CLIENT'
			Aadd( aCab, SA1->A1_COD    )			// Cliente

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_LOJENT'
			Aadd( aCab, SA1->A1_LOJA   )			// Loja

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_TIPO'
			Aadd( aCab,     "N"        )		    // Tipo (Normal)

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_TIPOCLI'
			Aadd( aCab, SA1->A1_PESSOA )		    // Tipo de cliente (F=Pessoa Fisica; J=Pessoa Juridica)

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_EMISSAO'
			Aadd( aCab,  dDataBase     )		    // Data de emissao

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_COND'
			Aadd( aCab,    cCond	     )	     	// Condicao de pagamento

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_HORA'
			Aadd( aCab, SubStr(Time(),1,5) )		// Hora do processamento

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_EST'
			Aadd( aCab, SA1->A1_EST    ) 	        // Estado

		Case ALLTRIM(aStruSF2[j][1]) == 'F2_NEXTDOC'
			Aadd( aCab, "      "       )		    // Proximo docto

		EndCase

	Next j

Return aCab