Linha Microsiga Protheus - Espanhol

Atalhos

Árvore de páginas

01. DATOS GENERALES

Línea de producto:Microsiga Protheus®
Segmento:Servicios
Módulo:Financiero


02. DESCRIPCIÓN

El punto de entrada FA260QBRW permite manejar la condición WHERE estándar de filtrado de los títulos que se mostrarán en el browse de la conciliación bancaria.


Informaciones

Parámetros que se pasan al punto de entrada

PARAMIXB - variable pública del tipo ARRAY, y en la posición 1 contiene la condición del WHERE estándar generada en la rutina. Modo de uso: PARAMIXB[1]


La devolución esperada por la rutina estándar del PE son las condiciones que se tratarán como filtro para la tabla SE2.


03. EJEMPLO DE UTILIZACIÓN


FA260QBRW
#INCLUDE "PROTHEUS.CH"  

user function FA260QBRW as character
Local   cWhere          :=  PARAMIXB[ 1 ]       as  character
Local   nTamCodBar	    := 0                    as  numeric
Local   nTamIdCnab	    := 0                    as  numeric
Local   dDtIni          := CToD( '  /  /  ' )   as  date
Local   dDtFin          := CToD( '  /  /  ' )   as  date

If cFilAnt == 'D MG 01 '
    nTamCodBar	:= TAMSX3("FIG_CODBAR")[1]
    nTamIdCnab	:= TAMSX3("E2_IDCNAB")[1]

    //Verifico si el parámetro De/A Vencto no está vacío
    dDtIni	    := Max(dDtIni,Iif(Empty(mv_par09),dDtIni,mv_par09))
    dDtFin	    := Max(dDtFin,Iif(Empty(mv_par10),dDtFin,mv_par10))

    // Aumento/disminuyo de las variables para abrir período
    dDtIni	    := dDtIni - mv_par14
    dDtFin	    := dDtFin + mv_par13

	cWhere      := "E2_FILIAL IN('D MG 01 ','D MG 02 ','D MG 03 ') AND "
	cWhere      += "E2_FORNECE  >= '"+ mv_par04 + "' AND "
	cWhere      += "E2_FORNECE  <= '"+ mv_par05 + "' AND "
	cWhere      += "E2_LOJA >= '"	+ mv_par06 + "' AND "
	cWhere      += "E2_LOJA <= '"	+ mv_par07 + "' AND "
	
	//Considera Vencto del título
	If mv_par08 == 1
		cWhere +=	"E2_VENCTO >= '"	+ DTOS(dDtIni) + "' AND "
		cWhere +=	"E2_VENCTO <= '"	+ DTOS(dDtFin) + "' AND "

	Else//Considera Vencto real del título
		cWhere +=	"E2_VENCREA >= '"	+ DTOS(dDtIni) + "' AND "
		cWhere +=	"E2_VENCREA <= '"	+ DTOS(dDtFin) + "' AND "

	Endif
	
	cWhere += "E2_SALDO > 0 AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MV_CPNEG+MVPAGANT,,3) + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVABATIM,'|') + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVTXA+"INA",,3) + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVTAXA,,3) + " AND "
	cWhere += "E2_TIPO NOT IN " + FORMATIN(MVPROVIS,,3) + " AND "
	cWhere += "E2_CODBAR = '"	+ Space(nTamCodbar) + "' AND "
	cWhere += "E2_IDCNAB = '"	+ Space(nTamIdCnab) + "' AND "
	cWhere += "D_E_L_E_T_ = ' ' "

EndIf

return cWhere



04. OTRAS INFORMACIONES

No hay


05. ASUNTOS RELACIONADOS

  • No hay