Linha Microsiga Protheus

Árvore de páginas


ÍNDICE

  1. Visão Geral
  2. Exemplo de utilização
  3. Conteúdos Relacionados

01. VISÃO GERAL

A execução do MRP (em Memória) - PCPA712 pode ser configurado para ser feita em modo SCHEDULE. Para isso, é necessário realizar uma chamada na função PCPA712, passando os parâmetros da execução, que podem ser encontrados na tabela abaixo.

ParâmetroTipoDescriçãoObrigatórioDefault
oParametrosObjectJson com os parâmetros de execução do MRP.X
lCancelLógicoIndica se irá cancelar o ticket reservado.
.F.
lIntegraLógicoIndica se irá realizar a integração no caso de pendencias.
.F.

02. EXEMPLO DE UTILIZAÇÃO

Para obter os parâmetros de execução do MRP, é possível utilizar a função P712Param passando um valor .T. por parâmetro. Isso irá retornar um objeto JSON, com os parâmetros padrões de execução.

A partir do objeto retornado, é possível alterar os parâmetros de execução. Sendo obrigatório nesse caso, informar a filial e o usuário por meio dos parâmetros, "branchId" e "user" respectivamente. Conforme o exemplo abaixo. 

Exemplo
#INCLUDE "PROTHEUS.CH"
#INCLUDE "TBICONN.CH"

User Function MrpSchdl()
    Local oParam := Nil

    PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "PCP"
    
    oParam := P712Param(.T.)  // Parâmetros Padrões

    /* ---- Parâmetros Obrigatórios ---- */
	oParam["cEmpAnt"] := cEmpAnt
	oParam["cFilAnt"] := cFilAnt
    oParam["user"]    := "000000"

    /* ---- Parâmetros Adicionais ---- */
    oParam["TELA_1"]["HW2_CODIGO"]          := ""
    oParam["TELA_1"]["HW2_DESCRI"]          := ""
    oParam["allocationSuggestion"]          := "2"
    oParam["blockedLot"]                    := "2"
    oParam["consignedIn"]                   := "2"
    oParam["consignedOut"]                  := "1"
    oParam["consolidateProductionOrder"]    := "3"
    oParam["consolidatePurchaseRequest"]    := "3"
    oParam["demandCodes"]["LISTA"]          := "|003|"
    oParam["demandEndDate"]                 := Date() + 30
    oParam["demandsProcessed"]              := .T.
    oParam["demandStartDate"]               := Date()
    oParam["demandType"]["EMP_PROJETO"]     := .T.
    oParam["demandType"]["MANUAL"]          := .T.
    oParam["demandType"]["PEDIDO_VENDA"]    := .T.
    oParam["demandType"]["PLANO_MESTRE"]    := .T.
    oParam["demandType"]["PREV_VENDAS"]     := .T.
    oParam["documents"]["LISTA"]            := ""
    oParam["documentType"]["PREVISTOS"]     := "1"
    oParam["documentType"]["SACRAMENTADOS"] := .T.
    oParam["documentType"]["SUSPENSOS"]     := .T.
    oParam["eventLog"]                      := .F.
    oParam["firmHorizon"]                   := 2
    oParam["leadTime"]                      := "1"
    oParam["lGeraDoc"]                      := .F.
    oParam["lRastreiaEntradas"]             := .F.
    oParam["numberOfPeriods"]               := "30 "
    oParam["orderPoint"]                    := "1"
    oParam["periodType"]                    := "1"
    oParam["productGroups"]["LISTA"]        := ""
    oParam["productionOrderNumber"]         := "2"
    oParam["productionOrderType"]           := "1"
    oParam["products"]["LISTA"]             := ""
    oParam["productTypes"]["LISTA"]         := ""
    oParam["purchaseRequestNumber"]         := "2"
    oParam["rejectedQuality"]               := "2"
    oParam["safetyStock"]                   := "1"

    If PCPA712(oParam, .T., .T.)
        ConOut(" -------- Concluido com Sucesso! -------- ")
    Else
		aHelp := GetHelpPCP("Execução do MRP não foi concluida com sucesso!") //Mensagem padrão que será assumida como problema, caso não encontrar um help.
		//Essa função retornará um array com as informações do help, onde:
		//aHelp[1] - Código do help
		//aHelp[2] - Problema do help (se estiver vazio, retorna a mensagem padrão)
		//aHelp[3] - Solução do help
        ConOut(" ----- Não Foi Concluido com Sucesso! -----")
    EndIf

    RESET ENVIRONMENT

Return

Para mais detalhes sobre os parâmetros do MRP, consulte Lista de parâmetros do MRP Memória


Em seguida será necessário configurar o Schedule por meio do SIGACFG. Para isso, pode ser seguido os passos a seguir:

1 - No Configurador (SIGACFG), acessar a rotina de configuração de Schedule (Ambiente -> Schedule -> Schedule);

2 - Na visão Schedule, inicie os serviços Task Manager e Queue Manager;

3 - Abra a visão Agent e selecione a opção Cadastro. Nesta tela, cadastre um novo Agent.

4 - Ainda na visão Agent, selecione a opção Monitor. Verifique se o Agent cadastrado está Iniciado. Caso não esteja, inicie o serviço.

5 - Abra a visão Agendamentos e selecione a opção Cadastro. Nesta tela será cadastrado o agendamento para execução do SCHEDULE para a rotina que foi criada anteriormente.

5.1 - Em seguida deve ser definido a recorrência de execução do agendamento, conforme a necessidade da execução do MRP.


6 - Para conferir se os agendamentos estão sendo executados, pode ser realizada a consulta na opção "Monitor" da visão "Agendamentos".

Para maiores detalhes sobre a utilização do cadastro de schedules e agendamentos, confira o documento Schedule - Como agendar a execução de rotinas.

03. Conteúdos Relacionados