01. DADOS GERAIS

Produto:

Linha de Produto:

Segmento:

Módulo:

Função:MNTA765()
País:Brasil

Não é permitido utilizar 'MNTA765' como nome do arquivo que contém o Ponto de Entrada.

02. DESCRIÇÃO

Descrição:

Ponto de entrada no padrão MVC para customização da rotina de cadastro de multas.

Localização:

SIGAMNT: Em Atualizações > Controle de Riscos > Multas > Multas
Programa Fonte:MNTA765.prx

Função:

MNTA765

Parâmetro:

NomeTipoDescriçãoObrigatório
ParamIXB[1]ObjetoModelo de dadosSim
ParamIXB[2]CaracterIdentificador do ponto de chamadaSim
ParamIXB[3]CaracterIdentificador do modelo de dadosSim


Retorno:

TipoDescriçãoObrigatório

Lógico

Determina a continuidade do processo.

Sim

03. DEMAIS INFORMAÇÕES

#INCLUDE 'PROTHEUS.CH'
#INCLUDE 'FWMVCDEF.CH'
 
User Function MNTA765()
 
    Local oMod   := PARAMIXB[1]
    Local cId    := PARAMIXB[2]
    Local cIdMod := PARAMIXB[3]
    Local lRet   := .T.
  
    If cId == 'MODELPRE'
 
        If oMod:GetModel( 'MULTAS' ):HasField( 'TRX_PREFIX' )
 
            oMod:LoadValue( 'MULTAS', 'TRX_PREFIX', &( Trim( Posicione( 'SX3', 2, 'TRX_PREFIX', 'X3_RELACAO' ) ) ) )
 
        EndIf
 
        If oMod:GetModel( 'MULTAS' ):HasField( 'TRX_TIPO' )
 
            oMod:LoadValue( 'MULTAS', 'TRX_TIPO', &( Trim( Posicione( 'SX3', 2, 'TRX_TIPO', 'X3_RELACAO' ) ) ) )
 
        EndIf
 
    ElseIf cId == 'MODELPOS'
 
        If oMod:GetModel( 'MULTAS' ):HasField( 'TRX_RODOVI' ) .And.;
            Empty( oMod:GetValue( 'MULTAS', 'TRX_RODOVI' ) )
 
            Help( , , 'MODELPOS', , 'Código da Rodovia está vazio.', 2, 1 )
             
            lRet := .F.
 
        EndIf
 
    EndIf
 
Return lRet


04. ASSUNTOS RELACIONADOS