DT PE J203ADT

 Tempo aproximado para leitura: 05 min

01. DADOS GERAIS

02. PONTO DE ENTRADA

03. EXEMPLO

#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWMVCDEF.CH"
#INCLUDE "PARMTYPE.CH"

//-------------------------------------------------------------------
/*/{Protheus.doc} J203Adt
Ponto de entrada para utilização de adiantamentos na emissão de fatura

@param PARAMIXB, array   , Parâmetros do ponto de entrada
          PARAMIXB[1], caracter, Código do Escritório da Fatura
          PARAMIXB[2], caracter, Código da Fatura
          PARAMIXB[3], caracter, Código da Fila de Emissão da Fatura
          PARAMIXB[4], numérico, Valor Total da Fatura

@author TOTVS
@since  19/03/2020
/*/
//-------------------------------------------------------------------
User Function J203Adt()
    Local aArea          := GetArea()
    Local aAreaNXA  := NXA->(GetArea())
    Local cEscrit        := ""
    Local cNumFat    := ""
    Local cFila           := ""
    Local nVlFatura   := 0
    Local cCliente     := 0
    Local cLojaCli     := 0
    Local aAdtUser   := {}
    Local aRetorno   := {}

    If ValType( PARAMIXB ) == "A"
        cEscrit   := PARAMIXB[1]
        cNumFat   := PARAMIXB[2]
        cFila     := PARAMIXB[3]
        nVlFatura := PARAMIXB[4]

        //----------------------
        // Posiciona na fatura
        //----------------------
        NXA->( DBSetOrder(1) ) // NXA_FILIAL + NXA_ESCRIT + NXA_COD
        If NXA->( DbSeek( xFilial("NXA") + cEscrit + cNumFat ) )
            cCliente := NXA->NXA_CLIPG
            cLojaCli := NXA->NXA_LOJPG
            //--------------------------------
            // Encontra adiantamentos válidos
            //--------------------------------
            aAdtUser := BuscaAdt( cCliente, cLojaCli )
        EndIf
    EndIf

    aRetorno := { .F., aAdtUser }

    RestArea(aAreaNXA)
    RestArea(aArea)

Return (aRetorno)

//===========================================================
Static Function BuscaAdt(cCliente, cLojaCli)
    Local cAlsTmp   := GetNextAlias()
    Local cPrefAdt   := PadR( SuperGetMV("MV_JADTPRF", .F., ""  ), TamSX3("E1_PREFIXO")[1] )
    Local cTipoAdt  := PadR( SuperGetMV("MV_JADTTP" , .F., "RA"), TamSX3("E1_TIPO")[1]    )
    Local cParcAdt   := PadR( SuperGetMV("MV_JADTPAR", .F., ""  ), TamSX3("E1_PARCELA")[1] )
    Local lResiduo   := .F.
    Local aAdtUser  := {}

    BeginSql Alias cAlsTmp
        SELECT NWF.R_E_C_N_O_ RECNOADT, SE1.R_E_C_N_O_ RECNOTIT, SE1.E1_SALDO VALOR
          FROM %Table:NWF% NWF
         INNER JOIN %Table:SE1% SE1
            ON SE1.E1_FILIAL  = %xFilial:SE1%
           AND SE1.E1_CLIENTE = NWF.NWF_CCLIAD
           AND SE1.E1_LOJA    = NWF.NWF_CLOJAD
           AND SE1.E1_PREFIXO = %Exp:cPrefAdt%
           AND SE1.E1_NUM     = NWF.NWF_TITULO
           AND SE1.E1_PARCELA = %Exp:cParcAdt%
           AND SE1.E1_TIPO    = %Exp:cTipoAdt%
           AND SE1.E1_ORIGEM  = 'JURA069'
           AND SE1.E1_SALDO   > 0 // Aditamentos com saldo
           AND SE1.%NotDel%
         WHERE NWF.NWF_FILIAL = %xFilial:NWF%
           AND NWF.NWF_CCLIAD= %Exp:cCliente%
           AND NWF.NWF_CLOJAD  = %Exp:cLojaCli%
           AND NWF.NWF_TITGER = '1' // Somente adiantamentos com títulos gerados
           AND NWF.%NotDel%
    EndSql

    While (cAlsTmp)->( !EOF() )
        Aadd( aAdtUser, { (cAlsTmp)->RECNOADT, (cAlsTmp)->RECNOTIT, 100, lResiduo } )
        (cAlsTmp)->( DbSkip() )
    End

    (cAlsTmp)->(DbCloseArea())

Return (aAdtUser)