Linha Microsiga Protheus

Árvore de páginas

Ponto de Entrada - FRT271ALTC

Descrição:

Este ponto de entrada permite substituir a tela de seleção de Clientes no FrontLoja (Tecla F10), onde é possível construir uma tela personalizada para seleção do cliente da venda.

Função:

FRT271ALTC( ExpC1, ExpC2, ExpC3, ExpC4, ExpC5 ) --> Nil

Programa Fonte:

FRTA271E.PRW

Parâmetros:

Nome

Tipo

Descrição

Obrigatório

ExpC1

Caractere

Código do Cliente

Sim

ExpC2

Caractere

Loja do Cliente

Sim
ExpC3CaractereNome do ClienteSim
ExpC4CaractereCódigo do ClienteSim
ExpC5CaractereLoja do ClienteSim
Retorno:Nulo (Nil)
Observação:Todos os parâmetros são passados como referência para a função, para que sejam alterados o Código, Loja e Nome do Cliente que for selecionado.

 

Exemplo:

#Include 'Protheus.ch'

User Function FRT271ALTC( cCliFrt, cLojFrt, cNomeCli, cCliente, cLojaCli )

DEFINE FONT oFnt2 NAME "Arial" SIZE 11.5,22 BOLD
DEFINE MSDIALOG oDlgAltCli FROM 47,130 TO 200,550 TITLE "Seleção do Cliente" PIXEL
@ 04, 05 TO 28, 85 LABEL "Cod.Cliente / Loja" OF oDlgAltCli PIXEL

@ 13, 15 MSGET oCliFrt VAR cCliFrt SIZE 40, 10 OF oDlgAltCli F3 "FCL" PIXEL VALID ExistCpo("SA1",cCliFrt+cLojFrt)
oCliFrt:cSx1Hlp:="A1_COD"
@ 13, 60 MSGET oLojFrt VAR cLojFrt SIZE 15, 10 OF oDlgAltCli PIXEL VALID ExistCpo("SA1",cCliFrt+cLojFrt)
oLojFrt:cSx1Hlp:="A1_LOJA"

@ 30, 05 TO 54, 210 LABEL "Nome do Cliente" OF oDlgAltCli PIXEL
@ 39, 15 MSGET oNomeCli VAR cNomeCli WHEN .F. PIXEL

oCliFrt:bLostFocus := { || cNomeCli := Subst(Posicione("SA1",1,xFilial("SA1")+cCliFrt+cLojFrt,"A1_NOME"),1,30), oNomeCli:Refresh() }
oLojFrt:bLostFocus := { || cNomeCli := Subst(Posicione("SA1",1,xFilial("SA1")+cCliFrt+cLojFrt,"A1_NOME"),1,30), oLojFrt:Refresh() }

DEFINE SBUTTON FROM 60, 135 oButton2 TYPE 1 ENABLE OF oDlgAltCli ;
ACTION IIf(ExistCpo("SA1",cCliFrt+cLojFrt),(cCliente := cCliFrt, cLojaCli := cLojFrt, oDlgAltCli:End()), .F.) PIXEL

DEFINE SBUTTON FROM 60, 170 oButton3 TYPE 2 ENABLE OF oDlgAltCli ;
ACTION (oDlgAltCli:End()) PIXEL

ACTIVATE MSDIALOG oDlgAltCli CENTERED


Return Nil