A partir das versões WebApp 10.1.1 e 9.2.1, foram efetuadas novas implementações. Veja Aprimoramento WebApp 10.1.1 e 9.2.1

Colapse ALL
Expand ALL

Função: cGetFile

Apresenta uma janela com os diretórios disponíveis, na estação e no servidor,  e retorna o nome do item.

Sintaxe

cGetFile ( [ cMascara], [ cTitulo], [ nMascpadrao], [ cDirinicial], [ lAbrir], [ nOpcoes], [ lArvore], [ lKeepCase] ) --> cRet
Parâmetros/Elementos

Retorno
cRet

(caracter)
• Retorna o nome do item. Caso nenhum item tenha sido selecionado, o retorna será uma string vazia.
• A partir da versão 7.00.170117A - 17.2.0.2 o nome do item irá retornar com a extensão selecionada, ou seja, quando o usuário digitar o nome de um arquivo (caso seja um "save dialog"), cRet já será com a extensão selecionada (cMascara).

Observações

Quando o parâmetro lArvore for verdadeiro (.T.) somente as pastas do rootpath do servidor serão acessíveis.

A função cGetFile exige que o programa AdvPL que a execute seja um SmartClient, não permitindo, portanto, que seja chamada em JOB. A partir da build 7.00.131227A com data de geração superior a 06/04/2016, caso a função seja chamada em JOB, o programa será finalizado com ocorrência de erro fatal "Function cGetFile() doesn't available in JOB.". Nas builds anteriores, se a função fosse chamada em JOB, era apresentada uma mensagem de erro de comunicação com o SmartClient.

No parâmetro <nOpções>, é possível determinar as seguintes funcionalidades:

Se o cInitialDir apontar para um diretório oculto ou de sistema, lembre-se de habilitar as opções correspondentes.

* Os dois parâmetros só estão disponível em builds superiores a 7.00.131227A.

cMascara

Informa descrição da máscara e máscara no formato "descrição|máscara".

Exemplos:

"Arquivos de texto|*.txt"

"*.txt | *.txt"

É possível especificar vários pares de descrição|máscara.

Exemplo:

"Arquivos de texto|*.txt|Bitmaps|*.bmp"

Se não for informada uma máscara, o campo poderá ser editado pelo usuário a fim de especificar o filtro/máscara que desejar

Disponível apenas em builds superiores a 7.00.131227A.

Compartilhamentos do Remote Desktop

No caso da função "cGetFile" precisar apresentar diretórios compartilhados via "Remote Desktop" o usuário deve mapear o endereço de rede \\tsclient\<nome da pasta compartilhada> e habilitar a opção "GETF_NETWORKDRIVE ".

#INCLUDE "TOTVS.CH"
 
User Function GetFile1()
	Local targetDir
 
	targetDir:= cGetFile( '*.txt|*.txt' , 'Textos (TXT)', 1, 'C:\', .F., nOR( GETF_LOCALHARD, GETF_LOCALFLOPPY, GETF_RETDIRECTORY ),.T., .T. )
 
	Alert(targetDir)
 
Return

#INCLUDE "TOTVS.CH"

User Function GetFile2()
	Local cMascara	:= "Todos os arquivos|."
	Local cTitulo	:= "Escolha o arquivo"
	Local nMascpad	:= 0
	Local cDirini	:= "\"
	Local lSalvar	:= .F. /*.T. = Salva || .F. = Abre*/
	Local nOpcoes	:= GETF_LOCALHARD
	Local lArvore	:= .F. /*.T. = apresenta o árvore do servidor || .F. = não apresenta*/
	Local resourceName:= "totvs.png"
	Local path := "\images\"
	Local fileName:= path + resourceName
	Local targetDir
	Local sucess

	If (!Resource2File(resourceName, fileName))
		Alert("Erro ao copiar o arquivo do repositorio!")
	EndIf

	If (GetRemoteType() == REMOTE_HTML)
		sucess:= (CpyS2TW(fileName, .T.) == 0)
	Else
		targetDir := cGetFile( cMascara, cTitulo, nMascpad, cDirIni, lSalvar, nOpcoes, lArvore)
		sucess:= CpyS2T(fileName, targetDir)
	Endif

	If (sucess)
		If (GetRemoteType() == REMOTE_HTML)
			Alert("Arquivo ''" + resourceName + "' enviado para download! " + CRLF + "Verifique se o browser nao bloqueou o popup!")
		Else
			Alert("Arquivo ''" + resourceName + "' copiado com sucesso para '" + targetDir + "'!")
		EndIf
	Else
		Alert("Erro ao copiar o arquivo ''" + resourceName + "'!")
	Endif
Return

Preview
Exemplo da função cGetFile()

Abrangência
Advanced Protheus 6.09 , Advanced Protheus 7.10 , Microsiga Protheus 8.11 , Protheus 10 , TOTVS Application Server 10 , ByYou Application Server

WebApp10.1.1 e 9.2.1

No WebApp, a partir das versões 10.1.1 e 9.2.1, foram efetuados aprimoramentos:

• Adicionado botões de acesso (em destaque) a arquivos locais, no lugar do link. 
  

• Implementado navegação por teclado na lista de arquivos.

  Tecla	Ação
  Home	Primeira linha da lista de arquivo .
  End	Última linha da lista de arquivo
  Up	Uma linha acima .
  Down	Uma linha abaixo.
  PageDown	Uma página abaixo.
  PageUp	Uma página acima
  Shift+navegação	Seleciona linhas conforme navegação, se multi-seleção ativa.
  Letra ou número	Navegação pelo primeiro caractere do nome de arquivo.

import.css=/download/attachments/327912/newLayout.css