Histórico da Página

Este parámetro solo es necesario cuando se tiene configurado el grupo de preguntas FINA998BUS.

#Include 'Protheus.ch'

User Function F998BRFLT
   Local querySelect := Paramixb[1]
   Local queryWhere := Paramixb[2]
   Local queryOption := Paramixb[3]
   Local whereNew := " AND SEL.EL_RECIBO >= '0040' "
   Local queryNew := ""

   IF queryOption == 'complete'
         queryNew := " SELECT " + querySelect + " AS totalreceipts FROM " + RetSqlName("SEL")
         queryNew += +" SEL WHERE " + queryWhere + whereNew
   ELSEIF queryOption == 'where'
         queryNew := queryWhere + whereNew
   ENDIF

RETURN queryNew

User Function F998BRFLT()

Local querySelect := Paramixb[1]
Local queryWhere  := Paramixb[2]
Local queryOption := Paramixb[3]
Local jPergunte   := Paramixb[4] // Objeto Json de Preguntas
Local whereNew := " "
Local queryNew := ""

      IF  jPergunte['form']['mv_par11'] != ""
        whereNew :=" AND EL_NATUREZ = '"+jPergunte['form']['mv_par11']+"' "
      EndIF

      IF queryOption == 'complete'
            queryNew := " SELECT " + querySelect + " AS totalreceipts FROM " + RetSqlName("SEL")
            queryNew += +" SEL WHERE " + queryWhere + whereNew
      ELSEIF queryOption == 'where'
            queryNew := queryWhere + whereNew
      ENDIF

RETURN queryNew

• El Punto de Entrada F887ROT proporciona una herramienta para que los usuarios puedan realizar acciones en el recibo seleccionado. Sin embargo, la decisión de realizar estas acciones son responsabilidad del cliente.
• El sistema no válida ni verifica la información alterada o consultada por el usuario. Por lo tanto, el cliente debe asegurarse de que los cambios realizados en el recibo sean correctos y no generen problemas posteriores.
• Al ejecutar la función de usuario, los datos del recibo seleccionado vienen en memoria, por lo cual el cliente puede hacer uso de ellas. Ejemplo:
  • FJT->FJT_CLIENT == '000001'  o SEL->EL_CLIENTE == '000001'. Las variables de memoria se posicionarán con prioridad en la tabla FJT (Encabezado de recibo). En caso de que el recibo no cuente con datos en dicha tabla, se actualizaran las variables de memoria a datos de la tabla de SEL (Recibos de cobro).
• La función de usuario retornada en el PE F887ROT debe estar compilada en RPO, de lo contrario marcará error.

#Include 'Protheus.ch'

User Function F887ROT

    Local aData	As Array

    aData := {"CANCEL FORZA","EjemploPE"} //{Nombre de la nueva opción,Funcion a ejecutarse}

Return aData


User Function EjemploPE()
    Local aRet := {}
    
    IF PARAMIXB[1] == "FJT"
        IF FJT->FJT_CLIENT == '000001'  //Cancelara recibos que pertenezcan a este cliente
            RecLock("FJT",.F.)
	        Replace FJT_CANCEL With "1"
	        MsUnLock()
            aRet:={.T.,"PE Ejecutado correctamente"} //{.T.,Mensaje personalizado}
        ELSE
            aRet:={.F.,"ESTE CLIENTE NO PERMITE MODIFICACIONES"} //{.F.,Mensaje personalizado}
        ENDIF
    ELSEIF PARAMIXB[1] == "SEL"
        IF SEL->EL_CLIENTE == '000001'  //Cancelara recibos que pertenezcan a este cliente
            RecLock("SEL",.F.)
	        Replace EL_CANCEL With .T.
	        MsUnLock()
            aRet:={.T.,"PE Ejecutado correctamente"} //{.T.,Mensaje personalizado}
        ELSE
            aRet:={.F.,"ESTE CLIENTE NO PERMITE MODIFICACIONES"} //{.F.,Mensaje personalizado}
        ENDIF
    ELSE    
            aRet:={.F.,"NO SE LOCALIZARON DATOS (FJT y SEL)"} //{.T.,Mensaje personalizado}
    ENDIF
Return aRet

#INCLUDE "Totvs.ch"
 
