FwDialogModal

Classe: FwDialogModal

Descrição

Mostra uma dialog Modal

New()

Sintaxe
oModal:=FWDialogModal():New()

Descrição

Gera uma instância da classe FWDialogModal

createDialog()

Sintaxe

FWDIALOGMODAL():createDialog()-> NIL

Descrição

Método responsável por criar a janela e montar os paineis.
Esse método não ativa a classe, ele apenas cria os componentes.
Para ativar a classe é necessário usar o método activate.

activate

Sintaxe

FWDIALOGMODAL():activate()-> NIL

Descrição

Método responsável por ativar a janela.

getPanelMain

Sintaxe

FWDIALOGMODAL():getPanelMain()-> NIL

Descrição

Método responsável por retornar o painel principal da janela.
Esse painel é o painel onde devem ser colocados os componentes que
se deseja mostra na janela.

addCloseButton

Sintaxe

FWDIALOGMODAL():addCloseButton([ bClose ])-> NIL

Descrição

Método responsável por criar um botão "Fechar" na janela.

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
bClose	Bloco de Código	Bloco de código que deve ser acionado no botão	{\|\| SELF:OOWNER:END()}

Exemplo

#Include "protheus.ch"  

//-------------------------------------------------------------------
/*/{Protheus.doc} modalTest
 Exemplo de uso da função FWInputBox
 
@author  FRAMEWORK
@since   30/08/2024
@version 1.0
/*/
//------------------------------------------------------------------

User Function modalTest()
Local oModal
Local oContainer
 
 
    oModal:= FWDialogModal():New()       
    oModal:SetEscClose(.T.)
    oModal:setTitle("título da Janela ")
    oModal:setSubTitle("SubTitulo da Janela")
     
    //Seta a largura e altura da janela em pixel
    oModal:setSize(200, 140)
    


	 addOkButton(MsgInfo,"Teste")


    
    oModal:createDialog()
    oModal:addCloseButton(nil, "Fechar")
    oModal:addOkButton(MsgInfo,"Teste")
    oContainer := TPanel():New( ,,, oModal:getPanelMain() )
    oContainer:SetCss("TPanel{background-color : red;}")
    oContainer:Align := CONTROL_ALIGN_ALLCLIENT
    
    TSay():New(1,1,{|| "Teste "},oContainer,,,,,,.T.,,,30,20,,,,,,.T.)
         
    oModal:Activate()
Return

addYesNoButton

Sintaxe

FWDIALOGMODAL():addYesNoButton()-> NIL

Descrição

Método responsável por criar os botões "Não" e "Sim", deixando como
focal o botão "Sim".

Veja também

Método getButtonSelected

addNoYesButton

Sintaxe

FWDIALOGMODAL():addNoYesButton()-> NIL

Descrição

Método responsável por criar os botões "Não" e "Sim", deixando como
focal o botão "Não".

Veja também

Método getButtonSelected

addExitPageButton

Sintaxe

FWDIALOGMODAL():addExitPageButton([ bClose ], [ bSave ], [ bGoBack ])-> NIL

Descrição

Método responsável por criar os botões "Sair da página", "Continuar Editando" e "Salvar".

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
bClose	Bloco de Código	Bloco de código usado no botão "Sair da Página"	{\|\| }
bSave	Bloco de Código	Bloco de código usado no botão "Salvar"	{\|\| }
bGoBack	Bloco de Código	Bloco de código usado no botão "Continuar Editando"	{\|\| }

addButtons

Sintaxe

FWDIALOGMODAL():addButtons(<aButtons >)-> NIL

Descrição

Método responsável por criar botões na barra.

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
aButtons	Array	array com as informações dos botões, na seguinte estrutura: [n] [n][1] Compatibilidade (Parâmetro descontinuado no P12) [n][2] cTitle Titulo do Botao [n][3] bBloco Bloco de codigo que será executado [n][4] cToolTip Comentário do botão [n][5] nShortCut Tecla para se criar o ShortCurt [n][6] lShowBar Indica que o botão estará visível na barra [n][7] lConfig Indica se botao estara visivel na configuracao		X

AddUserBtn

Sintaxe

