01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Backoffice
Módulo:Financeiro
Função:

FINA645 – Provis Dev Duvidos

02. DESCRIÇÃO

O ponto de entrada F645QYABT permite tratamento de datas da seleção de títulos no abatimento, vencidos após atraso, somente os vencidos e todos os títulos.

03. PARÂMETROS      

NomeTipoDescrição
PARAMIXBCaracter

Query em andamento para o filtro de títulos.

04. RETORNO

TipoDescrição

Caracter

Expressão SQL com a condição de filtro de data.

05. EXEMPLO DE UTILIZAÇÃO


#INCLUDE 'TOTVS.CH'

User Function F645QYABT() as character
Local aArea         := GetArea() as array
Local cQuery        := PARAMIXB as character
Local cQryDt        := "" as character
Local cParVenc		:= AllTrim(SuperGetMV( 'MV_PDDREF ' ,.F., '1' )) as character
Local cCpoVenc		:= IIF(cParVenc == '1', "E1_VENCREA" , Iif(cParVenc == '2', "E1_VENCTO" , "E1_VENCORI")) as character

//-------------------------------------------------------------------------------
// Tratamento de datas de seleção de títulos no abatimento, vencidos apos atraso
//-------------------------------------------------------------------------------
If mv_par03 == 1 //Todos titulos
	cQryDt += " AND SE1SUB.E1_EMISSAO 	BETWEEN	'" + Dtos(MV_PAR08) + "'	AND '" + Dtos(MV_PAR09) + "' " + CRLF

ElseIf MV_PAR03 == 2 //Titulos vencidos
	cQryDt += " AND SE1SUB."+cCpoVenc+" < '" + DToS(MV_PAR01) + "' " + CRLF

ElseIf MV_PAR03 == 3 //Vct apos atraso
	cQryDt += " AND SE1SUB."+cCpoVenc+" < '" + DToS(MV_PAR01 - MV_PAR02) + "' " + CRLF //Data de referencia - quantidade de dias de atraso 

EndIf

RestArea(aArea)

Return cQryDt