/*/{Protheus.doc} F998NROK
Punto de entrada que permite agregar validaciones al recibo antes del guardado
Si retorna un .T. procedera con el guardado del recibo
Si retorna un .F. no continuara con el guardado del recibo
/*/
USER FUNCTION F998NROK()
    Local jFormasPago   := Paramixb[1] //Json que contiene todas las formas de pago del recibo
    Local jTitulos      := Paramixb[2] //Json que contiene todos los titulos que contiene el recibo
    Local jEncabezado   := Paramixb[3] //Json que contiene los datos que conforman el encabezado del recibo
    Local lRet     := .T. As Logical
    Local aRet     := {}  As Array
    Local nCont    As Numeric
    Local cMensaje  := "" As Character
    Local nTipoDoc  As Numeric
    
    //Ejemplo de validaciones en las formas de pago que contiene el recibo
    FOR nCont := 1 TO LEN(jFormasPago)
        nTipoDoc  := AScan(jFormasPago[nCont],{|x|x['property'] == "tipodoc"})
        IF jFormasPago[nCont][nTipoDoc]['value'] == "EF"
            lRet := .F.
            cMensaje := "No se permite guardar recibos con forma de pago tipo EF-Efectivo"
            AADD(aRet,{lRet,cMensaje})
        ENDIF
    NEXT

    /*
    //Ejemplo de validaciones en los titulos que contiene el recibo
    FOR nCont := 1 TO LEN(jTitulos)
        IF jTitulos[nCont]['series'] == "A"
            lRet := .F.
            cMensaje := "No se permite guardar un recibo con un titulo de serie A"
            AADD(aRet,{lRet,cMensaje})
        ENDIF
    NEXT
    */

    /*
    //Ejemplo de validaciones sobre el encabezado del recibo
    IF ALLTRIM(jEncabezado['modalidad']) == "COBRO"
        lRet := .F.
        cMensaje := "No se permite guardar un recibo con una modalidad dde tipo COBRO"
        AADD(aRet,{lRet,cMensaje})
    ENDIF
    */

RETURN aRet

#Include 'Protheus.ch'

User Function F998NRG2()   

Local oModel:=PARAMIXB[1]
MsgYesNo("ATENCIÓN" , "Se manda a llamar la funcion de usuario") 

Return

#Include 'Protheus.ch'

User Function F998NRG1()      

MsgYesNo("ATENCIÓN" , "Se manda a llamar la funcion de usuario") 

Return

#Include 'Protheus.ch'

User Function F998VALBX()

    Local oResponse := JsonObject():New() as Object
    
    IF PARAMIXB[2]  //Vista
        IF PARAMIXB[1]['recalculate']
            oResponse:=setValues(PARAMIXB[1])
        ELSE
	        oResponse['label']              := "% Descuento por pronto pago"        //Nombre del campo nuevo a mostrar.
            oResponse['readonlyDiscount']   := .T.                  //Deshabilitar o habilitar el campo de descuento.
            oResponse['readonlyInterest']   := .T.                  //Deshabilitar o habilitar el campo de Intereses.
            oResponse['readonlyFine']       := .T.                  //Deshabilitar o habilitar el campo de Multa.
            oResponse['disabledInput']      := .F.//isDisable(PARAMIXB[1]) //Deshabilitar o habilitar el input nuevo
            oResponse['maxDiscount']        := 50//GetLimite(PARAMIXB[1]) //Se informa el descuento permitido debe tener un rango mayor a 0 y menor a 100
            oResponse['warningMaxDiscount'] := "Descuento por Pronto Pago mayor al permitido. En esta condición el tope es:"+ALLTRIM(STR(oResponse['maxDiscount'])) //Mensaje personalizado por si se excede el descuento permitido, si no se informa el front mandara uno por default
        ENDIF
    ELSE 
       SaveData(PARAMIXB[1]) //Grabación
    ENDIF

Return oResponse

/*/{Protheus.doc} setValues
Esta funcion determina los valores a mostrar en los campos de descuento, residuo,multa e interes
@type function
@version  
@author luis.aboytes
@since 25/7/2024
@param oJson, object, param_description
@return variant, return_description
/*/
Static Function setValues(oJson)
    Local oRes := JsonObject():New()       }
	
	// El cálculo se realiza por el total del título si se utiliza el dato PARAMIXB[1]['bind']['saldo']
    
	oRes['descuento']  := Round(PARAMIXB[1]['bind']['discountInput']/100*PARAMIXB[1]['bind']['saldo'],2)     			//Calculo con el total del titulo
    oRes['residuo']    := Round(PARAMIXB[1]['bind']['saldo']-oRes['descuento'],MsDecimais(SE1->E1_MOEDA))    			//Calculo con el total del titulo
	oRes['multa']      := 0
    oRes['interes']    := 0

