Linha Microsiga Protheus

Árvore de páginas

M461COR - Alteração das cores dos status do browse da Preparação do Documento de Saída

Características do Requisito

Linha de Produto:

Microsiga Protheus®

Segmento:

Serviços

Módulo:

Faturamento - SIGAFAT

Rotina:

Rotina

Nome Técnico

Preparação do Documento de Saída

MATA461

Ponto de Entrada:

M461COR

Tickets Relacionados

2433223

Requisito/Story/Issue:

DSERFAT-6369

País(es):

Todos os países

Banco(s) de Dados:

Todos os homologados

Sistema(s) Operacional(is):

Todos os homologados

Páginas relacionadas:Ponto de entrada M461LEG


Ponto de Entrada

Descrição:

Este ponto de entrada pertence à rotina de Preparação do Documento de Saída (MATA461). Ele deve ser utilizado em conjunto com o ponto M461LEG para que as cores dos status do browse da rotina da Preparação do Documento de Saída sejam customizadas.

Localização:

Atualizações → Faturamento → Documentos de Saída

Eventos:

M461COR ( < PARAMIXB> ) → aNewLegend

Parâmetros:O ponto de entrada se utiliza da variável padrão PARAMIXB que receberá a configuração padrão das regras de cada legenda da rotina, na forma de array bidimensional, para que seja possível a customização conforme a sua necessidade.

Programa Fonte:

Preparação de Documento de Saída - MATA461.PRX

Retorno:

Nome

Tipo

Descrição

Obrigatório

aNewLegend

Array

Array bidimensional com as novas regras para a aplicação das cores da legenda.

Sim


Exemplo:

#Include "protheus.ch"
User Function M461COR()
Local aNewLegend := {} // Variável que conterá o retorno das novas regras para a aplicação nas legendas do browse da rotina
//****************************************************************************************************************************************************
//---- O ParamIXB recebeu a configuração das REGRAS PADRÕES das legendas na forma de um array bidimensional
// ParamIXB := {{'Empty(SC9->C9_BLEST) .And. Empty(SC9->C9_BLCRED) .And. SC9->C9_BLWMS$"05,06,07, "',    "ENABLE"},;  // Pedido de Venda Liberado
//              {'SC9->C9_BLEST=="10" .And. SC9->C9_BLCRED=="10" .And. SC9->C9_BLWMS$"05,06,07, "',      "DISABLE"},; // Pedido de Venda Faturado
//              {'!(Empty(SC9->C9_BLEST) .And. Empty(SC9->C9_BLCRED) .And. SC9->C9_BLWMS$"05,06,07, ")', "BR_AZUL"}}  // Pedido de Venda com bloqueio
//****************************************************************************************************************************************************
aNewLegend := {{ParamIXB[01,01] + ' .And. SC9->C9_MYFIELD == "1"', ParamIXB[01,02]},;   // A regra padrão 1 para os 'Pedidos de Venda Liberados' foi modificada, acrescentando o teste do campo customizado C9_MYFIELD=="1". O seu status continuará a ser representado na legenda da cor VERDE.
               {ParamIXB[02,01] + ' .And. SC9->C9_MYFIELD == "1"', ParamIXB[02,02]},;   // A regra padrão 2 para os 'Pedidos de Venda Faturados' foi modificada, acrescentando o teste do campo customizado C9_MYFIELD=="1". O seu status continuará a ser representado na legenda da cor VERMELHA.
               {ParamIXB[03,01] + ' .And. SC9->C9_MYFIELD == "1"', ParamIXB[03,02]},;   // A regra padrão 3 para os 'Pedidos de Venda com bloqueio' foi modificada, acrescentando o teste do campo customizado C9_MYFIELD=="1". O seu status continuará a ser representado na legenda da cor AZUL.
               {ParamIXB[01,01] + ' .And. SC9->C9_MYFIELD == "2"', "BR_PINK"},;         // Nova regra para os 'Pedidos de Venda Liberados' acrescido do teste do campo customizado C9_MYFIELD=="2". O seu status será representado na legenda da cor ROSA.
               {ParamIXB[02,01] + ' .And. SC9->C9_MYFIELD == "2"', "BR_AMARELO"},;      // Nova regra para os 'Pedidos de Venda Faturados' acrescido do teste do do campo customizado C9_MYFIELD=="2". O seu status será representado na legenda da cor AMARELA.
               {ParamIXB[03,01] + ' .And. SC9->C9_MYFIELD == "2"', "BR_MARROM"}}        // Nova regra para os 'Pedidos de Venda com bloqueio' acrescido do teste do do campo customizado C9_MYFIELD=="2". O seu status será representado na legenda da cor MARROM.
Return aNewLegend

Exemplificação do Resultado

Importante

  1. A eventual customização das legendas passará pela aplicação das regras e critérios pré-estabelecidos pelas funcionalidades do Framework;
  2. É obrigatório que, o array das regras customizadas devolvido à rotina padrão pelo ponto de entrada para a aplicação de cada legenda, contenha apenas uma das regras como válida. Isto porque, a cor da legenda de cada registro do browse obedecerá sempre à primeira regra válida encontrada. Por isso, verifique sempre se a construção das regras customizadas realmente satisfazem a este princípio, caso contrário, a exibição de suas legendas pode não surtir o efeito esperado;
  3. Ao criar as legendas customizadas, as funcionalidades padrões da rotina não serão modificadas.