Para uma lista com o De/Para dos pontos de entrada do CNTA120 para o CNTA121, acessar a página GCT0084_Nova_Medição_CNTA121

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
	Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada CN130INC
*/
User Function CNTA121()
	Local aParam 	:= PARAMIXB
	Local xRet 		:= .T.
	Local oModel 	:= Nil
	Local oModelCND	:= Nil
	Local oModelCNE	:= Nil
	Local cIdPonto 	:= ''
	Local cIdModel	:= ''
	Local cCampo	:= ""
	Local cAction	:= ""
	Local xValue	:= 0

	If aParam <> NIL
		oModel  := aParam[1]
		cIdPonto:= AllTrim(aParam[2])
		cIdModel:= aParam[3]
		If(cIdModel == 'CNEDETAIL')
			oModelCNE := oModel //Qnd cIdModel for CNEDETAIl, oModel será o submodelo(FwFormGridModel) da CNE

			If cIdPonto == "FORMPRE"
				//
			ElseIf cIdPonto == "FORMLINEPRE"
				cAction := aParam[5]
				cCampo	:= aParam[6]

				If cAction == "SETVALUE"
					//
				Elseif cAction == "CANSETVALUE"
					//
				EndIf
			ElseIf cIdPonto == "FORMLINEPOS"//Será ativado 1x por linha			

				oModelCND := oModelCNE:GetModel():GetModel("CNDMASTER")//Obtêm o modelo da CND, com ele é possível verificar valores da CND

				/*Abaixo um exemplo de como informar valores para campos(que poderia ser um campo de usuário).*/
				If oModelCNE:GetValue("CNE_VLUNIT") > 100
					oModelCNE:LoadValue("CNE_CC", "GCT000001")	
				Else
					oModelCNE:LoadValue("CNE_CC", "GCT000002")
				EndIf
			EndIf			
		ElseIf(cIdModel == 'CNDMASTER')//Cabeçalho
			oModelCND := oModel //Qnd cIdModel for CNDMASTER, oModel será o submodelo(FWFormModel) da CND
			If cIdPonto == "FORMPRE"
				cAction := aParam[4]
				cCampo	:= aParam[5]
				xValue	:= aParam[6]

				If cAction == "SETVALUE"
					If cCampo == "CND_CONTRA"//Ao preencher o contrato
						oModel:LoadValue("CND_OBS", "Observacao") 
					EndIf
				Elseif cAction == "CANSETVALUE"
					//
				EndIf
			EndIf
		EndIf
	EndIf
Return xRet

#include "PROTHEUS.CH"
#INCLUDE "FWMVCDEF.CH"
#INCLUDE "RWMAKE.CH"
#INCLUDE "TBICONN.CH"

User Function CNTA121()
    Local aParam    := PARAMIXB
    Local xRet      := .T.
    Local oModelCND := Nil    
    Local cIdPonto  := ''
    Local cIdModel  := ''
    Local lIsInsert	:= .F.
 
    If aParam <> NIL        
        cIdPonto:= AllTrim(aParam[2])
        cIdModel:= aParam[3]		
		If (cIdPonto == "FORMCOMMITTTSPRE" .And. cIdModel == "CNDMASTER")//FORMCOMMITTTSPRE: Antes da gravação da tabela do formulário. Equivalente ao MD130GRV
		    oModelCND	:= aParam[1]			
			lIsInsert	:= aParam[4]
			
			If lIsInsert .And. AllTrim(oModelCND:GetValue("CND_SITUAC")) == "B"
				oModelCND:LoadValue("CND_SITUAC", "L")
			EndIf
		ElseIf (cIdPonto == "FORMCOMMITTTSPOS" .And. cIdModel == "CNDMASTER")//FORMCOMMITTTSPOS: Após a gravação da tabela do formulário. Equivalente ao CN130PGRV
		    //Lógica do usuário
		EndIf       
    EndIf
Return xRet

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
   Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada CN130BUT 
*/
User Function CNTA121()
 	 Local aParam := PARAMIXB
     Local xRet := .T.
     Local oModel := ''
     Local cIdPonto := ''
     Local cIdModel := ''
 
     If aParam <> NIL
         oModel  := aParam[1]
         cIdPonto:= aParam[2]
         cIdModel:= aParam[3]
         
         If(cIdPonto == 'BUTTONBAR')
 			xRet := { {'Botão customizado', 'BUDGET', { |x| U_Exemplo(x) }, 'Botão customizado' } } //Uma opção nova será adicionada ao menu Outras Ações
         EndIf
     EndIf
 Return xRet

User Function Exemplo(oView)
 	Local oModel	:= oView:GetModel()	
	Local nOpc		:= oModel:GetOperation()	

	Alert( 'Ação customizada.' )

Return 

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
	Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada C130KDEL
*/ 
User Function CNTA121()
    Local aParam    := PARAMIXB
    Local xRet      := .T.
    Local oModelCNE	:= Nil
    Local cIdPonto  := ''
    Local cIdModel  := ''
    Local cAction	:= ""
 
    If aParam <> NIL        
        cIdPonto:= AllTrim(aParam[2])
        cIdModel:= aParam[3]		
		If (cIdPonto == "FORMLINEPRE" .And. cIdModel == "CNEDETAIL")
			oModelCNE	:= aParam[1]
			cAction		:= aParam[5]			

			If cAction == "DELETE"
				xRet := MsgYesNo("Confirma a exclusão?")
			EndIf			
		EndIf       
    EndIf