Return oRes

/*/{Protheus.doc} SaveData
Guardamos el dato en un campo en especifico
@type function
@author luis.aboytes
@since 18/7/2024
/*/
Static Function SaveData(oJsonData)
    Local nCont as Numeric

    For nCont := 1 to LEN(oJsonData['titulos'])
        SE1->(dbSetOrder(1))
	    SE1->(dbSeek(xFilial("SE1")+PADR(oJsonData['titulos'][nCont]['prefix'],GetSx3Cache("E1_PREFIXO","X3_TAMANHO"))+PADR(oJsonData['titulos'][nCont]['billnumber'],GetSx3Cache("E1_NUM","X3_TAMANHO"))+PADR(oJsonData['titulos'][nCont]['installment'],GetSx3Cache("E1_PARCELA","X3_TAMANHO"))))
        RecLock("SE1",.F.)
            SE1->E1_XPERDES :=	oJsonData['titulos'][nCont]['percentDiscount']
		MsUnLock()
    Next
Return

/*/{Protheus.doc} GetLimite
Se retorna el limite de descuento
@type function
@author luis.aboytes
@since 18/7/2024
/*/
Static Function GetLimite(oJsonData)
    Local nTope := 0

    SE1->(dbSetOrder(1))
	SE1->(dbSeek(xFilial("SE1")+PADR(oJsonData['prefix'],GetSx3Cache("E1_PREFIXO","X3_TAMANHO"))+PADR(oJsonData['billnumber'],GetSx3Cache("E1_NUM","X3_TAMANHO"))+PADR(oJsonData['installment'],GetSx3Cache("E1_PARCELA","X3_TAMANHO"))))

    nTope:=IIF(VAZIO(Posicione("SE4", 1,xFilial("SE4")+SE1->E1_XCONDPP,"E4_XDESCON")),0,Posicione("SE4", 1,xFilial("SE4")+SE1->E1_XCONDPP,"E4_XDESCON"))
Return nTope

/*/{Protheus.doc} isDisable
Funcion que retorna si es editable o no el valor del input
@type function
@author luis.aboytes
@since 18/7/2024
/*/
Static Function isDisable(oJsonData)
    Local lRet := .t.

    SE1->(dbSetOrder(1))
	SE1->(dbSeek(xFilial("SE1")+PADR(oJsonData['prefix'],GetSx3Cache("E1_PREFIXO","X3_TAMANHO"))+PADR(oJsonData['billnumber'],GetSx3Cache("E1_NUM","X3_TAMANHO"))+PADR(oJsonData['installment'],GetSx3Cache("E1_PARCELA","X3_TAMANHO"))))

    IF SE1->E1_XCONDPP == '999'
        lRet := .f.
    ENDIF

Return lRet

#Include 'Protheus.ch'

User Function F998VALBX()

    Local oResponse := JsonObject():New() as Object
    
    IF PARAMIXB[2]  //Vista
        IF PARAMIXB[1]['recalculate']
            oResponse:=setValues(PARAMIXB[1])
        ELSE
	        oResponse['label']              := "% Descuento por pronto pago"        //Nombre del campo nuevo a mostrar.
            oResponse['readonlyDiscount']   := .T.                  //Deshabilitar o habilitar el campo de descuento.
            oResponse['readonlyInterest']   := .T.                  //Deshabilitar o habilitar el campo de Intereses.
            oResponse['readonlyFine']       := .T.                  //Deshabilitar o habilitar el campo de Multa.
            oResponse['disabledInput']      := .F.//isDisable(PARAMIXB[1]) //Deshabilitar o habilitar el input nuevo
            oResponse['maxDiscount']        := 50//GetLimite(PARAMIXB[1]) //Se informa el descuento permitido debe tener un rango mayor a 0 y menor a 100
            oResponse['warningMaxDiscount'] := "Descuento por Pronto Pago mayor al permitido. En esta condición el tope es:"+ALLTRIM(STR(oResponse['maxDiscount'])) //Mensaje personalizado por si se excede el descuento permitido, si no se informa el front mandara uno por default
        ENDIF
    ELSE 
       SaveData(PARAMIXB[1]) //Grabación
    ENDIF

