Linha Microsiga Protheus

Árvore de páginas

01. DADOS GERAIS

Produto:

TOTVS Backoffice

Linha de Produto:

Linha Protheus

Segmento:

Tecnologia

Módulo:

TOTVS Backoffice (Linha Protheus) - Contabilidade Gerencial (SIGACTB)

Função:CTBA010
País:Brasil
Ticket:Interno
Requisito/Story/IssueDSERCTR1-46829

02. DESCRIÇÃO

O ponto de entrada CT010ATU é executado a partir da rotina de Cadastro de Calendário Contábil (CTBA010).  Seu propósito é guardar e apresentar dados de campos criados por usuário, conhecidos como campos customizados.

Para saber detalhes a respeito de como codificar este Ponto de Entrada, veja o exemplo de utilização.

03. DEMAIS INFORMAÇÕES


Manipulação de PE no sistema
If ExistBlock ("CT010Atu")
	ExecBlock("CT010Atu",.F.,.F.,{aHeader,aCols,nCont,2})
EndIf
Exemplo de PE
User Function CT010Atu()
 
	//o Array ParamIxb possui os elementos: {aHeader,aCols,nCont,nTipo}, onde
	//aHeader   - Tipo: Array. Cabeçalho da MsGetDados
	//aCols     - Tipo: Array. Dados da MSGetDados
	//nCont     - Tipo: Numérico. Nro da Linha atual do aCols
	//nTipo     - Tipo: Numérico. Qual é o tipo de manipulação efetuada no PE:
	//                  1 - Leitura de Dados - carga do aCols;
	//                  2 - Persistência do dado em seu relativo campo - criado por usuário.
	Local aMyHeader := aClone(ParamIxb[1])  //aHeader
	Local aMyCols   := aClone(ParamIxb[2])  //aCols
 
	Local nItem     := ParamIxb[3]  //Linha do aCols
	Local nTipo     := ParamIxb[4]  //Tipo de manipulação de dado (1 - Carga do aCols; 2- Salvamento na tabela)
	Local nPxTeste  := aScan(aMyHeader,{|x| Alltrim(x[2]) == "CTG_XTESTE" })
 
	If ( nPxTeste > 0 .And. nTipo == 2 )
    	Replace CTG_XTESTE With aMyCols[nItem,nPxTeste]
	ElseIf (nPxTeste > 0)   
    	aMyCols[nItem,nPxTeste] := IIf(Empty(CTG->CTG_XTESTE),space(Len(CTG->CTG_XTESTE)),CTG->CTG_XTESTE)
	EndIf
 
	//Essencial Clonar o array para o aCols (array de escopo privado)
	aCols := aClone(aMyCols)
 
Return()


Importante !!

  • Observa-se que a utilização do PE e os impactos dele no sistema são de responsabilidade do cliente.
  • Os exemplos utilizados nessa documentação são apenas para fins de demonstração, cada cliente deve verificar qual comportamento deseja realizar de acordo com o escopo do ponto de entrada.

04. ASSUNTOS RELACIONADOS

  • Não se aplica.