TOTVSTEC

Árvore de páginas

Esta annotation deve ser utilizada quando for necessário desenvolver uma aplicação que responderá pelo método/verbo DELETE. Este método/verbo deleta o recurso especificado. Abaixo veremos exemplos de sua utilização:


Exemplo utilizando função e recebendo parâmetro via path param

#include "tlpp-core.th"
#include "tlpp-rest.th"
​
/* --------------------------------------------- */
@Delete("examples/function/delete/path/user/:user")
User Function examplesFunctionDeletePath()
    Local cJson := ""
    Local jPath
​
    jPath := JsonObject():New()
    jPath := oRest:getPathParamsRequest()
​
    If (jPath <> Nil)
        cJson := '[ { "description": "examplesFunctionDeletePath successfully executed, parameter received: ' + jPath['user'] +'"} ]'
    Endif
Return oRest:setResponse(cJson)


Exemplo utilizando função recebendo parâmetro via query string

#include "tlpp-core.th"
#include "tlpp-rest.th"
​
/* --------------------------------------------- */
@Delete("examples/function/delete/query/user")
User Function examplesFunctionDeleteQuery()
    Local cJson := ""
    Local jQuery
​
    jQuery := JsonObject():New()
    jQuery := oRest:getQueryRequest()
​
    If (jQuery <> Nil)
        cJson := '[ {"description": "examplesFunctionDeleteQuery successfully executed, parameter received: ' + jQuery['user'] + '"} ]'
    Endif
Return oRest:setResponse(cJson)


Exemplo utilizando classe com métodos e recebendo parâmetro via path param e query string.

#include "tlpp-core.th"
#include "tlpp-rest.th"
​
Class classDeleteExamples
​
    Public Method New()

    @Delete("examples/class/delete/path/user/:user")
    Public Method methodExamplesDeletePath()

    @Delete("examples/class/delete/query/user")
    Public Method methodExamplesDeleteQuery()
​
EndClass
​
Method New() class classDeleteExamples
​
Return self
​
/* --------------------------------------------- */
Method methodExamplesDeletePath() class classDeleteExamples
​
    Local cJson := ""
    Local jPath
​
    jPath := JsonObject():New()
    jPath := oRest:getPathParamsRequest()
​
    If (jPath <> Nil)
        cJson := '[ {"description": "methodExamplesDeletePath successfully executed, parameter received: ' + jPath['user'] + '"} ]'
    Endif
Return oRest:setResponse(cJson)
​
/* --------------------------------------------- */
Method methodExamplesDeleteQuery() class classDeleteExamples
    Local cJson := ""
    Local jQuery
​
    jQuery := JsonObject():New()
    jQuery := oRest:getQueryRequest()
​
    If (jQuery <> Nil)
        cJson := '[ {"description": "methodExamplesDeleteQuery successfully executed, parameter received: ' + jQuery['user'] + '"} ]'
    Endif
Return oRest:setResponse(cJson)

Atenção:

Os objetos JSON retornados por métodos de oRest, como por exemplo oRest:getQueryRequest(), são referências ao objeto existente no REST e não uma cópia.

Existem alguns motivos para ser uma referência, são eles:

  • Melhorar performance do serviço;
  • Economia de memória;
  • Evitar que seja necessário limpar o objeto na saída da implementação do serviço REST.

Portanto, é imprescindível que não se manipule diretamente o Objeto, pois isso irá refletir nas próximas requisições, causando problemas difíceis de serem detectados.

Métodos:

oRest:getPathParamsRequest()
oRest:getQueryRequest()
oRest:getHeaderRequest()
oRest:getThreadPoolTlppData()
oRest:getServerTlppData()
oRest:getThreadPoolUserData()
oRest:getThreadPoolServerUserData()
oRest:getHeaderResponse()

  • Sem rótulos