FINALEG - Manipula legendas do financeiro

01. DADOS GERAIS

Linha de Produto:	Microsiga Protheus®
Segmento:	Backoffice
Módulo:	Financeiro
Função:	FINA040 - Contas a Receber FINA050 - Contas a Pagar FINA070 - Baixas a Receber FINA080 - Baixas Pagar Manual FINA090 - Baixas Pagar Automática FINA110 - Baixas Automáticas de Títulos a Receber FINA200 - Retorno de Cobranças FINA240 - Borderô Pagamentos FINA241 - Borderô Com Impostos FINA250 - Rastreamento FINA290 - Faturas a Pagar FINA374 - Apuração Pis, Cofins e Csl a Pagar FINA426 FINA460 - Liquidação FINA565 - Liquidação FINA740 - Funções Contas a Receber FINA750 - Funções Contas a Pagar

02. DESCRIÇÃO

O ponto de entrada FINALEG permite alterar as legendas de diversas rotinas do financeiro, como FINA040, FNA050, FINA740, FINA750 entre outras.

Observações:

- O retorno desse ponto de entrada substituirá as regras do padrão;
- As regras de legenda são consideradas na ordem do array retornado;
- A primeira regra atendida definirá a cor que será atribuída;
- Atenção para com a ordem das regras e com regras conflitantes;
- É chamado para retornar as regras de legendas e chamado também quando acionado o botão de legendas para que seja mostrada a tela.

03. PARÂMETROS

Nome	Tipo	Descrição
PARAMIXB[1]	Numérico	Com valor: Abrir a tela de legendas; Sem valor: Retornar as regras.
PARAMIXB[2]	Caracter	SE1 ou SE2, dependendo da rotina utilizada.
PARAMIXB[3]	Array	Regras do padrão.
PARAMIXB[4]	Array	Legendas do padrão.

04. RETORNO

Tipo

Descrição

Array

Se PARAMIXB[1] igual a nil:

array[n,1] - regra da legenda
array[n,2] - cor da legenda

Se PARAMIXB[1] igual a numérico:

array[n,1] - cor da legenda
array[n,2] - descrição da legenda

05. EXEMPLO DE UTILIZAÇÃO

FINALEG

#INCLUDE "TOTVS.CH"
 
User Function FINALeg() as array
 
Local nReg := PARAMIXB[1] as numeric // Com valor: Abrir a telinha de legendas ### Sem valor: Retornar as regras
Local cAlias := PARAMIXB[2] as character // SE1 ou SE2
Local aRegras := PARAMIXB[3] as array// Regras do padrão
Local aLegendas := PARAMIXB[4] as array// Legendas do padrão
Local aRet := {} as array
Local nI := 0 as numeric
 
/*
    Sem Recno --> Retornar array com as regras para o Browse colocar as cores nas colunas.
    Com Recno --> Chamada quando acionado botão Legendas do browse -> Abrir telinha de Legendas (BrwLegenda)
*/
If nReg = Nil
 
    /*
        aRegras passado contém as regras do padrão
        O array retornado deverá conter todas as regras, do padrão e customizadas.
 
        Dicas:
        Lembrando que as regras de legenda são consideradas na ordem do array retornado.
        A Primeira regra atendida definirá a cor que será atribuída.
        Atenção para com a ordem das regras e com regras conflitantes.
        A Última regra do padrão, caso não atenda a nenhuma condição anterior é a .T. -> BR_VERDE -> Título em aberto
    */
    If cAlias = "SE1"
 
        /*
            Exemplo: adicionar uma regra de legenda "mais prioritária" que as do padrão
        */
        aAdd(aRet,{"!Empty(E1_PORTADO) .AND. Empty(E1_NUMBOR)","BR_LARANJA"})
     
        /*
            Regras do padrão para retorno
        */
        For nI := 1 To Len(aRegras)
            aAdd(aRet,{aRegras[nI][1],aRegras[nI][2]})
        Next nI
 
    Else // SE2
 
        /*
            Exemplo para retornar as mesmas regras do padrão sem alteração
        */
        aRet := aRegras
 
    Endif
 
 
Else // Abrir telinha de Legendas (BrwLegenda)
 
    If cAlias = "SE1"
 
        aAdd(aLegendas,{"BR_LARANJA","Título em Portador"})
 
    Else // SE2
        /*
            Adicionar a cor e descrição de legendas para SE2 aqui. Exemplo:
            Aadd(aLegendas, {"BR_AMARELO", "Titulo aguardando liberacao"}) //Titulo aguardando liberacao
        */
    Endif
 
    BrwLegenda(cCadastro, "Legenda", aLegendas)
 
Endif
 
Return aRet

Árvore de páginas