Linha Microsiga Protheus

Árvore de páginas

01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Backoffice
Módulo:Financeiro
Função:

FILMOTBX - Realiza o filtro na lista de Motivos de Baixa


02. DESCRIÇÃO

O ponto de entrada FILMOTBX tem como finalidade permitir o filtro da lista de Motivos de Baixa, carregados durante os processos que os utilizam.

A função que carrega a lista de Motivos de Baixa é utilizada internamente em diversos pontos do sistema, tanto do Financeiro como de outros módulos. Portanto, é importante fazer o uso correto, aplicando o filtro especificamente à rotina/processo que deseja contemplar, conforme sua regra de negócio; caso contrário, o filtro aplicado poderá deixar de carregar Motivos de Baixa reservados para outros processos do ERP. 

Recomenda-se avaliar o tópico 3 do documento relacionado ao final desta página para definir os Motivos de Baixas que devem ser retornados, em atendimento as necessidades de cada rotina.

03. PARÂMETROS      

Nome

Tipo

Descrição

aMotReadArrayArray contendo o Motivos de Baixa cadastrados na tabela F7G


04. RETORNO

Nome

Tipo

Descrição

aNewMotR

Array

Array com o filtro aplicado aos Motivos de Baixa

05. EXEMPLO DE UTILIZAÇÃO


FILMOTBX
#INCLUDE "PROTHEUS.CH"
 
User Function FILMOTBX()
 
    Local nX       As Numeric
    Local aArea    As Array
    Local aMotBx   As Array
    Local aNewMotR As Array
        
    aMotBx   := aClone(ParamIXB)//Motivos listados da F7G
    aArea    := GetArea()
    aNewMotR := {}

    //Só apresenta lista de Motivos de Baixa com movimentação bancária, na rotina de baixas da carteira Receber
    If FwIsInCallStack('FINA070')
        
        dbSelectArea('F7G')
        dbSetOrder(1)        
        For nX:=1 to Len(aMotBx)
            //Pesquisa pela Sigla do Motivo de Baixa
            dbSeek( FWxFilial('F7G') + Substr(aMotBx[nX],1,3) )
            If F7G_MOVBCO == 'S' 
                AADD( aNewMotR, aMotBx[nX] )         
            EndIF
        Next nX
    Else
        //Retorna lista completa
        aNewMotR := aClone(aMotBx)           
    EndIf

    RestArea(aArea)
    FwFreeArray(aMotBx)
    FwFreeArray(aArea)
 
Return aNewMotR


06. ASSUNTOS RELACIONADOS

Cadastro de Motivo de Baixa - FINA490