FWDIALOGMODAL():AddUserBtn()-> NIL

Descrição

long_description

setUIDelete

Sintaxe

FWDIALOGMODAL():setUIDelete()-> NIL

Descrição

Método responsável por definir que a janela deve exibir a interface
de janela de exclusão de formulário.

createDeletePanel

Sintaxe

FWDIALOGMODAL():createDeletePanel()-> NIL

Descrição

Método responsável por criar o conteudo do painel superior quando a
janela é do tipo UIDelete.
Quando a janela modal é usada como uma interface de exclusão, o painel
superior exibe uma imagem diferenciada.

enableFormBar

Sintaxe

FWDIALOGMODAL():enableFormBar()-> NIL

Descrição

Método responsável por habilitar/desabilitar a barra de botões da
janela. O padrão é exibir a barra.

enableAllClient

Sintaxe

FWDIALOGMODAL():enableAllClient()-> NIL

Descrição

Método responsável por definir que a janela deve ocupar a tela inteira.

getButtonSelected

Sintaxe

FWDIALOGMODAL():getButtonSelected()-> nOption

Descrição

Método responsável por retornar qual botão o usuário selecionou.
Esse método somente tem utilidade caso a janela esteja sendo usada
com os botões "Sim" e "Não".

Retorno

nOption Retorna 1 caso tenha sido selecionado o botão "Sim" e
retorna 0 caso tenha sido selecionado o botão "Não"

Veja também

Método addNoYesButton
Método addYesNoButton

setTimer

Sintaxe

FWDIALOGMODAL():setTimer(<nTempo >, <bAction >)-> NIL

Descrição

Set um Timer na Dlg

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
nTempo	Numérico	Tempo em segundos		X
bAction	Bloco de Código	Acao do Timer	{\|\| SELF:OOWNER:END()}	X

setValid

Sintaxe

FWDIALOGMODAL():setValid()-> NIL

Descrição

Seta a Validacao do dialog

setWhen

Sintaxe

FWDIALOGMODAL():setWhen()-> NIL

Descrição

Seta o when do dialog

setCloseButton

Sintaxe

FWDIALOGMODAL():setCloseButton()-> NIL

Descrição

Define a visibilidade do botão de fechar na janela do diálogo.

setSubTitle

Sintaxe

FWDIALOGMODAL():setSubTitle(<cSubTitle >)-> NIL

Descrição

Define um subtitulo para a janela.

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
cSubTitle	Caracteres	Sub Titulo da janela		X

setCloseBlock

Sintaxe

FWDIALOGMODAL():setCloseBlock(<bClose >)-> NIL

Descrição

Define um bloco de código para o botão fechar.

Parâmetros

Nome	Tipo	Descrição	Obrigatório	Referência
bClose	Bloco de Código	bloco de código	X

SetTitle

Sintaxe

FWDIALOGMODAL():SetTitle(<cTitle >)-> NIL

Descrição

Seta o titulo da Janela.

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
cTitle	Caracteres	Nome da janela		x

addOkButton

Sintaxe

addOkButton(bOk, cTitle, bAccOk, bWhen)

Parâmetros

Parâmetro	Tipo	Descrição	Obrigatório
bOk	Block	Bloco de código a ser executado quando o botão "OK" for acionado.	Não
cTitle	Character	Título do botão "OK"	Não
bAccOk	Block	Bloco de código adicional a ser executado ao acionar o botão "Ok"	Não
bWhen	Block	Bloco de código que determina quando o botão "Ok" deve estar habilitado	Não

Exemplo

#Include "protheus.ch"  

//-------------------------------------------------------------------
/*/{Protheus.doc} modalTest
 Exemplo de uso da função FWInputBox
 
@author  FRAMEWORK
@since   30/08/2024
@version 1.0
/*/
//------------------------------------------------------------------