Return oResponse

/*/{Protheus.doc} setValues
Esta funcion determina los valores a mostrar en los campos de descuento, residuo,multa e interes
@type function
@version  
@author luis.aboytes
@since 25/7/2024
@param oJson, object, param_description
@return variant, return_description
/*/
Static Function setValues(oJson)
    Local oRes := JsonObject():New()       }
	
	// El cálculo se realiza con el dato ingresado en la moneda 1 o en cualquier moneda puede 
	// utilizar por ejemplo PARAMIXB[1]["coins"][1]['value'] para la moneda 1.
    
    oRes['descuento']  := Round(PARAMIXB[1]['bind']['discountInput']/100*PARAMIXB[1]["coins"][1]['value'],2)		 	//Calculo con el valor ingresado a pagar
    oRes['residuo']    := Round(PARAMIXB[1]["coins"][1]['value']-oRes['descuento'],MsDecimais(SE1->E1_MOEDA))   		//Calculo con el valor ingresado a pagar
    oRes['multa']      := 0
    oRes['interes']    := 0

Return oRes

/*/{Protheus.doc} SaveData
Guardamos el dato en un campo en especifico
@type function
@author luis.aboytes
@since 18/7/2024
/*/
Static Function SaveData(oJsonData)
    Local nCont as Numeric

    For nCont := 1 to LEN(oJsonData['titulos'])
        SE1->(dbSetOrder(1))
	    SE1->(dbSeek(xFilial("SE1")+PADR(oJsonData['titulos'][nCont]['prefix'],GetSx3Cache("E1_PREFIXO","X3_TAMANHO"))+PADR(oJsonData['titulos'][nCont]['billnumber'],GetSx3Cache("E1_NUM","X3_TAMANHO"))+PADR(oJsonData['titulos'][nCont]['installment'],GetSx3Cache("E1_PARCELA","X3_TAMANHO"))))
        RecLock("SE1",.F.)
            SE1->E1_XPERDES :=	oJsonData['titulos'][nCont]['percentDiscount']
		MsUnLock()
    Next
Return

/*/{Protheus.doc} GetLimite
Se retorna el limite de descuento
@type function
@author luis.aboytes
@since 18/7/2024
/*/
Static Function GetLimite(oJsonData)
    Local nTope := 0

    SE1->(dbSetOrder(1))
	SE1->(dbSeek(xFilial("SE1")+PADR(oJsonData['prefix'],GetSx3Cache("E1_PREFIXO","X3_TAMANHO"))+PADR(oJsonData['billnumber'],GetSx3Cache("E1_NUM","X3_TAMANHO"))+PADR(oJsonData['installment'],GetSx3Cache("E1_PARCELA","X3_TAMANHO"))))

    nTope:=IIF(VAZIO(Posicione("SE4", 1,xFilial("SE4")+SE1->E1_XCONDPP,"E4_XDESCON")),0,Posicione("SE4", 1,xFilial("SE4")+SE1->E1_XCONDPP,"E4_XDESCON"))
Return nTope

/*/{Protheus.doc} isDisable
Funcion que retorna si es editable o no el valor del input
@type function
@author luis.aboytes
@since 18/7/2024
/*/
Static Function isDisable(oJsonData)
    Local lRet := .t.

    SE1->(dbSetOrder(1))
	SE1->(dbSeek(xFilial("SE1")+PADR(oJsonData['prefix'],GetSx3Cache("E1_PREFIXO","X3_TAMANHO"))+PADR(oJsonData['billnumber'],GetSx3Cache("E1_NUM","X3_TAMANHO"))+PADR(oJsonData['installment'],GetSx3Cache("E1_PARCELA","X3_TAMANHO"))))

    IF SE1->E1_XCONDPP == '999'
        lRet := .f.
    ENDIF

Return lRet

#Include 'Protheus.ch'

