Exibir origem

Verifica a assinatura digital utilizando o certificado/chave pública armazenada em dispositivo HSM.

Sintaxe

HSMPrivVery( < cKey >, < cContent >, < nTipo >, < @cErrStr >, < cAssinado >, [ lClient ] )

Parâmetros

Nome	Tipo	Descrição	Obrigatório	Referência
cKey	caractere	Indica o caminho no dispositivo HSM para a chave pública/certificado.	X
cContent	caractere	Indica a mensagem original que será verificada.	X
nType	numérico	Indica o tipo do algoritmo digest que será utilizado.	X
cErrStr	caractere	Indica a variável para retornar as mensagens de erro.		X
cSigned	caractere	Indica a mensagem assinada que será verificada.	X
lClient	lógico	Indica se o dispositivo HSM está na máquina do SmartClient.

Retorno

Nome	Tipo	Descrição
lRet	lógico	Retorna .T. caso a assinatura seja verificada com sucesso; caso contrário, retorna .F..

Observações

O caminho no dispositivo HSM indicado em cKey pode ser verificado através do retorno da função HSMObjList, checando se o índice 2 é .F., pois a chave pública e o certificado ficam juntos e são necessários para a verificação da assinatura.
O formato aceito no caminho do parâmetro cKey é "slot_<num>-id_<idhex>" ou "slot_<num>-label_<label>", onde <num> é o número do slot, igual ao índice 1 do valor retornado pela função HSMSlotList, <idhex> é o id do objeto em hexadecimal, sendo cada 2 caracteres a representação hexadecimal de um caractere da tabela ASCII, e <label> é igual ao índice 1 do valor retornado pela função HSMObjList.
Tipo de algoritmo válido para o parâmetro nType:
Valor
Algoritmo
1
MD5
2
RIPEMD160
3
SHA1
4
SHA224
5
SHA256
6 SHA384
7 SHA512

O valor 5 e 6 no parâmetro nTipo estão disponíveis em builds superiores a 121227P.
O parâmetro lClient está disponível a partir da build 7.00.131227A - 13.2.3.14.
O valor padrão do parâmetro lClient é .F.

Exemplos

user function verify()
  Local cMsg := ""
  Local cPrivSign := ""
  Local cPath := ""
  Local cPwd := ""
  Local cError := ""
  Local lPrivVery := .F.
  
  // Slot do HSM contendo a chave privada que será utilizada para assinatura digital
  cPath := "slot_3-label_NOME:12345678901 Private Key"
  
  // Senha para acesso da chave privada no HSM
  cPwd := "MINHA SENHA"
  
  // Inicializa o HSM
  if HSMInitialize() <= 0
    conout( "HSM nao inicializado" )
    return
  endif
  
  // Assinatura digital utilizando o HSM
  cMsg := "Essa mensagem sera assinada digitalmente utilizando a chave privada contida no HSM"
  cPrivSign := HSMPrivSign( cPath, cMsg, 1, cPwd, @cError )
  
  // exibe o conteúdo da variável de erro
  varinfo( "1 - cError", cError )
  
  //exibe o conteúdo da mensagem assinada
  varinfo( "cPrivSign", cPrivSign )

  // Verificacao da assinatura digital utilizando o certificado contido no HSM
  
  // Define o caminho do certificado que será utilizado para validar a mensagem assinada
  cPath := "slot_3-label_NOME:12345678901 Certificate"
  
  // Verifica a mensagem a autenticidade entre a mensagem assinada e a mensagem original
  lPrivVery := HSMPrivVery( cPath, cMsg, 1, @cError, cPrivSign )
  
  // exibe o conteúdo da variável de erro
  varinfo( "cError", cError )
  
  if lPrivVery
    conout( "Assinatura verificada com sucesso!" )
  else
    conout( "Erro ao verificar assinatura!" )
  endif
 
return

Veja também

Abrangência

Advanced Protheus 7.10, Microsiga Protheus 8.11, Protheus 10, TOTVS Application Server 10, ByYou Application Server

Valor	Algoritmo
1	MD5
2	RIPEMD160
3	SHA1
4	SHA224
5	SHA256
6	SHA384
7	SHA512