PE NGGERAOS validar geracao Ordem de Servico

#include 'protheus.ch'
#include 'parmtype.ch'
 
//---------------------------------------------------------------------
/*/{Protheus.doc} NGGERAOS
Verificar se deverá gerar O.S. caso a mesma já tenha sido aglutinada em outra.
 
@author NG Informática
@since 08/02/2018
@version MP11
@return
/*/
//---------------------------------------------------------------------
User Function NGGERAOS()
     
    Local cCodbem   := ParamIXB[1]
    Local cServico  := ParamIXB[2]
    Local cSequec   := Alltrim(ParamIXB[3])
    Local cQuery    := ""
    Local cAliasQry := GetNextAlias()
    Local aOldArea  := GetArea()
    Local aSeq      :={}
    Local aGeraOS   := {}
    Local nX        := 0
     
    cQuery := "SELECT TJ_SUBSTIT FROM "  + RetSqlName("STJ")
    cQuery += " WHERE TJ_FILIAL = " + ValToSql(xFilial("STJ"))
    cQuery += " AND TJ_CODBEM = " + ValToSql(cCodbem)
    cQuery += " AND TJ_SERVICO = " +  ValToSql(cServico)
    cQuery += " AND TJ_SITUACA = 'L' AND TJ_TERMINO ='N' AND TJ_PLANO ='000001' "
    cQuery += " AND D_E_L_E_T_ <> '*' AND TJ_SUBSTIT <> ''"
 
    cQuery := ChangeQuery(cQuery)
    dbUseArea(.T., "TOPCONN", TCGenQry(,,cQuery), cAliasQry, .F., .T.)
     
    Dbselectarea(cAliasQry)
    DBgotop()
    While !Eof()
        aSeq := StrTokArr((cAliasQry)->TJ_SUBSTIT, ",")
        For nX:=1 to len(aSeq)
            cSeq := Alltrim(aSeq[nX])
            If cSequec ==  cSeq
                AADD(aGeraOS,{'N','O.S. já foi substituida'})
                (cAliasQry)->(DbCloseArea())
                Return aGeraOS
            EndIf
        Next nX        
        DbSkip()
    End While
 
(cAliasQry)->(DbCloseArea())
RestArea(aOldArea)
 
Return aGeraOS