Histórico da Página

Ponto de Entrada

Exemplo:

//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Ponto de Entrada utilizado para realizar a Reserva dos produtos da venda sem a exibicao da interface para o usuario.
//Este ponto de entrada eh utilizado apenas para selecionar as opcoes que o sistema passa como parametro, ou seja,
//utiliza o mesmo conceito como se estivesse utilizando a interface (tela) para o ususario fazer a selecao das opcoes,
//porem a selecao eh feita por este PE sem a exibicao da interface.
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
//Este Ponto de Entrada é executado em dois momentos.
// 1º Momento (operacao= "1"): Neste momento deve ser feita a selecao das "LOJAS" onde serao reservados os produtos e a selecao dos "PRODUTOS" que serao reservados
// 2º Momento (operacao= "2"): Neste momento deve ser feita a selecao do "ARMAZEM" (Local de Estoque) relacionado a loja onde serao reservados os produtos
//-----------------------------------------------------------------------------------------------------------------------------------------------------------------
User Function LJRESERV()
Local aRet := {} //Retorno da funcao
Local cOperacao := PARAMIXB[1] //Tipo de Operacao em execucao
Local aLojas := PARAMIXB[2] //Lojas disponiveis para efetuar a Reserva
Local aProdutos := PARAMIXB[3] //Produtos da venda que a serem reservados
Local aEstoque := PARAMIXB[4] //Saldos dos Estoques nas lojas/armazem
Local aEstoqBKP := aClone(aEstoque)
Local nX := 0
Local nY := 0
Local nZ := 0
Local lConfirma := .F. //Simula o botao "Confirmar" (.T.=Confirma; .F.=Cancela)
Local nENTREGA := aScan( aHeader,{|x| Trim(x[2]) == "LR_ENTREGA" } ) //Posicao do Campo "LR_ENTREGA"
Local nITEM := aScan( aHeader,{|x| Trim(x[2]) == "LR_ITEM" } ) //Posicao do Campo "LR_ITEM"
Local nPosAcols := 0
Local lContinua := .F.
Local cItem := ""
Local cProduto := ""
Local lTemEstoque := .T.
Local aPrdSemEst := {} //Produtos sem estoque
Local cMsg := ""

MsgAlert("Passou pelo P.E. LJRESERV com cOperacao := " + cOperacao)
Do Case

    //Operacao 1: Selecao das "LOJAS" onde serao reservados os produtos e selecao dos "PRODUTOS" que serao reservados
    Case cOperacao == "1"

        //-------------------------------------------
        // Escolha da LOJA onde sera feita a reserva
        //-------------------------------------------
        aLojas[1][1] := .T. //Neste exemplo, sempre considera a escolha (selecao) da primeira loja

        //-------------------------------------------
        // Escolha dos PRODUTOS que serao reservados
        //-------------------------------------------
        For nX:=1 To Len(aProdutos)

            //Localiza o item no aCols
            nPosAcols := aScan( aCols, { |x| x[nITEM] == aProdutos[nX][2] } )

            //Selecionando apenas os produtos, cujo a opcao do campo "LR_ENTREGA" seja "3-Entrega" ou "5-Entrega c/Pedido s/Reserva"
            If !Empty(aCols[nPosAcols][nENTREGA]) .And. (aCols[nPosAcols][nENTREGA] == "3" .OR. aCols[nPosAcols][nENTREGA] == "5") // 3=Entrega, 5=Entrega c/Pedido s/Reserva
                aProdutos[nX][1] := .T.
            EndIf

        Next nX

        lConfirma := .T. //Confirma as informacoes selecionadas.

     //Operacao 2: Selecao do "ARMAZEM" (Local de Estoque) relacionado a loja onde serao reservados os produtos
    Case cOperacao == "2"

        //Efetua a reserva dos produtos
        For nX:=1 To Len(aProdutos)

            cItem := aProdutos[nX][2] //Item da venda
            cProduto := aProdutos[nX][3] //Codigo do Produto

            //Faz a Reserva no primeiro Local de Estoque (Armazem) encontrado para a loja escolhida que possua saldo
            For nY := 1 To Len(aEstoque)

                If aEstoque[nY][8] == cItem .And. aEstoque[nY][4] == cProduto

                    lTemEstoque := .F.

                    For nZ:=1 To Len(aEstoque[nY][5])

                        //Verifica se tem a qtde. suficiente em estoque para reservar
                        If aEstoque[nY][5][nZ][2] >= aEstoque[nY][6] .And. aEstoque[nY][5][nZ][1] == aEstoque[nY][9]
                            aEstoque[nY][5][nZ][2] -= aEstoque[nY][6] //Subtrai a qtde
                            lTemEstoque := .T.
                            Exit
                        EndIf

                    Next nZ

                    If lTemEstoque
                        aEstoque[nY][1] := .T. //Seleciona
                        Exit
                    EndIf

                EndIf

            Next nY

            If !lTemEstoque
                aAdd( aPrdSemEst, AllTrim(cProduto) + " - " + AllTrim(Posicione("SB1",1,xFilial("SB1")+cProduto,"B1_DESC")) )
            EndIf

        Next nX

        lConfirma := .T.

        //Se nao tem estoque suficiente para reservar todos os produtos, entao aborta todas as reservas
        If Len(aPrdSemEst) > 0
            cMsg := "Não existe estoque suficiente para o(s) seguinte(s) produto(s):" + Chr(13) + Chr(10) + Chr(13) + Chr(10)
            For nX:=1 To Len(aPrdSemEst)
                cMsg += aPrdSemEst[nX] + Chr(13) + Chr(10)
            Next nX
            Alert(cMsg)
            aEstoque := aEstoqBKP //Devolve o array sem alteracoes
            lConfirma := .F. //Cancela
        EndIf

EndCase

aRet := { lConfirma, aLojas, aProdutos, aEstoque }

Return aRet

//----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

Caso haja a necessidade de utilizar outro tipo de reserva ou entrega, usar como exemplo o Tipo de entrega 5, como é mostrado na imagemabaixo:

Image RemovedImage Added

Importante:

Para utilizar este ponto de entrada é necessário que o parâmetro MV_LJRESER esteja configurado como "2" ou "3"..