F693MOED – Mudar Valor na prestação de contas avulsa.

01. DADOS GERAIS

Linha de Produto:	Microsiga Protheus®
Segmento:	Backoffice
Módulo:	Financeiro
Função:	FINA693A - Faturamento de Prestação de Contas Avulsa
Requisito/Story/Issue (informe o requisito relacionado) :	DSERFINP-29426

02. DESCRIÇÃO

A finalidade do ponto de entrada F693MOED é permitir capturar os valores a serem gerados no momento do faturamento contra clientes pelas rotinas de viagens. Chamado na rotina FNA693AIND, para gravação do campo FL6_VALOR.

03. PARÂMETROS

Nome	Tipo	Descrição
nVlMoeda1	Valor da Despesa na Moeda 1	Motivo da Baixa

04. RETORNO

Nome	Tipo	Descrição
nVlMoeda1	Novo Valor da Despesa na Moeda 1	Motivo da Baixa

05. EXEMPLO DE UTILIZAÇÃO

F693MOED

#include 'totvs.ch'

/*/{Protheus.doc} F693MOED()

    Ponto de Entrada para manutenção do Valor da Despesa no Faturamento de Prestação de Contas Avulsa
    função FNA693AIND
    @param Paramixb[1] - nVlMoeda1 - Valor da Despesa na Moeda 1

	@return nVlMoeda1 - Novo Valor da Despesa na Moeda 1
/*/
User Function F693MOED()
    Local nVlMoeda1 := ParamIXB[01] //Valor em Moeda 1
    Local nVlMoeda2 := 0 //Valor em Moeda 2
    Local nVlMoeda3 := 0 //Valor em Moeda 3

    Local aArea     := GetArea()

    //Verifica se é viagem internacional
    If (FLF->FLF_NACION == '2')
        //Buscando a Cotação da Moeda para o Dia
        SM2->(DBSetOrder(01)) //M2_DATA
        If (SM2->(DBSeek(FLF->FLF_DTFIM)))
            //Conversão de Valores para a Moeda 1
            nVlMoeda2 := (FLF->(FLF_TVLRE2 - FLF_TDESC2) * SM2->M2_MOEDA2)
            nVlMoeda3 := (FLF->(FLF_TVLRE3 - FLF_TDESC3) * SM2->M2_MOEDA4)
        EndIf

        //Somando valores à moeda 1
        nVlMoeda1 += (nVlMoeda2 + nVlMoeda3)
    EndIf

    RestArea(aArea)
Return nVlMoeda1

Árvore de páginas