Histórico da Página

Função: MATA120 - Pedido de Compras

Versões:	Microsiga Protheus 8.11, Protheus 10, Protheus 11, Protheus 12
Compatível Países:	Todos
Sistemas Operacionais:	Todos
Compatível às bases de dados:	Todos
Nivel de Acesso:	Nivel 1 (Acesso Clientes)
Idiomas:	Todos

Descrição:

Essa rotina permite o registro de qualquer Pedido de Compras de mercadorias na empresa. O cadastro do Pedido de Compras é o contrato formal entre empresa e o fornecedor

Programa Fonte:

MATA120.PRX

Sintaxe:

MATA120 - Pedido de Compras ( [ ExpN1 ] [ ExpA1 ] [ ExpA2 ] [ ExpN2 ] [ ExpL1 ] [ ExpA3] [ ExpA4 ] [ ExpA5 ])

Nome	Tipo	Descrição	Default	Obrigatório	Referência
ExpN1	Numérico	Pedido de Compras ou Autorização de Entrega
ExpA1	Array	Cabeçalho do PC ou AE
ExpA2	Array	Itens do PC ou AE
ExpN2	Numérico	Opção da rotina automática			3 - Inclusão 4 - Alteração 5 - Exclusão
ExpL1	Lógico	Apresenta Dialog (Tela) da rotina automática
ExpA3	Array	Rateio de Centro de Custo
ExpA4	Array	Adiantamento
ExpA5	Array	Rateio de Projeto

Retorno

L (Logico) = .T. (Apresentou erro) / .F. (OK)

Observações:

Informações

title	Campos cabeçalho

Os campos de cabeçalho do Pedido de Compras (C7_EMISSAO / C7_FORNECE / C7_LOJA / C7_COND / C7_CONTATO / C7_FILENT) deverão ser obrigatoriamente informados nesta rotina.

Informações

title	Campos obrigatórios - Itens

Os campos de itens do Pedido de Compras (C7_PRODUTO / C7_QUANT / C7_PRECO / C7_TOTAL) deverão ser obrigatoriamente informados nesta rotina.

Informações

title	Moeda

Se informar o campo (C7_MOEDA), o campo (C7_TXMOEDA) também devera ser informado nos itens do pedido.

Informações

title	Alterar ou Excluir pedido

