Histórico da Página

User Function MinhaSaidaRemessa()

    Local xAutoCab := {}
	Local xAutoItens := {}
	Local lMsErroAuto := .f.
	Local aRotina := {}
	Private cCadastro := "Saida por remessa" 

    //Cabeçalho
	aAdd(xAutoCab,{"VV0_FILIAL"  ,xFilial("VV0")		,Nil}) // Filial
	aAdd(xAutoCab,{"VV0_FORPRO"  ,"1"   		 		,Nil}) // Formulário próprio     1 - Sim / 2 - Não 
	aAdd(xAutoCab,{"VV0_CLIFOR"  ,"C"				    ,Nil}) // Cliente ou fornecedor  C - Cliente / F- Fornecedor
	aAdd(xAutoCab,{"VV0_CODCLI"  ,"000001"		        ,Nil}) // Código do Cliente deve existir na base
	aAdd(xAutoCab,{"VV0_LOJA"    ,"01"          		,Nil}) // Loja
	aAdd(xAutoCab,{"VV0_FORPAG"  ,"004"					,Nil}) // Forma de pagamento
	aAdd(xAutoCab,{"VV0_NATFIN"  ,"VENDA"				,Nil}) // Natureza de venda
	aAdd(xAutoCab,{"VV0_CODVEN"  ,"000001"				,Nil}) // Código de vendedor 

    //Itens da Remessa
	xAutoIt := {}
	aAdd(xAutoIt,{"VVA_FILIAL"  ,xFilial("VVA")		,Nil}) // Filial 
	aAdd(xAutoIt,{"VVA_CHASSI"  ,"CHASSI290420251" 	,Nil}) // Chassi 
	aAdd(xAutoIt,{"VVA_CODTES"  ,"501"		,Nil}) // Código de tes (Tipo de entrada e saída)
	aAdd(xAutoIt,{"VVA_VALDES"  ,0	,Nil})  // Valor de desconto
	aAdd(xAutoIt,{"VVA_VALMOV"  ,20000		,Nil}) // Valor do movimento

	aAdd(xAutoItens,xAutoIt)

    MSExecAuto({|x,y,w,z,k,l,m,n,o,p,q| VEIXX001(x,y,w,z,k,l,m,n,o,p,q)},xAutoCab,xAutoItens,{},3,"3",NIL,,{},,,"VEIXA013" )

    If lMsErroAuto
		DisarmTransaction()
		MostraErro()
        Return
    Else
	    MsgInfo("Registro salvo com sucesso","Atenção")
    EndIf

Return()

User Function MinhaSaidaRemessaCancelada()

    Local xAutoCab := {} // Campos Cabecalho
    Local xAutoItens := {} // Campos Itens
    Local xAutoIt := {}

    Local aParParamBox := {}
    Local aRetParamBox := {}

    Private lMsErroAuto := .f.
    Private cCadastro := "Saida por remessa" 

    // Montagem de parambox para selecionar a NF 
    AADD( aParParamBox , { 1 , RetTitle("F2_DOC") , Space(TamSX3("F2_DOC" )[1]) , "" , "" , "" , "" , 40 , .T. } )
    AADD( aParParamBox , { 1 , RetTitle("F2_SERIE") , Space(TamSX3("F2_SERIE" )[1]) , "" , "" , "" , "" , 40 , .T. } )
    AADD( aParParamBox , { 1 , RetTitle("F2_CLIENTE") , Space(TamSX3("F2_CLIENTE")[1]) , "" , "" , "" , "" , 40 , .T. } )
    AADD( aParParamBox , { 1 , RetTitle("F2_LOJA") , Space(TamSX3("F2_LOJA" )[1]) , "" , "" , "" , "" , 40 , .T. } )

    If ! ParamBox(aParParamBox,"Saida Veiculo - NF",@aRetParamBox,,,,,,,, .f., .f.)
        Return
    EndIf

    cNota := aRetParamBox[1] + aRetParamBox[2] + aRetParamBox[3] + aRetParamBox[4]

    SF2->(dbSetOrder(1))
    If ! SF2->(dbSeek(xFilial("SF2") + cNota ))
        MsgStop("Nota fiscal não encontrada")
        Return
    EndIf

    cPergunta := "Nota: " + SF2->F2_SERIE + " - " + SF2->F2_DOC + CHR(13) + CHR(10) + "Fornecedor: " + SF2->F2_CLIENTE + " - " + SF2->F2_LOJA

    If ! MsgYesNo("Confirma Cancelamento da nota fiscal " + chr(13) + chr(10) + chr(13) + chr(10) + cPergunta )
        Return
    EndIf

    aAdd(xAutoCab, { 'VV0_NUMNFI'   , SF2->F2_DOC , NIL } ) // Numero da nota fiscal 
    aAdd(xAutoCab, { 'VV0_SERNFI'   , SF2->F2_SERIE , NIL } ) // Serie da bota fiscal
    aAdd(xAutoCab, { 'VV0_CODCLI'   , SF2->F2_CLIENTE , NIL } ) // Codigo do cliente
    aAdd(xAutoCab, { 'VV0_LOJA'     , SF2->F2_LOJA , NIL } ) // Loja do cliente
    aAdd(xAutoCab, { 'VV0_NUMTRA'   , '0000000754', NIL } ) //Numero da transação 

    MSExecAuto({ |a,b,c,d,e,f,g,h,i,j,k| VEIXX001(a,b,c,d,e,f,g,h,i,j,k) },xAutoCab,{} ,{} ,5,"3" ,NIL,.f.,{},,,"VEIXA013")

    If lMsErroAuto
        DisarmTransaction()
		MostraErro()
        Return
    Else
        MsgInfo("Movimento cancelado com sucesso.")
    EndIf

Return ()