Return xRet  

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
	Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada CN130TOK
 */  
User Function CNTA121()
    Local aParam    := PARAMIXB
    Local xRet      := .T.
    Local oModel	:= Nil
    Local cIdPonto  := ''
    Local cIdModel  := ''
 
    If aParam <> NIL        
        cIdPonto:= AllTrim(aParam[2])
        cIdModel:= aParam[3]		
		If (cIdPonto == "MODELPOS")//CN130TOK
			oModel := aParam[1]//instância de MPFormModel
			if oModel:GetOperation() == MODEL_OPERATION_INSERT
				If Empty(oModel:GetValue("CNDMASTER", "CND_OBS"))
					Alert("Informe observação.")
					xRet := .F.				
				EndIf
			ElseIf oModel:GetOperation() == MODEL_OPERATION_UPDATE
				//
			ElseIf oModel:GetOperation() == MODEL_OPERATION_DELETE
				xRet := MsgYesNo("Confirma exclusão?")
			endif
		EndIf       
    EndIf
Return xRet

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
	Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada CN130VLIN
*/  
User Function CNTA121()
	Local aParam 	:= PARAMIXB
	Local xRet 		:= .T.
	Local oModel 	:= Nil	
	Local oModelCNE	:= Nil
	Local cIdPonto 	:= ''
	Local cIdModel	:= ''
	Local cCampo	:= ""
	Local cAction	:= ""
	Local lOnCheck	:= .F.

	If aParam <> NIL
		oModel  := aParam[1]
		cIdPonto:= AllTrim(aParam[2])
		cIdModel:= aParam[3]
		If(cIdModel == 'CNEDETAIL')
			oModelCNE	:= oModel //Qnd cIdModel for CNEDETAIl, oModel será o submodelo(FwFormGridModel) da CNE
			lOnCheck	:= FwIsInCallStack("CN121ITEM")//Indica que trata-se da carga dos itens ao marcar a CXN

			If cIdPonto == "FORMLINEPRE" .And. !lOnCheck
				cAction := aParam[5]
				cCampo	:= aParam[6]

				If cAction == "SETVALUE"
					//Inserir validação do valor de acordo com <cCampo>
					if cCampo == "CNE_QUANT"
						if oModelCNE:GetValue(cCampo) > 1
							//Apresentar HELP
							xRet := .F.
						endif
					endif
				Elseif cAction == "CANSETVALUE"
					//Retorna se é possível alterar o campo(WHEN) de <cCampo>, usar com cuidado pois pode impactar performance
				EndIf			
			EndIf
		EndIf
	EndIf
Return xRet

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
	Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada CN130VCK/CN130VAD
*/   
User Function CNTA121()
	Local aParam 	:= PARAMIXB
	Local xRet 		:= .T.
	Local oModel 	:= Nil	
	Local oModelCZY	:= Nil
	Local cIdPonto 	:= ''
	Local cIdModel	:= ''
	Local cCampo	:= ""
	Local cAction	:= ""	

	If aParam <> NIL
		oModel  := aParam[1]
		cIdPonto:= AllTrim(aParam[2])
		cIdModel:= aParam[3]
		If(cIdModel == 'CZYDETAIL')//CZY = Tabela de amarração Medição x Adiantamentos(CNX)
			oModelCZY	:= oModel //Qnd cIdModel for CZYDETAIL, oModel será o submodelo(FwFormGridModel) da CZY
			If cIdPonto == "FORMLINEPRE"//CN130VCK
			    cAction := aParam[5]
				cCampo	:= aParam[6]

				If cAction == "SETVALUE"					
					if cCampo == "CZY_VALOR"
						if oModelCZY:GetValue(cCampo) > 100
							//Apresentar HELP
							xRet := .F.
						endif
					endif
				EndIf			
			ElseIf cIdPonto == "FORMPOS" //CN130VAD
				//Realizar validacao
			EndIf
		EndIf
	EndIf
Return xRet

#INCLUDE "Protheus.ch"
#INCLUDE "FWMVCDEF.CH"

/*{Protheus.doc} CNTA121()
	Possibilitar ao desenvolvedor realizar a mesma operação anteriormente feita no ponto de entrada CN130VCK/CN130MTINC 
*/    
User Function CNTA121()
	Local aParam 	:= PARAMIXB
	Local xRet 		:= .T.	
	Local cIdPonto 	:= ''
	Local cIdModel	:= ''
	Local oMdlCNQ	:= Nil
	Local oMdlCNR1	:= Nil
	Local oMdlCNR2	:= Nil

	If aParam <> NIL
		
		cIdPonto:= AllTrim(aParam[2])
		cIdModel:= aParam[3]

		If (cIdPonto == "FORMPOS" .And. cIdModel $ 'CNQDETAIL|CNRDETAIL1|CNRDETAIL2|')		
			
			If(cIdModel == 'CNQDETAIL') //Descontos
				oMdlCNQ := aParam[1]
			ElseIf(cIdModel == 'CNRDETAIL1') //Multas/Bonificacoes por Medição
				oMdlCNR1 := aParam[1]
			ElseIf(cIdModel == 'CNRDETAIL2') //Multas/Bonificacoes por Item
				oMdlCNR2 := aParam[1]
			EndIf
		endif

	EndIf
Return xRet