Linha Microsiga Protheus - Espanhol

Atalhos

Árvore de páginas

01. DATOS GENERALES

Línea de producto:Microsiga Protheus®
Segmento:Backoffice
Módulo:Financiero
Función:

FILMOTBX - Realiza el filtro en la lista de motivos de baja


02. DESCRIPCIÓN

El puento de entrada FILMOTBX tiene como finalidad permitir el filtro de la lista de Motivos de Baja, cargados durante los procesos que los utilizan.

La función que carga la lista de Motivos de Baja se utiliza internamente en diversos puntos del sistema, tanto del financiero como de otros módulos. Por lo tanto, es importante hacer el uso correcto, aplicando el filtro específicamente a la rutina/proceso que desea considerar, según su regla de negocio. En caso contrario, el filtro aplicado podrá dejar de cargar los Motivos de Baja reservados para otros procesos del ERP.

Se recomienda evaluar el tópico 3 del documento relacionado al final de esta página para definir los Motivos de bajas que deben devolverse, en atención a las necesidades de cada rutina.

03. PARÁMETROS      

Nombre

Tipo

Descripción

aMotReadArrayArray que contiene los Motivos de Baja registrados en la tabla F7G


04. DEVOLUCIÓN

Nombre

Tipo

Descripción

aNewMotR

Array

Array con el filtro aplicado a los Motivos de Baja

05. EJEMPLO DE UTILIZACIÓN


FILMOTBX
#INCLUDE "PROTHEUS.CH"
 
User Function FILMOTBX()
 
    Local nX       As Numeric
    Local aArea    As Array
    Local aMotBx   As Array
    Local aNewMotR As Array
        
    aMotBx   := aClone(ParamIXB)//Motivos listados de la F7G
    aArea    := GetArea()
    aNewMotR := {}

    //Solo presenta lista de Motivos de Baja con movimiento bancario, en la rutina de bajas de la cartera por cobrar
    If FwIsInCallStack('FINA070')
        
        dbSelectArea('F7G')
        dbSetOrder(1)        
        For nX:=1 to Len(aMotBx)
            //Búsqueda por la Sigla del Motivo de Baja
            dbSeek( FWxFilial('F7G') + Substr(aMotBx[nX],1,3) )
            If F7G_MOVBCO == 'S' 
                AADD( aNewMotR, aMotBx[nX] )         
            EndIF
        Next nX
    Else
        //Devuelve lista completa
        aNewMotR := aClone(aMotBx)           
    EndIf

    RestArea(aArea)
    FwFreeArray(aMotBx)
    FwFreeArray(aArea)
 
Return aNewMotR


06. ASUNTOS RELACIONADOS

Registro de Motivo de Baja - FINA490