Linha Microsiga Protheus

Árvore de páginas

Aviso!

Produto ainda em fase de piloto.

01. VISÃO GERAL

Produto:TOTVS Backoffice
Linha de Produto:

Linha Protheus ®

Módulo:Financeiro
Função:FINTITG - Inclusão de títulos Pagar/Receber via smartlink

02. DESCRIÇÃO

Ponto de Entrada FiTitGsp para permitir a alteração do conteúdo do array que será passado para o execauto do FINA040/FINA050. O ponto de entrada é executado antes da chamada da execução da rotina automática, durante o processo de geração ou exclusão de títulos a Pagar/Receber da integração Gesplan, via smartlink.

O ponto de entrada deverá retornar um array na mesma estrutura do aDados que receberá como parâmetro, efetuando a edição de informações específicas, conforme regra de negócio do cliente.

03. PARÂMETROS

PosiçãoNomeDescrição
1cCarteira

Indica a rotina que está sendo executada:

"R" = Título a receber - FINA040

"P" = Título a pagar - FINA050

2cOperacao

Indica a ação que está sendo executada para o título:

"I" = Inclusão

"E" = Exclusão

3aDadosArray com a estrutura dos dados (campo e conteúdo) a serem passados para o processamento da rotina automática.

04. RETORNO

NomeDescrição
aDados

Array na mesma estrutura recebida como parâmetro e novo conteúdo.

05. EXEMPLO DE UTILIZAÇÃO

P.E. FiTitGsp
#include "Protheus.ch"

User Function FiTitGsp()

Local nPos      as Numeric
Local aArea     as Array
Local cCarteira as Character
Local cOperacao as Character
Local aDados    as Array

aArea     := GetArea()
cCarteira := ParamIxb[1]
cOperacao := ParamIxb[2]
aDados    := ParamIxb[3]

If cCarteira=='P' .And. cOperacao=="I" // Inclusão de título carteira Pagar

    If (nPos:=aScan(aDados,  { |x| Alltrim(x[1]) == 'E2_NATUREZ'  })) > 0
        dbSelectArea('SED')
        dbSetOrder(1)
        If dbSeek(FWxFilial()+aDados[nPos,2])
            //-- Adiciona a conta contabil da Natureza no campo do título
            Aadd(aDados, {'E2_DEBITO' , ED_CONTA , Nil} )
        EndIF
    EndIF

EndIf

If cCarteira=='R' .And. cOperacao=="I" // Inclusão de título carteira Receber
     If (nPos:=aScan(aDados,  { |x| Alltrim(x[1]) == 'E1_HIST'  })) == 0   
		Aadd(aDados, {'E1_HIST' , 'GESPLAN' , Nil} ) 
	EndIf
EndIF

RestArea(aArea)
FwFreeArray(aArea)

Return(aDados)


05. CONTEÚDO RELACIONADO

Integração Gesplan - Manutenção de Títulos a Pagar/Receber