Linha Microsiga Protheus - Espanhol

Atalhos

Árvore de páginas

01. DATOS GENERALES

Línea de producto:

Microsiga Protheus®

Segmento:

Backoffice

Módulo:

Financiero

Función:

FINA040 - Cuentas por cobrar
FINA050 - Cuentas por pagar
FINA070 - Bajas por cobrar
FINA080 - Bajas por pagar manual
FINA090 - Bajas por pagar automática
FINA110 - Bajas automáticas de títulos por cobrar
FINA200 - Devolución de cobranzas
FINA240 - Borderó de pagos
FINA241 - Borderó con impuestos
FINA250 - Rastreo
FINA290 - Facturas por pagar
FINA374 - Cálculo Pis, Cofins y Csl por pagar
FINA426
FINA460 - Liquidación
FINA565 - Liquidación
FINA740 - Funciones Cuentas por cobrar
FINA750 - Funciones Cuentas por pagar

02. DESCRIPCIÓN

El punto de entrada FINALEG permite modificar las leyendas de diversas rutinas del financiero, como FINA040, FNA050, FINA740, FINA750 etc.


Observaciones:

    • La devolución de este punto de entrada sustituirá las reglas del estándar.
    • Las reglas de leyenda se consideran en el orden del array devuelto.
    • La primera regla atendida definirá el color que se atribuirá.
    • Atención con el orden de las reglas y con reglas conflictivas.
    • Se activa para devolver las reglas de leyendas y se activa también al activar la opción de leyendas para que se muestre la pantalla.

03. PARÁMETROS

Nombre

Tipo

Descripción

PARAMIXB[1]

Numérico

Con valor: Abrir la pantalla de leyendas; Sin valor: Devolver las reglas.

PARAMIXB[2]

Carácter

SE1 o SE2, dependiendo de la rutina utilizada.

PARAMIXB[3]

Array

Reglas del estándar.

PARAMIXB[4]

Array

Leyendas del estándar.

04. DEVOLUCIÓN

Tipo

Descripción

Array

Si PARAMIXB[1] fuera igual a nil:

  • array[n,1] - regla de la leyenda
  • array[n,2] - color de la leyenda

Si PARAMIXB[1] fuera igual a numérico:

  • array[n,1] - color de la leyenda
  • array[n,2] - descripción de la leyenda

05. EJEMPLO DE UTILIZACIÓN

FINALEG
#INCLUDE "TOTVS.CH"
 
User Function FINALeg() as array
 
Local nReg := PARAMIXB[1] as numeric // Con valor: Abrir la pantalla pequeña de leyendas ### Sin valor: Devolver las reglas
Local cAlias := PARAMIXB[2] as character // SE1 o SE2
Local aRegras := PARAMIXB[3] as array// Reglas de estándar
Local aLegendas := PARAMIXB[4] as array// Leyendas del estándar
Local aRet := {} as array
Local nI := 0 as numeric
 
/*
    Sin Recno --> Devolver array con las reglas para que el Browse coloque los colores en las columnas.
    Con Recno --> Activada al activar la opción Leyendas del browse -> Abrir pantalla pequeña de Leyendas (BrwLegenda)
*/
If nReg = Nil
 
    /*
        aRegras transferido contiene las reglas del estándar
        El array devuelto debe contener todas las reglas, del estándar y personalizadas.
 
        Importante:
        Recordando que las reglas de leyenda se consideran en el orden del array devuelto.
        La Primera regla atendida definirá el color que se atribuirá.
        Atención con el orden de las reglas y con reglas conflictivas.
        La Última regla del estándar, si no atendiera ninguna condición anterior es .T. -> BR_VERDE -> Título pendiente
    */
    If cAlias = "SE1"
 
        /*
            Ejemplo: incluir una regla de leyenda "más prioritaria" que las del estándar
        */
        aAdd(aRet,{"!Empty(E1_PORTADO) .AND. Empty(E1_NUMBOR)","BR_LARANJA"})
     
        /*
            Reglas del estándar para devolución
        */
        For nI := 1 To Len(aRegras)
            aAdd(aRet,{aRegras[nI][1],aRegras[nI][2]})
        Next nI
 
    Else // SE2
 
        /*
            Ejemplo para devolver las mismas reglas del estándar sin modificación
        */
        aRet := aRegras
 
    Endif
 
 
Else // Abrir pantalla pequeña de leyendas (BrwLegenda)
 
    If cAlias = "SE1"
 
        aAdd(aLegendas,{"BR_LARANJA","Título en el Portador"})
 
    Else // SE2
        /*
            Incluir el color y descripción de leyendas a SE2 aquí. Ejemplo:
            Aadd(aLegendas, {"BR_AMARELO", "Titulo aguardando liberacao"}) //Título esperando liberación
        */
    Endif
 
    BrwLegenda(cCadastro, "Leyenda", aLegendas)
 
Endif
 
Return aRet