MAPVLNFS - Generación de documento de salida a partir de ítems del Pedido de venta

#INCLUDE "PROTHEUS.CH"
#INCLUDE "TBICONN.CH"

User Function MyPVLNFS()

    Local aPvlDocS := {}
    Local nPrcVen := 0
    Local cC5Num  := "pcpAO9"
    Local cSerie  := "001"
    Local cEmbExp := ""
    Local cDoc    := ""

    PREPARE ENVIRONMENT EMPRESA "T1" SUCURSAL "D MG 01 " MÓDULO "FAT" TABLES "SF2","SD2","SA1","SA2","SB1","SB2","SF4","SED","SE1"

    SC5->(DbSetOrder(1))
    SC5->(MsSeek(xFilial("SC5")+cC5Num))

    SC6->(dbSetOrder(1))
    SC6->(MsSeek(xFilial("SC6")+SC5->C5_NUM))

    //Es necesario cargar el grupo de preguntas MT460A, si no se ejecuta con los valores estándar.
    Pregunta("MT460A",.F.)

    // Obtener los datos de cada ítem del pedido de ventas liberado para generar el Documento de salida
    While SC6->(!Eof() .And. C6_FILIAL == xFilial("SC6")) .And. SC6->C6_NUM == SC5->C5_NUM

        SC9->(DbSetOrder(1))
        SC9->(MsSeek(xFilial("SC9")+SC6->(C6_NUM+C6_ITEM))) //SUCURSAL+NÚMERO+ÍTEM

        SE4->(DbSetOrder(1))
        SE4->(MsSeek(xFilial("SE4")+SC5->C5_CONDPAG) )  //SUCURSAL+CONDICIÓN PAGO

        SB1->(DbSetOrder(1))
        SB1->(MsSeek(xFilial("SB1")+SC6->C6_PRODUTO))    //SUCURSAL+PRODUCTO

        SB2->(DbSetOrder(1))
        SB2->(MsSeek(xFilial("SB2")+SC6->(C6_PRODUTO+C6_LOCAL))) //SUCURSAL+PRODUCTO+LOCAL

        SF4->(DbSetOrder(1))
        SF4->(MsSeek(xFilial("SF4")+SC6->C6_TES))   //SUCURSAL+TES

        nPrcVen := SC9->C9_PRCVEN
        If ( SC5->C5_MOEDA <> 1 )
            nPrcVen := xMoeda(nPrcVen,SC5->C5_MOEDA,1,dDataBase)
        EndIf

		If AllTrim(SC9->C9_BLEST) == "" .And. AllTrim(SC9->C9_BLCRED) == ""
        	AAdd(aPvlDocS,{ SC9->C9_PEDIDO,;
                        	SC9->C9_ITEM,;
                        	SC9->C9_SEQUEN,;
                        	SC9->C9_QTDLIB,;
                        	nPrcVen,;
                        	SC9->C9_PRODUTO,;
                        	.F.,;
                        	SC9->(RecNo()),;
                        	SC5->(RecNo()),;
                        	SC6->(RecNo()),;
                        	SE4->(RecNo()),;
                        	SB1->(RecNo()),;
                        	SB2->(RecNo()),;
                        	SF4->(RecNo())})
		EndIf

        SC6->(DbSkip())
    EndDo

	SetFunName("MATA461")
    
    cDoc := MaPvlNfs(  /*aPvlNfs*/         aPvlDocS,;  // 01 - Array con los ítems que se generarán
                       /*cSerieNFS*/       cSerie,;    // 02 - Serie de la factura
                       /*lMostraCtb*/      .F.,;       // 03 - Muestra asiento contable
                       /*lAglutCtb*/       .F.,;       // 04 - Agrupa asiento contable
                       /*lCtbOnLine*/      .F.,;       // 05 - Contabiliza on-line
                       /*lCtbCusto*/       .T.,;       // 06 - Contabiliza costo on-line
                       /*lReajuste*/       .F.,;       // 07 - Reajuste de precio en la factura
                       /*nCalAcrs*/        0,;         // 08 - Tipo de aumento financiero
                       /*nArredPrcLis*/    0,;         // 09 - Tipo de redondeo
                       /*lAtuSA7*/         .T.,;       // 10 - Actualiza vínculo Cliente vs. Producto
                       /*lECF*/            .F.,;       // 11 - Comprobante fiscal
                       /*cEmbExp*/         cEmbExp,;   // 12 - Número del embarque de exportación
                       /*bAtuFin*/         {||},;      // 13 - Bloque de código para complemento de actualización de los títulos financieros
                       /*bAtuPGerNF*/      {||},;      // 14 - Bloque de código para complemento de actualización de los datos después de la generación de la factura
                       /*bAtuPvl*/         {||},;      // 15 - Bloque de código de actualización del Pedido de venta antes de la generación de la factura
                       /*bFatSE1*/         {|| .T. },; // 16 - Bloque de código para indicar si el valor del Título por cobrar se grabará en el campo F2_VALFAT cuando el parámetro MV_TMSMFAT esté con el valor igual a "2".
                       /*dDataMoe*/        dDatabase,; // 17 - Fecha de la cotización para conversión de los valores de la Moneda del Pedido de venta a la Moneda fuerte
                       /*lJunta*/          .F.)        // 18 - Agrupa pedidos iguales
    
    If !Empty(cDoc)
        Conout("Documento de salida: " + cSerie + "-" + cDoc + ", generado con éxito.")
    EndIf

    RESET ENVIRONMENT

Return .T.