TOTVSTEC

Árvore de páginas

Construtor TCBrowse:New

Método construtor da classe.

Sintaxe

TCBrowse():New( [ nRow ], [ nCol ], [ nWidth ], [ nHeight ], [ bLine ], [ aHeaders ], [ aColSizes ], [ oWnd ], [ cField ], [ uValue1 ], [ uValue2 ], [ bChange ], [ bLDblClick ], [ bRClicked ], [ oFont ], [ oCursor ], [ nClrFore ], [ nClrBack ], [ cMsg ], [ uParam20 ], [ cAlias ], [ lPixel ], [ bWhen ], [ uParam24 ], [ bValid ], [ lHScroll ], [ lVScroll ] )

Parâmetros

Nome

Tipo

Descrição

Obrigatório

Referência

nRow

numérico

Indica a coordenada vertical.



nCol

numérico

Indica a coordenada horizontal.



nWidth

numérico

Indica a largura em pixels do objeto.



nHeight

numérico

Indica a altura em pixels do objeto.



bLine

bloco de código

Indica o bloco de código da lista de campos. Observação: Esse parâmetro é utilizado somente quando o browse trabalha com array.



aHeaders

vetor

Indica o título dos campos no cabeçalho.



aColSizes

vetor

Indica a largura das colunas.



oWnd

objeto

Indica o controle visual onde o divisor será criado.



cField

caractere

Indica os campos necessários para o filtro.



uValue1

qualquer

Indica o início do intervalo para o filtro.



uValue2

qualquer

Indica o fim do intervalo para o filtro.



bChange

bloco de código

Indica o bloco de código que será executado ao mudar de linha.



bLDblClick

bloco de código

Indica o bloco de código que será executado quando clicar duas vezes, com o botão esquerdo do mouse, sobre o objeto.



bRClicked

bloco de código

Indica o bloco de código que será executado quando clicar, com o botão direito do mouse, sobre o objeto.



oFont

objeto

Indica o objeto do tipo TFont utilizado para definir as características da fonte aplicada na exibição do conteúdo do controle visual.



oCursor

objeto

Indica o tipo de ponteiro do mouse.



nClrFore

numérico

Indica a cor do texto da janela.



nClrBack

numérico

Indica a cor de fundo da janela.



cMsg

caractere

Indica a mensagem ao posicionar o ponteiro do mouse sobre o objeto.



uParam20

lógico

Compatibilidade.



cAlias

caractere

Indica se o objeto é utilizado com array (opcional) ou tabela (obrigatório).



lPixel

lógico

Indica se considera as coordenadas passadas em pixels (.T.) ou caracteres (.F.).



bWhen

bloco de código

Indica o bloco de código que será executado quando a mudança de foco da entrada de dados, na janela em que o controle foi criado, estiver sendo efetuada. Observação: O bloco de código retornará verdadeiro (.T.) se o controle permanecer habilitado; caso contrário, retornará falso (.F.).



uParam24

lógico

Compatibilidade.



bValid

bloco de código

Indica o bloco de código de validação que será executado quando o conteúdo do objeto for modificado. Retorna verdadeiro (.T.), se o conteúdo é válido; caso contrário, falso (.F.).



lHScroll

lógico

Indica se habilita(.T.)/desabilita(.F.) a barra de rolagem horizontal.



lVScroll

lógico

Indica se habilita(.T.)/desabilita(.F.) a barra de rolagem vertical.



Retorno

Nome

Tipo

Descrição

oObj

objeto

Nova instância da classe TCBrowse

Exemplos

Exemplo 1
#include "TOTVS.CH"
 
USER FUNCTION TCBrowse()
Local oOK := LoadBitmap(GetResources(),'br_verde')
Local oNO := LoadBitmap(GetResources(),'br_vermelho')
Local aList := {}
 
    DEFINE DIALOG oDlg TITLE "Exemplo TCBrowse" FROM 180,180 TO 550,700 PIXEL
 
        // Vetor com elementos do Browse
        aBrowse := { {.T.,'CLIENTE 001','RUA CLIENTE 001',111.11},;
                     {.F.,'CLIENTE 002','RUA CLIENTE 002',222.22},;
                     {.T.,'CLIENTE 003','RUA CLIENTE 003',333.33} }
 
        // Cria Browse
        oBrowse := TCBrowse():New( 01 , 01, 260, 156,, {'','Codigo','Nome','Valor'},{20,50,50,50}, oDlg,,,,,{||},,,,,,,.F.,,.T.,,.F.,,, )
 
        // Seta vetor para a browse
        oBrowse:SetArray(aBrowse)
 
        // Monta a linha a ser exibina no Browse
        oBrowse:bLine := {||{ If(aBrowse[oBrowse:nAt,01],oOK,oNO),;
                                 aBrowse[oBrowse:nAt,02],;
                                 aBrowse[oBrowse:nAt,03],;
                                 Transform(aBrowse[oBrowse:nAT,04],'@E 99,999,999,999.99') } }
 
        // Evento de clique no cabeçalho da browse
        oBrowse:bHeaderClick := {|o, nCol| alert('bHeaderClick') }
 
        // Evento de duplo click na celula
        oBrowse:bLDblClick := {|| alert('bLDblClick') }
 
        // Cria Botoes com metodos básicos
        TButton():New( 160, 002, "GoUp()", oDlg,{|| oBrowse:GoUp(), oBrowse:setFocus() },40,010,,,.F.,.T.,.F.,,.F.,,,.F. )
        TButton():New( 160, 052, "GoDown()" , oDlg,{|| oBrowse:GoDown(), oBrowse:setFocus() },40,010,,,.F.,.T.,.F.,,.F.,,,.F. )
        TButton():New( 160, 102, "GoTop()" , oDlg,{|| oBrowse:GoTop(),oBrowse:setFocus()}, 40, 010,,,.F.,.T.,.F.,,.F.,,,.F.)
        TButton():New( 160, 152, "GoBottom()", oDlg,{|| oBrowse:GoBottom(),oBrowse:setFocus() },40,010,,,.F.,.T.,.F.,,.F.,,,.F.)
        TButton():New( 172, 002, "Linha atual", oDlg,{|| alert(oBrowse:nAt) },40,010,,,.F.,.T.,.F.,,.F.,,,.F. )
        TButton():New( 172, 052, "Nr Linhas", oDlg,{|| alert(oBrowse:nLen) },40,010,,,.F.,.T.,.F.,,.F.,,,.F. )
        TButton():New( 172, 102, "Linhas visiveis", oDlg,{|| alert(oBrowse:nRowCount()) },40,010,,,.F.,.T.,.F.,,.F.,,,.F.)
        TButton():New( 172, 152, "Alias", oDlg,{|| alert(oBrowse:cAlias) },40,010,,,.F.,.T.,.F.,,.F.,,,.F.)
 
    ACTIVATE DIALOG oDlg CENTERED
RETURN
  • Sem rótulos