User Function F998BRANU
     Local cSerie := Paramixb[1]
     Local cRecibo := Paramixb[2]
     Local cQueryWhere := ""
     Local cQueryFields := ""
     Local cAlias := GetNextAlias()
     Local aRet := {.T.,""}

     cQueryWhere := " FJT_FILIAL = '"+xFilial("FJT")+"' AND FJT_SERIE = '"+cSerie+"' AND FJT_RECIBO = '"+cRecibo+"' "

     cQueryFields := " FJT_SERIE,FJT_RECIBO,FJT_CLIENT,FJT_DTDIGI "

     cQuery := " SELECT "+cQueryFields+" FROM "+ RetSqlName("FJT") + " WHERE "+cQueryWhere

     cQuery := ChangeQuery(cQuery)
     MPSysOpenQuery(cQuery, cAlias)

     WHILE (cAlias)->(!EOF())
          IF (cAlias)->FJT_DTDIGI == DTOS(ddatabase)
               aRet := {.F.,"No se puede eliminar un recibo que haya sido generado el dia de hoy"}
          EndIf
          (cAlias)->(DbSkip())
     END
Return aRet

#Include 'Protheus.ch'

User Function F998BRBOR
     Local cSerie := Paramixb[1]
     Local cRecibo := Paramixb[2]
     Local cQueryWhere := ""
     Local cQueryFields := ""
     Local cAlias := GetNextAlias()
     Local aRet := {.T.,""}

     cQueryWhere := " FJT_FILIAL = '"+xFilial("FJT")+"' AND FJT_SERIE = '"+cSerie+"' AND FJT_RECIBO = '"+cRecibo+"' "

     cQueryFields := " FJT_SERIE,FJT_RECIBO,FJT_CLIENT,FJT_DTDIGI "

     cQuery := " SELECT "+cQueryFields+" FROM "+ RetSqlName("FJT") + " WHERE "+cQueryWhere

     cQuery := ChangeQuery(cQuery)
     MPSysOpenQuery(cQuery, cAlias)

     WHILE (cAlias)->(!EOF())
          IF (cAlias)->FJT_DTDIGI == DTOS(ddatabase)
               aRet := {.F.,"No se puede BORRAR un recibo que haya sido generado el dia de hoy"}
          EndIf
          (cAlias)->(DbSkip())
     END
Return aRet

#INCLUDE "Totvs.ch"
  
User Function F887FPG()
    Local cUser     := PARAMIXB[1]      //Parámetro en el cual se obtiene el nombre del usuario logueado
    Local cUseriD   := PARAMIXB[2]      //Parámetro en el cual se obtiene el ID del usuario logueado
    Local cWhere    := PARAMIXB[3]      //Where del Query que se utiliza para obtener los títulos en Panel General
    Local cAlias    := getNextAlias()   
    Local aSAQS     := {} As Array
    Local cCobrador := "" As Character
    Local cQryFields := "" As Character
    Local cQryWhere  := "" As Character
    Local cQuery    := "" As Character
    Local nX        := 0  As Numeric
    Local cAuxWhere := "" As Character
 
 
    //Definimos los campos a retornar en la instrucción SQL
    cQryFields := "AQ_COD,AQ_NOME"
    //Definimos la condición, en este caso de que el código del campo usuario sea igual al ID del usuario logueado
    cQryWhere  := " AQ_CODUSR ='"+ cUseriD +"' "
    //Definimos la estructura de la intrucción SQL a ejecutar
    cQuery := "SELECT "+ cQryFields +" FROM "+ retSqlName("SAQ") +" WHERE "+ cQryWhere
    //Ejecutamos la intrucción
    cQuery := changeQuery(cQuery)
 
    mpSysOpenQuery(cQuery, cAlias)
    (cAlias)->(DbGoTop())
    While (cAlias)->(!Eof())
        IF aScan(aSAQS,(cAlias)->AQ_COD) == 0 //Instrucción para no repetir cobradores en el array
            aadd(aSAQS,(cAlias)->AQ_COD)      //Agrega en un array los cobradores asociados con el cliente logueado 
        ENDIF
        (cAlias)->(dbSkip())
    ENDDO
    (cAlias)->(dbCloseArea())
 
    //Preparamos la cadena que se retornara con los cobradores
    IF !VAZIO(aSAQS)
        FOR nX := 1 To LEN(aSAQS)
            cCobrador += " E1_COBRAD =" + aSAQS[nX]
            IF nX < LEN(aSAQS)
               cCobrador += " OR "
            ENDIF
        NEXT
    ELSE
    //Opcional (En caso de que no tenga cobradores asociados)
        cCobrador := "E1_COBRAD = ''"
    ENDIF
 
    cAuxWhere := cWhere +' AND ( '+cCobrador+' )'
 
Return cAuxWhere