HTTPCPost

Esta função permite consumir o método POST de uma API Rest a partir da estação de trabalho.

Importante

Esta função depende do WebAgent para ser utilizada via WebApp, pois será executada na estação de trabalho.

Sintaxe

HttpCPost( < cUrl >, [ cPostParms ], [ nTimeOut ], [ aHeadStr ], [ @cHeaderGet ] )

Parâmetros

Nome	Tipo	Descrição	Obrigatório	Referência
cUrl	caractere	Indica o endereço HTTP com a pasta e o documento solicitado.	X
cPostParms	caractere	Indica uma string de parâmetros, do tipo POST, que serão enviados ao servidor HTTP através da URL. Caso não seja especificado, este parâmetro será considerado vazio ("").
nTimeOut	numérico	Indica o tempo, em segundos, máximo de inatividade permitido durante a recepção do documento. Caso não seja especificado, o valor assumido será de 120 segundos.
aHeadStr	vetor	Indica o array que contêm as strings que serão acrescentadas no header da requisição HTTP que será realizada. Utilizar "\|" (pipes) para separação entre parâmetro e valor.
cHeaderGet	caractere	Indica a string que conterá o header de resposta HTTP enviado pelo servidor requisitado. Observação: A variável deve ser declarada antes da chamada da função.		X

Retorno

Nome	Tipo	Descrição
cRet	caractere	Retorna a string que corresponde a requisição solicitada.

Observações

Importante: Função disponível em versões iguais ou superiores a 7.00.111010P

O parâmetro cPostParms representa um texto que será enviado via "Post". (Exemplo "param1=value1&m2=value2").
Caso não seja retornado o documento antes do término do time-out, especificado na chamada da função, ou não seja possível localizar o servidor; seja por falha de resolução de DNS ou por erro de sintaxe ao especificar a URL, a função retornará nulo (NIL).
Ao utilizar a função HTTPCPost(), pode-se especificar um Content-Type diferenciado para o conteúdo postado. Caso não seja especificado um Content-Type, alguns servidores tratam a informação postada como sendo um dado do tipo 'application/x-www-form-url', ou seja, seria o equivalente a um formulário HTML postado via browser. Desta forma, outros servidores poderão não reconhecer tal informação postada dessa forma. Para especificar que o conteúdo postado deve ser tratado como um POST de formulário HTTP, deve-se passar no parâmetro um elemento 'Content-Type: application/x-www-form-url'.
Mais informações sobre Content-Type, acesse os links a seguir:

Exemplos

1-Consumindo uma API Rest de testes

Neste primeiro exemplo utilizaremos para testes um mini servidor Rest, capaz de responder os métodos GET e POST.

Para acessar o exemplo do mini servidor Rest clique aqui.

Este fonte, na linguagem TLPP, envia o conteúdo de uma variavel do tipo JSON para o metodo POST de uma API de teste

httpcpost.tlpp

#include "protheus.ch"

// Funcao envia o conteudo de uma variavel do tipo JSON
// para o metodo POST de uma API de teste
Function u_HttpCPost()
  Local cUrl := "http://localhost:3333/postJson"
  
  // JSON para testes de envio
  Local oPostPar := {"template":"AQAAABQAAACEAQAAAQASAAMAZAAAAAAAgAEAAH2CDU7keLcCA0aog19vXa0IXbXH4eUkOvWEDD2PBqXwZedxxCkWflZytlYal4QsDC35NggrdNniVZ2aL69I7KOXAkV9WIwC0tAFfDlf7hZeZ2UY/54FkRNF5bxw27e7O3L/xwxENHNOtqF5YH9tI2H2Z*x1buX23HMAbykimzyAcGMsx9Ng/jq1v7lFVXkbiM2RgutC5JwyZC14EhwrviEEsBh67NCWALkGNb*/FG7uJ8Tk/J4ohXtcqN5BoES8aeWHGeWOPLs0GWKjb8Tf8gnOq8r9OHHpyye2qeTv7UjV/sHShe7ey2LhZVVJ9gQfrzr975wlm9mlkTZxSjpWiI9iAa3CWZQORGKKLVPUPhWw6Idyq/sVS5BtVeJgPmRLSh4UYLOQ3Dh4CUnQ9ApbofC6KSdRXVVg8j5CZdyVS56WkBTF*lCa8NW/Y2B1ain*sc2eo/H7IqKvjHmO9Qe37PwVGTSSDId2PDQol7BbYYk2EpsOzC933RDp1vTaOxD1sQ"}

  Local cPostPar := oPostPar:toJson() // Converte JSON pra texto
  Local nTimeOut  := 2 // Segundos
  Local aHeaderStr:= {}
  Local cHeaderRet:= ""
  Local cResponse := ""
  Local cErro     := ""
  Local cMsgAlert := "HttpCPost()"
  
  aAdd(aHeaderStr,"Content-Type| application/json")
  aAdd(aHeaderStr,"Content-Length| " + Alltrim(Str(Len(cPostPar))) )

  cResponse := HttpCPost( cUrl , cPostPar , nTimeOut , aHeaderStr , @cHeaderRet )
  cMsgAlert += VarInfo("Header:", cHeaderRet )
  cMsgAlert += VarInfo("Retorno:", cResponse )
  cMsgAlert += VarInfo("Erro:", HTTPGetStatus(cErro) )
  cMsgAlert += VarInfo("Erro:", cErro )
  MsgAlert(cMsgAlert)
Return

Fonte sendo executado via WebApp com o WebAgent ativo.

2-Consumindo uma API externa

Neste segundo exemplo será consumido uma API enviando o Content-Type application/x-www-form-urlencoded.

Exemplo 2

#INCLUDE "TOTVS.CH"
User Function tstCpost()
  Local cUrl     := "endereço do post"
  Local cPostPar := "String a ser eviada"
  Local nTimeOut  := 2 //Segundos
  Local aHeaderStr:= {}
  Local cHeaderRet:= ""
  Local cResponse  := ""
  Local cErro    := ""
  cPostPar := 'Conteudo a ser enviado via Post'
  aAdd(aHeaderStr,"Content-Type| application/x-www-form-urlencoded")
  aAdd(aHeaderStr,"Content-Length| " + Alltrim(Str(Len(cPostPar))) )
  cResponse := HttpCPost( cUrl , cPostPar , nTimeOut , aHeaderStr , @cHeaderRet )
  VarInfo("Header:", cHeaderRet )
  VarInfo("Retorno:", cResponse )
  VarInfo("Erro:", HTTPGetStatus(cErro) )
  VarInfo("Erro:", cErro )
Return

Veja também

Interface HTTP

Árvore de páginas