PE MNTA9853 - Carrega campos em tela na rotina de Controle de Portaria

#Include 'Protheus.ch'
#Include 'RwMake.ch'
 
/*
Função MNTA9853
Autor Felipe Nathan Welter
Data 16/02/10
Descrição PE para carregar campos (X3_RELAC) em tela atraves da funcao M985RELAC
Parametros aParamIxb [1] - cCampo - (indica campo a ser validado)
                     [2] - cFilMov - Filial de Movientacao
                     [3] - cEmpMov - Empresa de Movimentacao
Retorno xCampo - Conteudo para preencher o campo em tela (ou Nil p/ nao sobrescrever)
Uso MNTA985
*/
 
User Function MNTA9853()
 
    Local aArea := GetArea()
    Local lENT := lSAI := .F.
    Local cCampo := ""
    Local xRet := Nil
 
    //Carrega variaveis de Entrada e Saida
    If Type("ParamIxb") == "A"
        cCampo := ParamIXB[1]
        cFilMov := ParamIXB[2]
        cEmpMov := ParamIXB[3]
    EndIf
 
    Do Case
        Case cCampo == "TTI_DESSIT"
            xRet := NGSEEK("ZY0",If(M->TTI_TIPMOV == '1',M->TTI_SITENT,M->TTI_SITSAI),01,"ZY0_DESSIT")
        Case cCampo == "TTI_REGORI"
            If M->TTI_TIPMOV == '1'
                xRet := NGSEEK("DUY",M->TTI_CDRORE,01,"DUY_DESCRI",cFilMov,cEmpMov)
            ElseIf M->TTI_TIPMOV == '2'
                xRet := NGSEEK("DUY",M->TTI_CDRORS,01,"DUY_DESCRI",cFilMov,cEmpMov)
            EndIf
    EndCase
 
    RestArea(aArea)
 
Return xRet