O relatório Provisão de Devedores Duvidosos (FINR645) demonstra os clientes e títulos que constituíram a provisão.

O relatório foi desenvolvido utilizando a tecnologia TReport, onde permite a inclusão de campos da
tabela de provisão, títulos a receber (SE1), Clientes (SA1), Complemento de Cliente (AI0), Nota fiscal
de Saída (SD2) e Situação de Cobrança (FRV), Produto (SB1), Complemento de Produto (SBM) e
Referência do Contas a Receber(SK1).

Parâmetros do relatório:

1. 1. Cliente De?
      1. Selecione o cliente inicial para seleção dos títulos que pretende filtrar.
         
         
   2. Loja De?
      
      1. Selecione a loja do cliente inicial para seleção dos títulos que pretende filtrar.
         
         
   3. Cliente Até?
      
      1. Selecione o cliente final para seleção dos títulos que pretende filtrar.
         
         
   4. Loja Até?
      
      1. Selecione a loja do cliente final para seleção dos títulos que pretende filtrar.
         
         
   5. Código da Provisão?
      1. Informe a provisão que será listada no relatório. Parâmetro do tipo range, possibilitando intervalos com ponto e vírgula.
         
         
   1. Data Provisão Inicial?
      
      1. Selecione a data inicial da provisão que pretende filtrar.
         
         
   2. Data Provisão Final?
      
      1. Selecione a data final da provisão que pretende filtrar.
         
         
   3. Demonstra?
      
      1. Todos
      2. Constituídos
      3. Revertidos
         
         
   4. Seleciona Filial
      
      1. Sim
         
         1. Serão processados os registros das filiais selecionadas.
      2. Não
         1. Serão processados apenas os registros da filial corrente.
   5. Situação de cobrança
      
      1. Informe quais situações de cobrança serão consideradas no relatório.
         
         
   6. Mostra Rateio NF
      
      1. Defina se mostrará o rateio por item lançado na nota fiscal.
         
         
   7. Status Proc.?
      
      1. Todos
      2. Simulados
      3. Efetivados
         
         
   8. Data de Referência De?
      
      1. Selecione a data inicial de referência que pretende filtrar.
         
         
   9. Data de Referência Até?
      
      1. Selecione a data final de referência que pretende filtrar.

A constituição de PDD e a reversão da constituição serão contabilizadas a partir dos lançamentos padrão:

#include "protheus.ch"
#include "topconn.ch"
#include "RWMAKE.CH"
#include "TBICONN.CH"

/*/{Protheus.doc} F645Const

Constituição PDD

@type function
@version 1.0
@author totvs
@return nil
/*/
User Function F645Const()

    Local lAutomato := .T.
    Local nOperation:= 3
    Local aSitCob   := {}

    Private lMsErroAuto := .f. 
	Private lAutoErrNoFile	:= .T.

    PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01"

    //Situações de cobrança a serem filtradas
	Aadd(aSitCob, '0')
	Aadd(aSitCob, '3')
	Aadd(aSitCob, '4')
	Aadd(aSitCob, '5')
	Aadd(aSitCob, '6')
	Aadd(aSitCob, '7')

    //Ajusta perguntas (F12)

    Pergunte("FINA645C",.F.) 

    SetMVValue("FINA645C","MV_PAR01", DDATABASE )              // Data de Referencia ?                                          
    SetMVValue("FINA645C","MV_PAR02", 1 )                      // Numero de dias de atraso ?                                                                                  
    SetMVValue("FINA645C","MV_PAR03", 3 )                      // Transferir para Provisao ?                                                 
    SetMVValue("FINA645C","MV_PAR04", "PDD001"  )              // Cliente De ?                                                                                 
    SetMVValue("FINA645C","MV_PAR05", "01" )                   // Loja do Cliente De ?                                                              
    SetMVValue("FINA645C","MV_PAR06", "PDD001"  )              // Cliente Ate ?                            
    SetMVValue("FINA645C","MV_PAR07", "01" )                   // Loja do Cliente Ate ?                          
    SetMVValue("FINA645C","MV_PAR08", CTOD("01/01/2001") )     // Emissão De ?                                     
    SetMVValue("FINA645C","MV_PAR09", CTOD("31/12/2049") )     // Emissão Ate ?                                                   
    SetMVValue("FINA645C","MV_PAR10", 2 )                      // Seleciona Filial ? 1 = Sim 2 = Não                                                              
    SetMVValue("FINA645C","MV_PAR11", "8" )                    // Situação de Cobrança PDD ?                                                                
    SetMVValue("FINA645C","MV_PAR12", 2 )                      // Seleciona Sit. de Cobrança ?  1 = Sim 2 = Não                                                                            
    SetMVValue("FINA645C","MV_PAR13", 2 )                      // Considera Negociados ?   1 = Sim 2 = Não  

    //Constituição
    MSExecAuto({|a,b,c| FINA645(a,b,c)},  lAutomato, nOperation, aSitCob )

    If !lMsErroAuto
        conout("sucesso! ")
    Else
        conout("Erro!")
        mostraErro()
    EndIf