Se for alterar ou excluir um pedido de compra, o campo (C7_REC_WT) tem que estar preenchido com o numero do registro (SC7->(Recno())

Alteração de Pedido de Compras:

Para alterar/excluir item já existente no Pedido de Compras, deve-se utilizar o LINPOS e AUTODELETA

Para incluir um novo item em um pedido já existente, deve-se informar o campo (C7_ITEM) com um registro novo, e NÃO utilizar o LINPOS e AUTODELETA.

Informações

title	Vinculo para atender solicitação de compras

Para que seja atendida a SC, deve-se informar os seguintes campos nos itens do PC.

C7_NUMSC (Numero da solicitação) = Informar o numero da solicitação de Compras que originou o Pedido de Compras

C7_ITEMSC (Item da solicitação) = Informar o item da solicitação de compras que esta vinculada ao Pedido de Compras

C7_QTDSOL (Quantidade pedido da SC) = Informar a quantidade da solicitação de compras vinculada ao Pedido de Compras

Informações

title	Rateio - Centro de Custo

O array de centro de custo deve ser passado com todos os campos e seguindo a mesma ordem do exemplo abaixo

Informações

title	Rateio - Projeto

(Opção disponível a partir da versão 11)

O array de projeto deve ser passado com todos os campos e seguindo a mesma ordem do exemplo abaixo.

Informações

title	Adiantamento

O array de adiantamento deve ser passado com todos os campos e seguindo a mesma ordem do exemplo abaixo.

Informações

title	Inicializando Ambiente

PREPARE ENVIRONMENT

Na preparação do ambiente deve ser utilizado o usuário e senha, pois o sistema utiliza o usuário do sistema(RetCodUsr()) para realizar a gravação do campo C7_USER.
Exemplo:

PREPARE ENVIRONMENT EMPRESA "01" FILIAL "1001" USER "usuário" PASSWORD "****" MODULO "COM"

Informações

title	Valor Frete

As informações do frete devem ser enviadas no cabeçalho do pedido de compras.

C7_TPFRETE (Tipo Frete)

C7_FRETE (Valor Frete)

Observação: O valor informado no campo C7_FRETE (Valor Frete) corresponde ao valor TOTAL do frete daquele pedido, então se houver 2 ou mais itens esse valor sera rateado entre a quantidade de itens do pedido e seu valor ficar salvo no campo C7_VALFRE (Valor Frete)

Ex:

C7_FRETE = 10 e PC tem 1 Item

C7_VALFRE (Valor Frete) = 10

C7_FRETE = 20 e PC tem 4 Itens

C7_VALFRE (Valor Frete) = 5 (Em cada item, totalizando os 20 informados no C7_FRETE)

Informações

title	Descontos

As informações de desconto devem ser enviadas no cabeçalho ou itens do pedido de compras.

Informadas via cabeçalho:

C7_DESC1 / C7_DESC2 / C7_DESC3

Informadas via itens:

C7_VLDESC / C7_DESC

Observação:

A porcentagem informada no campo C7_DESC1, será aplicada em cada item do pedido.

A porcentagem do campo C7_DESC2, será aplicado ao valor menos o informado no campo C7_DESC1.

A porcentagem do campo C7_DESC3, será aplicado ao valor menos o informado no campo C7_DESC1 menos o informado no C7_DESC2.

Ex:

Item 0001 - Total: 1000,00

Item 0002 - Total: 2000,00

C7_DESC1 = 10%

C7_DESC2 = 20%

C7_DESC3 = 50%

Calculo após C7_DESC1 = 10%

Item 0001 = 1000*10/100 = 100,00

Item 0002 = 2000*10/100 = 200,00

Total de desconto = R$ 300,00, Total do Pedido: R$ 2700,00

Calculo após C7_DESC2 = 20%

Item 0001 = 900*20/100 = 180,00

Item 0002 = 1800*20/100 = 360,00

Total de desconto = R$ 840,00, Total do Pedido: R$ 2160,00

Calculo após C7_DESC3 = 50%

Item 0001 = 720*50/100 = 360,00

Item 0002 = 1440*10/100 = 720,00

Total de desconto = R$ 1920,00, Total do Pedido: R$ 1080,00

Exemplos:

Bloco de código

language	delphi
theme	Midnight
title	Inclusão PC - Rateio de CC / Projeto / Adiantamento
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User FUnction EXEC121()

Local aCabec := {}
Local aItens := {}
Local aLinha := {}
Local aRatCC := {}
Local aRatPrj := {}
Local aAdtPC := {}
Local aItemPrj := {{"01","02"},{"02","01"}} //Projeto, Tarefa
Local aCCusto := {{40,"01","101010","333330","CL0001"},{60,"02","101011","333330","CL0001"}} //Porcentagem,Centro de Custo, Conta Contabil, Item Conta, CLVL
Local nX := 0
Local cDoc := ""
Local nOpc := 3

PRIVATE lMsErroAuto := .F.

PREPARE ENVIRONMENT EMPRESA "01" FILIAL "1001" MODULO "COM"

dbSelectArea("SC7")

//Teste de Inclusão
cDoc := GetSXENum("SC7","C7_NUM")
SC7->(dbSetOrder(1))
While SC7->(dbSeek(xFilial("SC7")+cDoc))
ConfirmSX8()
cDoc := GetSXENum("SC7","C7_NUM")
EndDo

aadd(aCabec,{"C7_NUM" ,cDoc})
aadd(aCabec,{"C7_EMISSAO" ,dDataBase})
aadd(aCabec,{"C7_FORNECE" ,"001 "})
aadd(aCabec,{"C7_LOJA" ,"01"})
aadd(aCabec,{"C7_COND" ,"001"})
aadd(aCabec,{"C7_CONTATO" ,"AUTO"})
aadd(aCabec,{"C7_FILENT" ,cFilAnt})
aadd(aCabec,{"C7_TPFRETE" ,"C"})
aadd(aCabec,{"C7_FRETE" ,15})

For nX := 1 To 1
aLinha := {}
aadd(aLinha,{"C7_PRODUTO" ,"0001",Nil})
aadd(aLinha,{"C7_QUANT" ,1 ,Nil})
aadd(aLinha,{"C7_PRECO" ,100 ,Nil})
aadd(aLinha,{"C7_TOTAL" ,100 ,Nil})
aadd(aItens,aLinha)
Next nX

//Rateio Centro de Custo
aAdd(aRatCC, Array(2))
aRatCC[1][1] := "0001"
aRatCC[1][2] := {}

For nX := 1 To Len(aCCusto)
aLinha := {}
aAdd(aLinha, {"CH_FILIAL" , xFilial("SCH"), Nil})
aAdd(aLinha, {"CH_ITEM" , PadL(nX, TamSx3("CH_ITEM")[1], "0"), Nil})
aAdd(aLinha, {"CH_PERC" , aCCusto[nX][1], Nil})
aAdd(aLinha, {"CH_CC" , aCCusto[nX][2], Nil})
aAdd(aLinha, {"CH_CONTA" , aCCusto[nX][3], Nil})
aAdd(aLinha, {"CH_ITEMCTA" , aCCusto[nX][4], Nil})
aAdd(aLinha, {"CH_CLVL" , aCCusto[nX][5], Nil})

aAdd(aRatCC[1][2], aClone(aLinha))
Next nX

//Rateio Projeto
aAdd(aRatPrj, Array(2))
aRatPrj[1][1] := "0001"
aRatPrj[1][2] := {}

For nX := 1 To Len(aItemPrj)
aLinha := {}
aAdd(aLinha, {"AJ7_FILIAL" , xFilial("AJ7") , Nil})
aAdd(aLinha, {"AJ7_PROJET" , aItemPrj[nX][1], Nil})
aAdd(aLinha, {"AJ7_TAREFA" , PadR(aItemPrj[nX][2],TamSX3("AF9_TAREFA")[1]), Nil})
aAdd(aLinha, {"AJ7_NUMPC" , cDoc , Nil})
aAdd(aLinha, {"AJ7_ITEMPC" , "0001" , Nil})
aAdd(aLinha, {"AJ7_COD" , "0001" , Nil})
aAdd(aLinha, {"AJ7_QUANT" , 1 , Nil})
aAdd(aLinha, {"AJ7_REVISA" , "0001" , Nil})
aAdd(aRatPrj[1][2], aClone(aLinha))
Next nX

//Adiantamento
aLinha := {}
aAdd(aLinha, {"FIE_FILIAL", xFilial("FIE"),                                                            Nil})
aAdd(aLinha, {"FIE_CART",   "P",                                                                        Nil}) // Carteira pagar
aAdd(aLinha, {"FIE_PEDIDO", "" ,                                                                       Nil}) // Não precisa, pois quem trata é a MATA120
aAdd(aLinha, {"FIE_PREFIX", PadR("A", TamSX3("FIE_PREFIX")[1]),                    Nil}) //Prefixo
aAdd(aLinha, {"FIE_NUM",    PadR("PAPC01", TamSX3("FIE_NUM")[1]),            Nil}) //Numero Titulo
aAdd(aLinha, {"FIE_PARCEL", PadR("1", TamSX3("FIE_PARCEL")[1]),                  Nil}) //Parcela
aAdd(aLinha, {"FIE_TIPO",   PadR("PA", TamSX3("FIE_TIPO")[1]),                       Nil}) //Tipo = PA
aAdd(aLinha, {"FIE_FORNEC", PadR("001 ", TamSX3("FIE_FORNEC")[1]),          Nil}) // Fornecedor
aAdd(aLinha, {"FIE_LOJA",   PadR("01", TamSX3("FIE_LOJA")[1]),                       Nil}) //Loja
aAdd(aLinha, {"FIE_VALOR",  100,                                                                     Nil}) // Valor do pa que está vinculado ao pedido
aAdd(aAdtPC, aClone(aLinha))  

MSExecAuto({|a,b,c,d,e,f,g,h| MATA120(a,b,c,d,e,f,g,h)},1,aCabec,aItens,nOpc,.F.,aRatCC,aAdtPC,aRatPrj)

If !lMsErroAuto
ConOut("Incluido PC: "+cDoc)
Else
ConOut("Erro na inclusao!")
MostraErro()
EndIf

RESET ENVIRONMENT

Return

Bloco de código

language	delphi
theme	Midnight
title	Alteração PC - Rateio de CC / Projeto / Adiantamento
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User FUnction EXEC121()

Local aCabec := {}
Local aItens := {}
Local aLinha := {}
Local aRatCC := {}
Local aRatPrj := {}
Local aAdtPC := {}
Local aItemPrj := {{"01","02"},{"02","01"}} //Projeto, Tarefa
Local aCCusto := {{40,"01","101010","333330","CL0001"},{60,"02","101011","333330","CL0001"}} //Porcentagem,Centro de Custo, Conta Contabil, Item Conta, CLVL
Local nX := 0
Local cDoc := ""
Local nOpc := 4

PRIVATE lMsErroAuto := .F.

PREPARE ENVIRONMENT EMPRESA "01" FILIAL "1001" MODULO "COM"

dbSelectArea("SC7")

//Teste de alteração
cDoc := "000054" //Informar PC ou AE (Alteração / Exclusão)

aadd(aCabec,{"C7_NUM" ,cDoc})
aadd(aCabec,{"C7_EMISSAO" ,dDataBase})
aadd(aCabec,{"C7_FORNECE" ,"001 "})
aadd(aCabec,{"C7_LOJA" ,"01"})
aadd(aCabec,{"C7_COND" ,"006"}) // Condição de pagamento que permite adiantamento
aadd(aCabec,{"C7_CONTATO" ,"AUTO"})
aadd(aCabec,{"C7_FILENT" ,cFilAnt})

aLinha := {}

// Alterar item existente
aadd(aLinha,{"C7_ITEM" ,"0001" ,Nil})
aadd(aLinha,{"C7_PRODUTO" ,"0001",Nil})
aadd(aLinha,{"C7_QUANT" ,10,Nil})
aadd(aLinha,{"C7_PRECO" ,10 ,Nil})
aadd(aLinha,{"C7_TOTAL" ,100 ,Nil})
aAdd(aLinha,{"LINPOS","C7_ITEM" ,"0001"})
aAdd(aLinha,{"AUTDELETA","N" ,Nil})
aadd(aItens,aLinha)

aLinha := {}
// Incluir novo item no pedido
aadd(aLinha,{"C7_ITEM" ,"0002" ,Nil})
aadd(aLinha,{"C7_PRODUTO" ,"0002",Nil})
aadd(aLinha,{"C7_QUANT" ,20,Nil})
aadd(aLinha,{"C7_PRECO" ,10 ,Nil})
aadd(aLinha,{"C7_TOTAL" ,200 ,Nil}) 

aadd(aItens,aLinha)

//alterado Rateio Centro de Custo do item existente
aAdd(aRatCC, Array(2))
aRatCC[1][1] := "0001"
aRatCC[1][2] := {}

For nX := 1 To Len(aCCusto)
aLinha := {}
aAdd(aLinha, {"CH_FILIAL" , xFilial("SCH"), Nil})
aAdd(aLinha, {"CH_ITEM" , PadL(nX, TamSx3("CH_ITEM")[1], "0"), Nil})
aAdd(aLinha, {"CH_PERC" , aCCusto[nX][1], Nil})
aAdd(aLinha, {"CH_CC" , aCCusto[nX][2], Nil})

aAdd(aRatCC[1][2], aClone(aLinha))
Next nX

//Rateio Centro de Custo novo item
aAdd(aRatCC, Array(2))
aRatCC[2][1] := "0002"
aRatCC[2][2] := {}

For nX := 1 To Len(aCCusto)
aLinha := {}
aAdd(aLinha, {"CH_FILIAL" , xFilial("SCH"), Nil})
aAdd(aLinha, {"CH_ITEM" , PadL(nX, TamSx3("CH_ITEM")[1], "0"), Nil})
aAdd(aLinha, {"CH_PERC" , aCCusto[nX][1], Nil})
aAdd(aLinha, {"CH_CC" , aCCusto[nX][2], Nil})

aAdd(aRatCC[2][2], aClone(aLinha))
Next nX
// pa já existente no financeiro.
aLinha := {}
aAdd(aLinha, {"FIE_FILIAL", xFilial("FIE"),                                 Nil})
aAdd(aLinha, {"FIE_CART",   "P",                                            Nil}) // Carteira pagar
aAdd(aLinha, {"FIE_PEDIDO", cDoc,                                           Nil}) // Numero pedido de compras
aAdd(aLinha, {"FIE_PREFIX", PadR("A", TamSX3("FIE_PREFIX")[1]),             Nil}) //Prefixo
aAdd(aLinha, {"FIE_NUM",    PadR("PAPC01", TamSX3("FIE_NUM")[1]),           Nil}) //Numero Titulo
aAdd(aLinha, {"FIE_PARCEL", PadR("1", TamSX3("FIE_PARCEL")[1]),             Nil}) //Parcela
aAdd(aLinha, {"FIE_TIPO",   PadR("PA", TamSX3("FIE_TIPO")[1]),              Nil}) //Tipo = PA
aAdd(aLinha, {"FIE_FORNEC", PadR("001", TamSX3("FIE_FORNEC")[1]),        Nil}) // Fornecedor
aAdd(aLinha, {"FIE_LOJA",   PadR("01", TamSX3("FIE_LOJA")[1]),              Nil}) //Loja
aAdd(aLinha, {"FIE_VALOR",  300,                                            Nil}) // Valor do pa que está vinculado ao pedido
aAdd(aAdtPC, aClone(aLinha))  

MSExecAuto({|a,b,c,d,e,f,g,h| MATA120(a,b,c,d,e,f,g,h)},1,aCabec,aItens,nOpc,.F.,aRatCC,aAdtPC)
If !lMsErroAuto
ConOut("Alterado PC: "+cDoc)
Else
ConOut("Erro na alteracao!")
MostraErro()
EndIf

RESET ENVIRONMENT

Return

Bloco de código

language	delphi
theme	Midnight
title	Exclusão PC
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User FUnction EXEC121()

Local aCabec := {}
Local aItens := {}
Local aLinha := {}
Local aRatCC := {}
Local aRatPrj := {}
Local aAdtPC := {}
Local aItemPrj := {{"01","02"},{"02","01"}} //Projeto, Tarefa
Local aCCusto := {{40,"01","101010","333330","CL0001"},{60,"02","101011","333330","CL0001"}} //Porcentagem, Centro de Custo, Conta Contábil, Item Conta, CLVL
Local nX := 0
Local nOpc := 5
Local cDoc := "000054" 

PREPARE ENVIRONMENT EMPRESA "01" FILIAL "1001" MODULO "COM"

dbSelectArea("SC7")

aadd(aCabec,{"C7_NUM" ,cDoc})
aadd(aCabec,{"C7_EMISSAO" ,dDataBase})
aadd(aCabec,{"C7_FORNECE" ,"001 "})
aadd(aCabec,{"C7_LOJA" ,"01"})
aadd(aCabec,{"C7_COND" ,"001"})
aadd(aCabec,{"C7_CONTATO" ,"AUTO"})
aadd(aCabec,{"C7_FILENT" ,cFilAnt})

For nX := 1 To 1
aLinha := {}

aadd(aLinha,{"C7_ITEM" ,StrZero(nX,4) ,Nil})
aadd(aLinha,{"C7_PRODUTO" ,StrZero(nX,4),Nil})
aadd(aLinha,{"C7_QUANT" ,1 ,Nil})
aadd(aLinha,{"C7_PRECO" ,150 ,Nil})
aadd(aLinha,{"C7_TOTAL" ,150 ,Nil})
aadd(aItens,aLinha)
Next nX

MSExecAuto({|a,b,c,d,e| MATA120(a,b,c,d,e)},1,aCabec,aItens,nOpc,.F.)

If !lMsErroAuto
ConOut("Exclusao PC: "+cDoc)
Else
ConOut("Erro na exclusão!")
MostraErro()
EndIf

RESET ENVIRONMENT

Return

Bloco de código

language	delphi
theme	Midnight
title	Inclusão PC com desconto item (C7_VLDESC)
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User Function EXEC120()

Local aCabec 	:= {}
Local aItens 	:= {}
Local aLinha 	:= {}
Local nX 		:= 0
Local cDoc 		:= ""
Local nOpc		:= 3

PRIVATE lMsErroAuto := .F.

PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "COM" 

dbSelectArea("SC7")

//Teste de Inclusão 
If nOpc == 3
	cDoc := GetSXENum("SC7","C7_NUM")		
	SC7->(dbSetOrder(1))		
	While SC7->(dbSeek(xFilial("SC7")+cDoc))			
		ConfirmSX8()			
		cDoc := GetSXENum("SC7","C7_NUM")	
	EndDo
Endif

aadd(aCabec,{"C7_NUM" 		,cDoc})
aadd(aCabec,{"C7_EMISSAO" 	,dDataBase})
aadd(aCabec,{"C7_FORNECE" 	,"COM002"})
aadd(aCabec,{"C7_LOJA" 		,"01"})
aadd(aCabec,{"C7_COND" 		,"000"})
aadd(aCabec,{"C7_CONTATO" 	,"AUTO"})
aadd(aCabec,{"C7_FILENT" 	,cFilAnt})
	
For nX := 1 To 2 
	aLinha := {}
	aadd(aLinha,{"C7_ITEM" ,StrZero(nX,TamSX3("C7_ITEM")[1]),Nil})
	aadd(aLinha,{"C7_PRODUTO" ,"01",Nil})
	aadd(aLinha,{"C7_QUANT" ,1 ,Nil})
	aadd(aLinha,{"C7_PRECO" ,nX*1000 ,Nil})
	aadd(aLinha,{"C7_TOTAL" ,nX*1000 ,Nil}) 
	
	If nX == 1
		aadd(aLinha,{"C7_VLDESC" ,150 ,Nil}) 
	Endif

	aadd(aItens,aLinha) 
Next nX 

MSExecAuto({|a,b,c,d,e,f,g| MATA120(a,b,c,d)},1,aCabec,aItens,nOpc)  
	
If !lMsErroAuto 
	ConOut("Incluido PC: " + cDoc) 
Else
	ConOut("Erro na inclusao!")   
	MostraErro()
EndIf

RESET ENVIRONMENT

Return

Bloco de código

language	delphi
theme	Midnight
title	Inclusão PC com desconto item (C7_DESC)
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User Function EXEC120()

Local aCabec 	:= {}
Local aItens 	:= {}
Local aLinha 	:= {}
Local nX 		:= 0
Local cDoc 		:= ""
Local nOpc		:= 3

PRIVATE lMsErroAuto := .F.

PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "COM" 

dbSelectArea("SC7")

//Teste de Inclusão 
If nOpc == 3
	cDoc := GetSXENum("SC7","C7_NUM")		
	SC7->(dbSetOrder(1))		
	While SC7->(dbSeek(xFilial("SC7")+cDoc))			
		ConfirmSX8()			
		cDoc := GetSXENum("SC7","C7_NUM")	
	EndDo
Endif

aadd(aCabec,{"C7_NUM" 		,cDoc})
aadd(aCabec,{"C7_EMISSAO" 	,dDataBase})
aadd(aCabec,{"C7_FORNECE" 	,"COM002"})
aadd(aCabec,{"C7_LOJA" 		,"01"})
aadd(aCabec,{"C7_COND" 		,"000"})
aadd(aCabec,{"C7_CONTATO" 	,"AUTO"})
aadd(aCabec,{"C7_FILENT" 	,cFilAnt})
	
For nX := 1 To 2 
	aLinha := {}
	aadd(aLinha,{"C7_ITEM" ,StrZero(nX,TamSX3("C7_ITEM")[1]),Nil})
	aadd(aLinha,{"C7_PRODUTO" ,"01",Nil})
	aadd(aLinha,{"C7_QUANT" ,1 ,Nil})
	aadd(aLinha,{"C7_PRECO" ,nX*1000 ,Nil})
	aadd(aLinha,{"C7_TOTAL" ,nX*1000 ,Nil}) 
	
	If nX == 1
		aadd(aLinha,{"C7_DESC" ,20 ,Nil}) //Porcentagem
	Endif

	aadd(aItens,aLinha) 
Next nX 

MSExecAuto({|a,b,c,d,e,f,g| MATA120(a,b,c,d)},1,aCabec,aItens,nOpc)  
	
If !lMsErroAuto 
	ConOut("Incluido PC: " + cDoc) 
Else
	ConOut("Erro na inclusao!")   
	MostraErro()
EndIf

RESET ENVIRONMENT

Return

Bloco de código

language	delphi
theme	Midnight
title	Inclusão PC com desconto item (C7_VLDESC/C7_DESC)
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User Function EXEC120()

Local aCabec 	:= {}
Local aItens 	:= {}
Local aLinha 	:= {}
Local nX 		:= 0
Local cDoc 		:= ""
Local nOpc		:= 3

PRIVATE lMsErroAuto := .F.

PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "COM" 

dbSelectArea("SC7")

//Teste de Inclusão 
If nOpc == 3
	cDoc := GetSXENum("SC7","C7_NUM")		
	SC7->(dbSetOrder(1))		
	While SC7->(dbSeek(xFilial("SC7")+cDoc))			
		ConfirmSX8()			
		cDoc := GetSXENum("SC7","C7_NUM")	
	EndDo
Endif

aadd(aCabec,{"C7_NUM" 		,cDoc})
aadd(aCabec,{"C7_EMISSAO" 	,dDataBase})
aadd(aCabec,{"C7_FORNECE" 	,"COM002"})
aadd(aCabec,{"C7_LOJA" 		,"01"})
aadd(aCabec,{"C7_COND" 		,"000"})
aadd(aCabec,{"C7_CONTATO" 	,"AUTO"})
aadd(aCabec,{"C7_FILENT" 	,cFilAnt})
	
For nX := 1 To 2 
	aLinha := {}
	aadd(aLinha,{"C7_ITEM" ,StrZero(nX,TamSX3("C7_ITEM")[1]),Nil})
	aadd(aLinha,{"C7_PRODUTO" ,"01",Nil})
	aadd(aLinha,{"C7_QUANT" ,1 ,Nil})
	aadd(aLinha,{"C7_PRECO" ,nX*1000 ,Nil})
	aadd(aLinha,{"C7_TOTAL" ,nX*1000 ,Nil}) 
	
	If nX == 1
		aadd(aLinha,{"C7_VLDESC" ,300 ,Nil})
		aadd(aLinha,{"C7_DESC" ,30 ,Nil}) //Porcentagem
		aadd(aItens,aLinha) 
	Endif
Next nX 

MSExecAuto({|a,b,c,d,e,f,g| MATA120(a,b,c,d)},1,aCabec,aItens,nOpc)  
	
If !lMsErroAuto 
	ConOut("Incluido PC: " + cDoc) 
Else
	ConOut("Erro na inclusao!")   
	MostraErro()
EndIf

RESET ENVIRONMENT

Return

Bloco de código

language	delphi
theme	Midnight
title	Inclusão PC com desconto cabeçalho (C7_DESC1/C7_DESC2/C7_DESC3)
collapse	true

#Include "Protheus.ch"
#Include "RwMake.ch"
#Include "TbiConn.ch"

User Function EXEC120()

Local aCabec 	:= {}
Local aItens 	:= {}
Local aLinha 	:= {}
Local nX 		:= 0
Local cDoc 		:= ""
Local nOpc		:= 3

PRIVATE lMsErroAuto := .F.

PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "COM" 

dbSelectArea("SC7")

//Teste de Inclusão 
If nOpc == 3
	cDoc := GetSXENum("SC7","C7_NUM")		
	SC7->(dbSetOrder(1))		
	While SC7->(dbSeek(xFilial("SC7")+cDoc))			
		ConfirmSX8()			
		cDoc := GetSXENum("SC7","C7_NUM")	
	EndDo
Endif

aadd(aCabec,{"C7_NUM" 		,cDoc})
aadd(aCabec,{"C7_EMISSAO" 	,dDataBase})
aadd(aCabec,{"C7_FORNECE" 	,"COM002"})
aadd(aCabec,{"C7_LOJA" 		,"01"})
aadd(aCabec,{"C7_COND" 		,"000"})
aadd(aCabec,{"C7_CONTATO" 	,"AUTO"})
aadd(aCabec,{"C7_FILENT" 	,cFilAnt})
aadd(aCabec,{"C7_DESC1" 	,10})
aadd(aCabec,{"C7_DESC2" 	,20})
aadd(aCabec,{"C7_DESC3" 	,50})

For nX := 1 To 2 
	aLinha := {}
	aadd(aLinha,{"C7_ITEM" ,StrZero(nX,TamSX3("C7_ITEM")[1]),Nil})
	aadd(aLinha,{"C7_PRODUTO" ,"01",Nil})
	aadd(aLinha,{"C7_QUANT" ,1 ,Nil})
	aadd(aLinha,{"C7_PRECO" ,nX*1000 ,Nil})
	aadd(aLinha,{"C7_TOTAL" ,nX*1000 ,Nil}) 
Next nX 

MSExecAuto({|a,b,c,d,e,f,g| MATA120(a,b,c,d)},1,aCabec,aItens,nOpc)  
	
If !lMsErroAuto 
	ConOut("Incluido PC: " + cDoc) 
Else
	ConOut("Erro na inclusao!")   
	MostraErro()
EndIf

RESET ENVIRONMENT

Return

Función: MATA120 - Pedido de compras

...

Atalhos

Árvore de páginas

Versões comparadas

Versão antiga 11

Nova versão 12

Chave