User Function modalTest()
Local oModal
Local oContainer
 
 
    oModal:= FWDialogModal():New()       
    oModal:SetEscClose(.T.)
    oModal:setTitle("título da Janela ")
    oModal:setSubTitle("SubTitulo da Janela")
     
    //Seta a largura e altura da janela em pixel
    oModal:setSize(200, 140)     

    MsgInfo("Msg teste")    

    oModal:createDialog()
    oModal:addCloseButton(nil, "Fechar")
    oModal:addOkButton(MsgInfo,"Teste")    
    oContainer := TPanel():New( ,,, oModal:getPanelMain() )
    oContainer:SetCss("TPanel{background-color : red;}")
    oContainer:Align := CONTROL_ALIGN_ALLCLIENT
    
    TSay():New(1,1,{|| "Teste "},oContainer,,,,,,.T.,,,30,20,,,,,,.T.)
         
    oModal:Activate()
Return

Descrição

Método responsável por criar um botão "Ok" na janela.

SetSize

Sintaxe

SetSize(nWidth, nHeigth)

Descrição

Define o tamanho da janela de diálogo ajustando a largura e altura.

Parâmetros

Parâmentro	Tipo	Descrição	Obrigatório
nWidth	Numérico	Largura da janela em pixels.	Sim
nHeight	Numérico	Altura da janela em pixels.	Sim

SetBackground

Sintaxe
FWDIALOGMODAL ():setBackground([ lBackground ])-> NIL

Descrição

Método responsável por definir se será usado painel para escurecer o fundo da janela.

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
lBackground	Lógico	Boleano que seta o uso do painel	.T.

Importante

A janela que irá ser definida para escurecer o fundo não poderá ser a principal (workspace ativa).

setFreeArea

Sintaxe
FWDIALOGMODAL ():setFreeArea(<nWidth >, <nHeigt >)-> NIL

Descrição
Método responsável por definir qual será o tamanho da janela.

Parâmetros

Nome	Tipo	Descrição	Default	Obrigatório	Referência
nWidth	Numérico	Largura		X
nHeigt	Numérico	Altura		X

SetEscClose

Sintaxe

SetEscClose(lEscClose)

Descrição

Habilita ou desabilita o fechamento da janela utilizando a tecla "Esc"

Parâmetro

Parâmetro	Tipo	Descrição	Obrigatório
lEscClose	Lógico	Define se o fechamento pelo Esc é permitido (.T.) ou (.F.)	Sim

SetInitBlock

Sintaxe

SetInitBlock(bSet)

Descrição

Permite informar um bloco de código que será executado na inicialização da modal

Parâmetro

Parâmetro	Tipo	Descrição	Obrigatório
bSet	Bloco de código	Define um bloco de código que será executado na inicialização da modal	Sim

Exemplo de uso:

Exemplo

#include "protheus.ch"  

//-------------------------------------------------------------------
/*/{Protheus.doc} modalTest
Exemplo de uso da função FWInputBox
 
@author  FRAMEWORK
@since   30/08/2024
@version 1.0
/*/
//------------------------------------------------------------------
User Function modalTest()
Local oModal as object
Local oContainer as object

    oModal  := FWDialogModal():New()       
    oModal:SetEscClose(.T.)
    oModal:setTitle("título da Janela ")
    oModal:setSubTitle("SubTitulo da Janela")
     
    //Seta a largura e altura da janela em pixel
    oModal:setSize(200, 140)

    MsgInfo("Msg teste")

    oModal:createDialog()
    oModal:addCloseButton(nil, "Fechar")
    oModal:addOkButton(MsgInfo,"Teste")  // Exemplo demonstra como utilizar o método 
    oContainer := TPanel():New( ,,, oModal:getPanelMain() )
    oContainer:SetCss("TPanel{background-color : red;}")
    oContainer:Align := CONTROL_ALIGN_ALLCLIENT
    
    TSay():New(1,1,{|| "Teste "},oContainer,,,,,,.T.,,,30,20,,,,,,.T.)
         
    oModal:Activate()
Return

Índice

Páginas filhas

FwDialogModal

activate

getPanelMain

addCloseButton

addYesNoButton

addNoYesButton

addExitPageButton

addButtons

createDeletePanel

enableFormBar

enableAllClient

getButtonSelected

setTimer

setValid

setWhen

setCloseButton

setSubTitle

setCloseBlock

SetTitle

addOkButton

Sintaxe

SetSize

Sintaxe

SetEscClose

SetInitBlock