TFolder

TFolder(): New ( [ nTop], [ nLeft], [ aPrompts], [ aDialogs], [ oWnd], [ nOption], [ nClrFore], [ nClrBack], [ lPixel], [ uParam10], [ nWidth], [ nHeight], [ cMsg], [ uParam14] ) --> oObjeto

Nome	Tipo	Descrição	Obrigatório	Referência
nTop	Numérico	Indica a coordenada vertical em pixels ou caracteres.
nLeft	Numérico	Indica a coordenada horizontal em pixels ou caracteres.
aPrompts	Vetor	Indica o título das pastas.
aDialogs	Vetor	Indica o nome do diálogo.
oWnd	Objeto	Indica a janela ou controle visual onde o objeto será criado.
nOption	Numérico	Indica a pasta selecionada.
nClrFore	Numérico	Indica a cor de frente da pasta.
nClrBack	Numérico	Indica a cor de fundo da pasta.
lPixel	Lógico	Indica se considera as coordenadas passadas em pixels (.T.) ou caracteres (.F.).
uParam10	Lógico	Compatibilidade.
nWidth	Numérico	Indica a largura em pixels do objeto.
nHeight	Numérico	Indica a altura em pixels do objeto.
cMsg	Caracter	Indica a mensagem, do tipo dica de contexto (tooltip/hint), que será apresentada ao posicionar o ponteiro do mouse sobre o objeto.
uParam14	Lógico	Compatibilidade.

Retorno

oObjeto

Retorna o objeto criado.

oTFolder := TFolder():New( 0,0,aTFolder,,oDlg,,,,.T.,,260,184 )

Métodos

AddItem

Inclui uma pasta.

TFolder(): AddItem ( [ cItem], [ lVisible] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
cItem	Caracter	Indica a título da pasta.
lVisible	Lógico	Indica se a pasta está (.T.) ou não (.F.) visível.

oTFolder:AddItem("Nova Aba", .T.)

Preview

Exemplo do método AddItem

aEnable

Habilita/Desabilita uma pasta.

TFolder(): aEnable ( [ nItem], [ lEnable] ) --> lOk

Nome	Tipo	Descrição	Obrigatório	Referência
nItem	Numérico	Indica a pasta que será habilitada/desabilitada.
lEnable	Lógico	Indica se habilita(.T.)/desabilita(.F.) a pasta.

Retorno

lOk

Retorna verdadeiro (.T.), se o processo ocorrer com sucesso; caso contrário, retornará falso (.F.).

Observações

A pasta continuará visível, porém não será possível selecioná-la.

oTFolder:aEnable(2, .F.)

HidePage

Oculta uma pasta.

TFolder(): HidePage ( < nItem> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nItem	Numérico	Indica a pasta que será oculta.	X

oTFolder:HidePage(2)

SetOption

Seleciona a pasta desejada.

TFolder(): SetOption ( [ nOption] ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nOption	Numérico	Indica a pasta que será selecionada.

oTFolder:SetOption(2)

ShowPage

Apresenta uma pasta.

TFolder(): ShowPage ( < nItem> ) -->

Nome	Tipo	Descrição	Obrigatório	Referência
nItem	Numérico	Indica a pasta que será apresentada.	X

oTFolder:ShowPage(2)

Propriedade

Propriedade	Descrição	Tipo
aDialogs	Indica o nome dos diálogos.	Array of Record
aPrompts	Indica o título da pasta.	Array of Record
bSetOption	Indica o bloco de código que será executado quando a pasta for selecionada.	Bloco de código
nOption	Indica a pasta selecionada.	Numérico

Exemplo

#include "TOTVS.CH"

User Function TFolder()

	DEFINE DIALOG oDlg TITLE "Exemplo TFolder" FROM 180,180 TO 550,700 PIXEL
		// Cria a Folder    
		aTFolder := { 'Aba 01', 'Aba 02', 'Aba 03' }
		oTFolder := TFolder():New( 0,0,aTFolder,,oDlg,,,,.T.,,260,184 )

		// Insere um TGet em cada aba da folder    
		cTGet1 := "Teste TGet 01"
		oTGet1 := TGet():New( 01,01,{||cTGet1},oTFolder:aDialogs[1],096,009,;
              "",,0,,,.F.,,.T.,,.F.,,.F.,.F.,,.F.,.F.,,cTGet1,,,, )

		cTGet2 := "Teste TGet 02"
		oTGet2 := TGet():New( 01,01,{||cTGet2},oTFolder:aDialogs[2],096,009,;
              "",,0,,,.F.,,.T.,,.F.,,.F.,.F.,,.F.,.F.,,cTGet2,,,, )

		cTGet3 := "Teste TGet 03"
		oTGet3 := TGet():New( 01,01,{||cTGet3},oTFolder:aDialogs[3],096,009,;
              "",,0,,,.F.,,.T.,,.F.,,.F.,.F.,,.F.,.F.,,cTGet3,,,, )

	ACTIVATE DIALOG oDlg CENTERED
Return