Return

#include "protheus.ch"
#include "topconn.ch"
#include "RWMAKE.CH"
#include "TBICONN.CH"

/*/{Protheus.doc} F645EfeCon

Efetiva Constituição PDD

@type function
@version 1.0
@author totvs
@return nil
/*/
User Function F645EfeCon()

    Local lAutomato := .T.
    Local nOperation:= 4
    Local aSitCob   := {}
    Local cNroProc  := "000010"

    Private lMsErroAuto := .f. 
	Private lAutoErrNoFile	:= .T.

    PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01"

    //Ajusta perguntas (F12)
    Pergunte("FINA645D",.F.)        
    SetMVValue("FINA645D","MV_PAR01", 2 )  // Mostra Lançamento ?                                     
    SetMVValue("FINA645D","MV_PAR02", 2 )  // Aglutina Lançamento ?                                                                       
    SetMVValue("FINA645D","MV_PAR03", 2 )  // Considera movimento posterior geração do processo ?                                                     

    //Efetivação
    MSExecAuto({|a,b,c,d| FINA645(a,b,c,d)},  lAutomato, nOperation, aSitCob, cNroProc )

    If !lMsErroAuto
        conout("sucesso! ")
    Else
        conout("Erro!")
        mostraErro()
    EndIf

Return

#include "protheus.ch"
#include "topconn.ch"
#include "RWMAKE.CH"
#include "TBICONN.CH"

/*/{Protheus.doc} F645Revers

Reversão da Constituição PDD

@type function
@version 1.0
@author totvs
@return nil
/*/
User Function F645Revers()

    Local lAutomato := .T.
    Local nOperation:= 5
    Local aSitCob   := {}
    Local cNroProc  := "000010"
    Local dDtRef    := CTOD("14/10/2021")
    Private lMsErroAuto := .f. 
	Private lAutoErrNoFile	:= .T.

    PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01"

    //Ajusta perguntas (F12)

    Pergunte("FINA645E",.F.) 
                                         
    SetMVValue("FINA645E","MV_PAR01", 1 )             // Reverter Provisão ? - 1 = Todos / 2 = Titulos Baixados / 3 = Abertos
    SetMVValue("FINA645E","MV_PAR02", "PDD001" )      // Cliente De ?                                                  
    SetMVValue("FINA645E","MV_PAR03", "01" )          // Loja do Cliente De ?             
    SetMVValue("FINA645E","MV_PAR04", "PDD001"  )     // Cliente Ate ?                            
    SetMVValue("FINA645E","MV_PAR05", "01" )          // Loja do Cliente Ate ?                 
    SetMVValue("FINA645E","MV_PAR06", 2  )            // Seleciona Filial ? 1 = Sim 2 = Não
    SetMVValue("FINA645E","MV_PAR07", dDtRef )        // Data de Refenrencia ?
    SetMVValue("FINA645E","MV_PAR08", dDatabase )     // Emissão De ?
    SetMVValue("FINA645E","MV_PAR09", dDatabase )     // Emissão Ate ?

    //Reversão da Constituição
    MSExecAuto({|a,b,c,d| FINA645(a,b,c,d)},  lAutomato, nOperation, aSitCob, cNroProc )

    If !lMsErroAuto
        conout("sucesso! ")
    Else
        conout("Erro!")
        mostraErro()
    EndIf

Return

#include "protheus.ch"
#include "topconn.ch"
#include "RWMAKE.CH"
#include "TBICONN.CH"

/*/{Protheus.doc} F645EfetRev

Efetiva a Reversão da Constituição PDD

@type function
@version 1.0
@author totvs
@return nil
/*/
User Function F645EfetRev()

    Local lAutomato := .T.
    Local nOperation:= 6  //Efetiva Reversão
    Local aSitCob   := {}
    Local cNroProc  := "000010"

    Private lMsErroAuto := .f. 
	Private lAutoErrNoFile	:= .T.

    PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01"

    //Ajusta perguntas (F12)
    Pergunte("FINA645D",.F.)        
    SetMVValue("FINA645D","MV_PAR01", 2 )  // Mostra Lançamento ?                                     
    SetMVValue("FINA645D","MV_PAR02", 2 )  // Aglutina Lançamento ?                                                                       
    SetMVValue("FINA645D","MV_PAR03", 2 )  // Considera movimento posterior geração do processo ?                                                     

    //Efetivação
    MSExecAuto({|a,b,c,d| FINA645(a,b,c,d)},  lAutomato, nOperation, aSitCob, cNroProc )

    If !lMsErroAuto
        conout("sucesso! ")
    Else
        conout("Erro!")
        mostraErro()
    EndIf

Return